Using a script to "recolor" forms

Question

Hello,
I don't know if this is possible, but I thought I'd ask. We maintain forms applications that exist in a Real World Mode and a Test Mode. The only difference is what database I connect to , and the color of the forms. Is there a way to write a script (maybe in perl) that could modify the .fmb files and change the form colors without having to bring up the forms developer and slop through all the forms? I've looked at the .fmb files and unfortunately they appear to not be entirely ascii....

Answer 1

> How do you tell which database you're attached to?
Each db has a table with one row and column with 'Test' or 'Production' in it. The startup form that each user is required to use queries that table and stores the value in a global variable.
> I would also like to see the sample code
Not sure what good seeing the code is, but here is our PLL library procedure called by each form's pre-form trigger:
PROCEDURE PLL_PRE_FORM IS
    Cur_form    Varchar2(30);
BEGIN
--*   Common initialization procedures
  COPY('0','SYSTEM.MESSAGE_LEVEL');
  DEFAULT_VALUE(' ','GLOBAL.BACKGROUND_COLOR');
  -- SDSU globals
  DEFAULT_VALUE(' ','GLOBAL.SD_FORMS_TYPE');
  DEFAULT_VALUE(' ','GLOBAL.SD_DATABASE_TYPE');
  DEFAULT_VALUE(' ','GLOBAL.SD_BACKGROUND_COLOR');
  Cur_form := GET_APPLICATION_PROPERTY(CURRENT_FORM_NAME);
  IF GET_APPLICATION_PROPERTY(OPERATING_SYSTEM) <> 'MACINTOSH' THEN
    DECLARE
      WINDOW_ID        WINDOW;
      WTitle           Varchar2(100);
      p_version        varchar2(20); --for sd
      sd_forms_type    varchar2(20); --for sd
      sd_database_type varchar2(20); --for sd
      sd_bgd_color     varchar2(20); --for sd
    BEGIN
      WINDOW_ID   := FIND_WINDOW('ROOT_WINDOW');
      IF ID_NULL(WINDOW_ID) THEN
        WINDOW_ID := FIND_WINDOW('WINDOW0');
        IF ID_NULL(WINDOW_ID) THEN
          PLL_MSGF('  PLL_PRE_FORM:  '
                    ||'Window must be named ROOT_WINDOW OR WINDOW0');
        END IF;
      END IF;
      Set_Window_Property(Window_Id,Window_State,Maximize);
      WTitle := Get_Window_Property(Window_Id,Title);
      WTitle := nvl(WTitle,Cur_form);
      -- SD globals:
      If Cur_form <> 'S100' then
        p_version        := NAME_IN('PARAMETER.VERSION');
        sd_forms_type    := ltrim(NAME_IN('GLOBAL.sd_forms_type'));
        sd_database_type := ltrim(NAME_IN('GLOBAL.sd_database_type'));
      End if;
      -- for SD, add form version, and change if Testing database.
      IF  sd_database_type = 'PRODUCTION'
      AND sd_forms_type    = 'PRODUCTION' THEN
        WTitle := SUBSTR(WTitle || ' v.' || p_version  ,1,100);
      Elsif sd_forms_type    is not null
      or    sd_database_type is not null then
        --sd testing instance
        WTitle := SUBSTR(WTitle ||' v.'         || p_version
                                ||', Form: '    || sd_forms_type
                                ||', Database: '|| sd_database_type
                         ,1,100);
        sd_bgd_color := ltrim(NAME_IN('GLOBAL.SD_BACKGROUND_COLOR'));
        if sd_bgd_color is not null then
          copy(sd_bgd_color,'GLOBAL.BACKGROUND_COLOR');
        end if;
      End if; -- end of SD-specific code
      If Get_Application_Property(User_Interface) = 'WEB' then
        --Web forms:  set MDI title, erase W0 title.
        Set_Window_Property(Window_Id,Title,' ');
        Set_Window_Property(Forms_MDI_Window,Title,' ' || WTitle);
        --- Check if running SeparateFrame=False (form within browser)
        If get_window_property(forms_mdi_window,title) is null then
          --Cannot set browser title; need to set Window0 title--
          Set_Window_Property(Window_Id,Title,' ' || WTitle);
        end if;
      Else -- client/server forms
        Set_Window_Property(Forms_MDI_Window,Title,' ');
        Set_Window_Property(Window_Id,Title,' '||WTitle||' ');
      End if;
    END;
  END IF;
  -- Set background color of canvas if user has changed it.
  Declare
    Cnv1 canvas  := FIND_CANVAS('CANVAS1');
  Begin
    If NOT id_null(Cnv1) then
      -- store original (design-time) color
      PLL_MB.CNV_BGD_COLOR:= get_canvas_property(Cnv1,background_color);
    End if;
    If NOT id_null(Cnv1)
    and NAME_IN('GLOBAL.BACKGROUND_COLOR') <> ' ' then
      SET_CANVAS_PROPERTY(Cnv1,
                   BACKGROUND_COLOR,NAME_IN('GLOBAL.BACKGROUND_COLOR'));
    End if;
  End;
  -- Set window size at least as large as Window0.
  -- Reduce size if H and W are more than 110% of Window0 size
  Declare
    H          number;
    W          number;
    Win0_id    window := FIND_WINDOW('WINDOW0');
    MDI_id     window := Forms_MDI_Window;
    B_continue boolean := false;
  Begin
    If  NOT id_null(Win0_id)
    and NOT id_null(MDI_id) then
      W := Get_Window_Property(Win0_id,Width)  + 1;
      H := Get_Window_Property(Win0_id,Height) + 1;
      If  W between 640 and 700
      and H between 400 and 450
      and Get_Window_Property(MDI_Id,window_state)='NORMAL' then
        B_continue := true;
      end if;
    End if;
    If Get_Application_Property(User_Interface) = 'WEB' then
      W := W + 14; -- Web forms
      H := H + 124;
    end if;
    if  B_continue then
      -- set window to minimum height and width
      if Get_Window_Property(MDI_id,Width )<W  then
         Set_Window_Property(MDI_id,Width,  W);
      end if;
      if Get_Window_Property(MDI_id,Height)<H then
         Set_Window_Property(MDI_id,Height, H);
      end if;
      -- If H and W are both more than 110% of window H,W,
      -- then set to 110% of H,W.
      if  Get_Window_Property(MDI_id,Width )>1.1 * W + 1
      and Get_Window_Property(MDI_id,Height)>1.1 * H + 1 then
          Set_Window_Property(MDI_id,Width,  1.1 * W );
          Set_Window_Property(MDI_id,Height, 1.1 * H );
      end if;
    end if;
  End;
END PLL_PRE_FORM;