Use of DBMS_OUTPUT.GET_LINE to debug triggers

Question

I states in the PL/SQL Users Guide and Reference (page 9-16):
"Package DBMS_OUTPUT enables you to display output from PL/SQL blocks and subprograms, which makes it easier to test and debug them. The procedure put_line outputs information to a buffer in the SGA. You display the information Overview of Product-Specific Packages by calling the procedure get_line or by setting SERVEROUTPUT ON in SQL*Plus."
Also in Supplied PL/SQL Packages and Types Reference it states:
"A trigger might want to print out some debugging information. To do this, the trigger would do:
DBMS_OUTPUT.PUT_LINE(I got here:||:new.col|| is the new value);
If you have enabled the DBMS_OUTPUT package, then this PUT_LINE would be buffered, and you could, after executing the statement (presumably some INSERT, DELETE, or UPDATE that caused the trigger to fire), get the line of information back.
For example:
BEGIN
DBMS_OUTPUT.GET_LINE(:buffer, :status);
END;
It could then display the buffer on the screen. You repeat calls to GET_LINE until status comes back as nonzero. For better performance, you should use calls to GET_LINES which can return an array of lines."
I have tried to use this, but cannot get anything out. I do not find any actual examples in any of the docs on how to use this.
Jim Azeltine
[email protected]

Answer 1

With SET SERVEROUTPUT ON, it causes the usage of DBMS_OUPUT.PUT_LINE to display automatically. With SET SERVEROUPUT OFF, you have to use DBMS_OUPUT.ENABLE to allow things from DBMS_OUTPUT.PUT_LINE to be stored to a buffer and DBMS_OUTPUT.GET_LINE or DBMS_OUTPUT.GET_LINES to retrieve the items from the buffer into variables and use PRINT or SET AUTOPRINT ON or something to display them. I have always just used SET SERVEROUTPUT ON, however I imagine the other method might be useful under certain circumstances where you want to store the values to variables or enter the values into audit tables or something other than just display them directly to the screen. There are also many environments where SET SERVEROUTPUT ON cannot be used, since it is a SQL*Plus command. Below I have given, first, an example of usage of SET SERVEROUTPUT ON, then, second, an example with SET SERVEROUTPUT OFF, that uses DBMS_OUTPUT.ENABLE and DBMS_OUTPUT.GET_LINE and SET AUTOPRINT ON.
SQL> SET ECHO ON
SQL> -- trigger for demonstration:
SQL> CREATE OR REPLACE TRIGGER test_trigger
  2    BEFORE INSERT ON anytable
  3    FOR EACH ROW
  4  BEGIN
  5    DBMS_OUTPUT.PUT_LINE ('I got here: '
  6                          || :NEW.anycolumn
  7                          || ' is the new value.');
  8    :NEW.anycolumn := 0;
  9    DBMS_OUTPUT.PUT_LINE ('I got here: '
10                          || :NEW.anycolumn
11                          || ' is the new value.');
12  END test_trigger;
13  /
Trigger created.
SQL>
SQL>
SQL> -- example with serverouput on
SQL> SET SERVEROUTPUT ON
SQL> INSERT INTO anytable VALUES (1)
  2  /
I got here: 1 is the new value.
I got here: 0 is the new value.
1 row created.
SQL>
SQL>
SQL> -- example with serveroutput off:
SQL> SET SERVEROUTPUT OFF
SQL> EXECUTE DBMS_OUTPUT.ENABLE (40)
PL/SQL procedure successfully completed.
SQL> INSERT INTO anytable VALUES (1)
  2  /
1 row created.
SQL> VARIABLE buffer VARCHAR2 (40)
SQL> VARIABLE status NUMBER
SQL> SET AUTOPRINT ON
SQL> BEGIN
  2    DBMS_OUTPUT.GET_LINE(:buffer, :status);
  3  END;
  4  /
PL/SQL procedure successfully completed.
    STATUS
         0
BUFFER
I got here: 1 is the new value.
SQL> BEGIN
  2    DBMS_OUTPUT.GET_LINE(:buffer, :status);
  3  END;
  4  /
PL/SQL procedure successfully completed.
    STATUS
         0
BUFFER
I got here: 0 is the new value.
SQL> BEGIN
  2    DBMS_OUTPUT.GET_LINE(:buffer, :status);
  3  END;
  4  /
PL/SQL procedure successfully completed.
    STATUS
         1
BUFFER
SQL>