User defined function to find difference between dates

Question

format of dtActivityStartDate/dtActivityFinishDate: 2010-09-17 14:50:51.150
usdFuncTimeCalc (vcActivityName,dtActivityStartDate, dtActivityFinishDate) -- user defined function
i need to calculate time elapsed for that type of activity following are the rules:
(If Process Request is the activity)
Working Days: Monday through Saturday
Hours of Operation: 9AM – 5PM
only working hours of day need to the counted like for example if it is sep 15 11 Am is dtActivityStartDate & Sep 17 is dtActivityFinishDate is 10 Am. then time elapsed is 11am to 5pm on sep 15 , 9 to 5 on sep 16 & 9 to 10 on sep 17 so total should be
6+ 8 + 1 = 15 hours + minutes.
format of date time: 2010-09-17 14:50:51.150
vcActivityName = Process Request
Don't worry about process request...

Answer 1

I hv modified the code to make it more generic inorder to suit any timings (customizable) from Monday - Saturday.
declare
  -- ** b u s i n e s s _ h o u r s **
  -- business_hours returns the number of work houts (9 am through 5 pm,
  -- Monday through Saturday) between in_start_dt and in_end_dt.
  -- If in_start_dt > in_end_dt, the results will be <= 0.
  -- Holidays are not considered.
  in_start_dt DATE := to_date('15-SEP-2010 11:00:00','DD-MON-RRRR HH24:MI:SS');
  in_end_dt   DATE := to_date('17-SEP-2010 10:00:00','DD-MON-RRRR HH24:MI:SS');
  d          NUMBER; -- Hours of either start_dt or end_dt after midnight
  end_dt     DATE := GREATEST(in_start_dt, in_end_dt); -- In case dates were in wrong order
  return_val NUMBER; -- Total number of working hours
  start_dt   DATE := LEAST(in_start_dt, in_end_dt); -- In case dates were in wrong order
  start_time number := 9;
  end_time   number := 17;
BEGIN
  WITH all_days AS(
    SELECT start_dt + LEVEL - 1 AS a_dt
      FROM dual
    CONNECT BY LEVEL <= 1 + TRUNC(end_dt) - TRUNC(start_dt))
      --SELECT SUM(12)
       SELECT SUM(end_time-start_time)
        INTO return_val
        FROM all_days
       WHERE TO_CHAR(a_dt,'Dy','NLS_DATE_LANGUAGE = ''ENGLISH''') NOT IN ('Sun');
  dbms_output.put_line('Return_Val_1 : '||return_val);
  -- Adjust hours from start_dt, if necessary
  IF TO_CHAR(start_dt, 'Dy', 'NLS_DATE_LANGUAGE = ''ENGLISH''') NOT IN ('Sun') THEN
     -- Calculate nbr of hours passed from midnight
     d := 24 * (start_dt - TRUNC(start_dt));
     dbms_output.put_line('d:'||d);
     IF d >= end_time THEN -- d has passed 5 PM (end_time)
        -- Don't count start_dt if it has passed the closing hours
        return_val := return_val - (end_time-start_time);
        dbms_output.put_line('if-d:'||return_val);
     ELSIF d > start_time and d < end_time THEN -- d has passed 9 AM but less than 5 PM
        -- Don't count the part of start_dt which has passed the opening hours
        return_val := return_val - (d - start_time);
        dbms_output.put_line('else-d:'||return_val);
     END IF;
  END IF;
  dbms_output.put_line('');
  dbms_output.put_line('Return_Val_2 : '||return_val);
  -- Adjust hours from end_dt, if necessary
  IF TO_CHAR(end_dt, 'Dy', 'NLS_DATE_LANGUAGE = ''ENGLISH''') NOT IN ('Sun') THEN
     d := 24 * (end_dt - TRUNC(end_dt));
     dbms_output.put_line('d:'||d);
    IF d <= 9 THEN -- d < 9 AM
       -- Don't count end_dt itself
       return_val := return_val - (end_time-start_time);
       dbms_output.put_line('if-d:'||return_val);
    ELSIF d > start_time and d < end_time THEN -- d > 5 PM
      -- Don't count part of end_dt
      return_val := return_val - (end_time - d);
      dbms_output.put_line('else-d:'||return_val);
    END IF;
  END IF;
  dbms_output.put_line('');
  dbms_output.put_line('Return_Val_3 : '||return_val);
  IF in_start_dt > in_end_dt THEN
      return_val := -return_val;
  END IF;
  dbms_output.put_line('');
  dbms_output.put_line('Return_Val_4 : '||return_val);
END;Plz note the following points of the code :
1) You'll need to convert it a function, I just made it a declare..begin..end; block.
2) I hv used the same timings for start & end as you hv mentioned.
3) The 2 variables "start_time" and "end_time" take the opening & closing business hours respectively in a 24 hour format.
4) You might want to remove the DBMS_OUTPUT ... stmts which I had added for debugging.
It was an interesting code block to analyze ... :-)