Use Automator/AppleScript to clean iPhoto Library

Question

Hello,
Having read a lot of posts about the use of AppleScript and Automator to do things with iPhoto, I think it's possible to create a script or a processus to clean the iPhoto Library (let say, a copy of it) to eliminate "zombie files" (photos which have not been deleted of the iPhoto Library when emptying the iPhoto trash).
The script should simply verify, for each file in the "master" folder, il the path of this file is known in the iPhoto database (the data base is in the "AlbumData.xml" file). If it is, the file is kept. It it's not, the file is moved to trash (or to a temporary folder).
Should anyone create this script ? I should try, but I would need two weeks to do it correctly, and I'm sure someone can do it in 5 minutes... Some help here ? Thanks !

Answer 1

Hi,
Try this AppleScript:
repeat
    set r to (choose file with prompt "Select an iPhoto Library package" default location (path to pictures folder)) as string
    try
        (r & "AlbumData.xml") as alias
        (r & "Masters") as alias
        (r & "Previews") as alias
        exit repeat
    on error
        activate
        display dialog "This package does not contains \"AlbumData.xml\" file or the \"Masters\" folder or the \"Previews\" folder." buttons {"OK"} default button "OK"
    end try
end repeat
set iPhoto_Library to quoted form of POSIX path of r
set AlbDataXML to quoted form of POSIX path of (r & "AlbumData.xml")
tell application "Finder"
    set newFolder to (make new folder) as string
    set dest to (make new folder at folder newFolder with properties {name:"Images qui ne sont pas dans AlbumDataXML"}) as string
end tell
set destF to quoted form of POSIX path of dest
set file1 to quoted form of POSIX path of (newFolder & "filesPath.txt")
set file2 to quoted form of POSIX path of (newFolder & "PhotosDataPath.txt")
do shell script "dest=" & destF & "; tFile=" & file1 & "; tFile2=" & file2 & "; iPhotoLib=" & iPhoto_Library & ";
grep -A1 '\\(\\<key>OriginalPath<\\|\\<key>ImagePath<\\)' " & AlbDataXML & "  | sed -n  '/<string>/s/^.*<string>\\(.*\\)<\\/string>$/\\1/p' | sort -o \"$tFile2\"
find \"$iPhotoLib\"Masters -type f \\! -name '.*' >\"$tFile\"
find \"$iPhotoLib\"Previews -type f \\! -name '.*' >>\"$tFile\"
sort -o \"$tFile\" \"$tFile\"
diff -ab  \"$tFile2\" \"$tFile\" | sed -n '/> /s/^> //p' | while read f; do
   name=${f##*/}
   if [ -e \"$dest$name\" ];then
        i=1
        while [ -e \"$dest$name $i\" ];do
            ((i++))
        done
        name=\"$name $i\"
   fi
   /bin/mv -f \"$f\" \"$dest$name\"
done"
tell application "Finder"
    activate
    reveal folder dest -- select the folder which contains moved files
end tell
This script move every files in the ("Masters" and "Previews") folders which it's path is not in the "AlbumData.xml" file to a new folder on the desktop.
The grep command get all path in "AlbumData.xml" from the (OriginalPath and ImagePath) keys and put the result in file2.
The find command get all file's path in the ("Masters" and "Previews") folders and put the result in file1.
The diff and sed command get all file path in text file1 which is not in text file2
Before moving file:
This script check name of the file to not overwrite any file in the destination folder.
If a name already exist in the destination folder, the script add a space and a number to the end of the filename.