Usage of widening cast in abap oops

Question

hi experts,
I understood the widening cast concept. i want to know in what scenarios, the usage of widening cast makes sense. does the widening improve performance of the program? is there any scenario where we MUST use the widening cast in the logic? i want to understand how do we justify the usage of widening cast.
please do not give me links explaining widening case. I know what widening cast is, but want to understand the need for it and how it helps in programing.
thanks

Answer 1

As for the thread's question: you use it when you have a subclass instance being pointed at by a superclass reference, and you need to access subclass specific components.
Adding about widening / down cast:
I repeat: you don't have choice.
You actually do. Check the following example. BAPIRET2_T is a table type for BAPIRET2.
You can call the method YOU know the actual referenced object of a subclass supports dynamically, like this:
* Using downcasting
DATA lo_tabledescr TYPE REF TO cl_abap_tabledescr.
DATA lo_structdescr TYPE REF TO cl_abap_structdescr.
DATA lv_linetypename  TYPE string.
TRY.
    lo_tabledescr   ?= cl_abap_typedescr=>describe_by_name( 'BAPIRET2_T' ).
    lo_structdescr  ?= lo_tabledescr->get_table_line_type( ).
  CATCH cx_sy_move_cast_error.
    MESSAGE 'Error in downcast!' TYPE 'A'.
ENDTRY.
lv_linetypename = lo_structdescr->get_relative_name( ).
WRITE: /, lv_linetypename.
* Alternative way using dynamic calling
DATA lo_typedescr_tab TYPE REF TO cl_abap_typedescr.
DATA lo_typedescr_str TYPE REF TO cl_abap_typedescr.
lo_typedescr_tab   = cl_abap_typedescr=>describe_by_name( 'BAPIRET2_T' ).
TRY.
    CALL METHOD lo_typedescr_tab->('GET_TABLE_LINE_TYPE')
      RECEIVING
        p_descr_ref = lo_typedescr_str.
  CATCH cx_sy_dyn_call_error.
    MESSAGE 'Error in dynamic call!' TYPE 'A'.
ENDTRY.
lv_linetypename = lo_typedescr_str->get_relative_name( ).
WRITE: /, lv_linetypename, '...again'.
Note that in either approach, you should catch the relevant exception(s) that may occur, unless you are certain about the object's actual subclass.
Edited by: Alejandro Bindi on Mar 31, 2010 5:47 PM
As you can see I got confused by the narrowing / widening terms as well. I also found out the terms upcast / downcast to be much easier to understand.