Using a function in a Cursor Definiftion

Question

Hi all,
my problem is to define a curson inside a package, using a function already defined in the function.
My source code is the folowing:
PROCEDURE TEST
IS
CURSOR cursor_test IS
SELECT ID_CUSTOMER
FROM CUSTOMER
WHERE START_VALIDITY_DATE > GET_DATE(DATE_NEW_CUSTOMER, DATE_EXPIRED);
BEGIN
END;
The function Get_date ( a date,b date) is defined in the same package where it is collocated my procedure "Test". The function called "Get date" return a date.
When I compile, I have an error and I don't understand why.
Thank'you in advance

Answer 1

Hi,
To illustrate APC's point with some simple examples:
HR%xe> create or replace package test_pkg
  2  as
  3    procedure public_proc;
  4  end test_pkg; 
  5  /
Package is aangemaakt.
HR%xe> create or replace package body test_pkg
  2  as
  3    procedure public_proc
  4    is
  5      function private_func
  6      return date
  7      is
  8      begin
  9       return(sysdate);
10      end private_func;
11      --
12      l_count number := 0;
13      --
14    begin
15      select count(*) into l_count
16      from   employees
17      where  employees.hire_date < private_func;
18      --
19      dbms_output.put_line(l_count||' employees were counted.');
20      --
21    end;
22  end test_pkg; 
23  /
Waarschuwing: package-body is aangemaakt met compilatiefouten.
HR%xe> sho err
Fouten voor PACKAGE BODY TEST_PKG:
LINE/COL ERROR
12/5     PLS-00103: Encountered the symbol "L_COUNT" when expecting one of
         the following:
         begin function package pragma procedure form
22/5     PLS-00103: Encountered the symbol "TEST_PKG" when expecting one
         of the following:
HR%xe> create or replace package test_pkg
  2  as
  3  /* commented out the declaration in the specification this time
  4    function private_func
  5    return date;
  6  */ 
  7    procedure public_proc;
  8  end test_pkg; 
  9  /
Package is aangemaakt.
HR%xe> create or replace package body test_pkg
  2  as
  3    function private_func
  4    return date
  5    is
  6    begin
  7     return(sysdate);
  8    end;
  9 
10    procedure public_proc
11    is
12      l_count number := 0;
13    begin
14      select count(*) into l_count
15      from   employees
16      where  employees.hire_date < private_func;
17      --
18      dbms_output.put_line(l_count||' employees were counted.');
19      --
20    end;
21  end test_pkg; 
22  /
Waarschuwing: package-body is aangemaakt met compilatiefouten.
HR%xe> sho err
Fouten voor PACKAGE BODY TEST_PKG:
LINE/COL ERROR
14/5     PL/SQL: SQL Statement ignored
16/34    PL/SQL: ORA-00904: "PRIVATE_FUNC": invalid identifier
16/34    PLS-00231: function 'PRIVATE_FUNC' may not be used in SQL
HR%xe> create or replace package test_pkg
  2  as
  3  
  4    function private_func
  5    return date;
  6   
  7    procedure public_proc;
  8  end test_pkg; 
  9  /
Package is aangemaakt.
HR%xe> create or replace package body test_pkg
  2  as
  3    function private_func
  4    return date
  5    is
  6    begin
  7     return(sysdate);
  8    end;
  9 
10    procedure public_proc
11    is
12      l_count number := 0;
13    begin
14      select count(*) into l_count
15      from   employees
16      where  employees.hire_date < private_func;
17      --
18      dbms_output.put_line(l_count||' employees were counted.');
19      --
20    end;
21  end test_pkg; 
22  /
Package-body is aangemaakt.
HR%xe> exec test_pkg.public_proc
107 employees were counted.
PL/SQL-procedure is geslaagd.Once you declare your function in your package specification as well, you can use your function in your procedure.
http://download.oracle.com/docs/cd/B19306_01/appdev.102/b14251/adfns_packages.htm#sthref823