Using a string as sql statement in PL/SQL

Question

Hi there,
I have a function which returns a part of a query depending on some conditions.
FUNCTION GET_REPORT_TYPE(in_report_type IN NUMBER)
RETURN VARCHAR2
AS
reporttype varchar2(50);
BEGIN
CASE in_report_type
WHEN 0 THEN
reporttype := 'C1.DATE_CLOSED != NULL';
WHEN 1 THEN
reporttype := 'C1.DATE_CLOSED := NULL';
WHEN 2 THEN
reporttype := '';
END CASE;
RETURN reporttype;
END GET_REPORT_TYPE;
Now in my procedure I would like to put this returned value in an AND clause of my query:
procedure get_cpl(p_cursor OUT rst_cur, searchcode IN VARCHAR2, reporttype IN VARCHAR2)
is
begin
open p_cursor for
SELECT C1.CIPIDI_NR,
C1.CIPIDI_NAME,
C2.TEAM_MEMBER
FROM TBL_CIPIDI C1, TBL_TEAM_MEMBERS C2
WHERE C1.CIPIDI_NR LIKE searchcode
AND C1.CIPIDI_NR = C2.CIPIDI_NR (+);
AND reporttype; -- HERE I WOULD LIKE TO USE WHAT THE FUNCTIONS RETURNED
end get_cpl;
How can I can I use reporttype to function as a part of the query? Thanks a lot
Chris

Answer 1

scott@ORA92> -- test data:
scott@ORA92> SELECT * FROM tbl_cipidi
  2  /
CIPIDI_NR CIPIDI_NAME DATE_CLOS
         1 name1       30-MAY-05
         1 name2
scott@ORA92> SELECT * FROM tbl_team_members
  2  /
CIPIDI_NR TEAM_MEMBER
         1 team1
scott@ORA92> -- function:
scott@ORA92> CREATE OR REPLACE FUNCTION GET_REPORT_TYPE
  2    (in_report_type IN NUMBER)
  3    RETURN            VARCHAR2
  4  AS
  5    reporttype       varchar2(50);
  6  BEGIN
  7    CASE in_report_type
  8        WHEN 0 THEN reporttype := 'C1.DATE_CLOSED IS NOT NULL';
  9        WHEN 1 THEN reporttype := 'C1.DATE_CLOSED IS NULL';
10        ELSE reporttype := '1 = 1';
11    END CASE;
12    RETURN reporttype;
13  END GET_REPORT_TYPE;
14  /
Function created.
scott@ORA92> SHOW ERRORS
No errors.
scott@ORA92> -- packaged with procedure:
scott@ORA92> CREATE OR REPLACE PACKAGE your_pkg
  2  AS
  3    TYPE rst_cur IS REF CURSOR;
  4    procedure get_cpl
  5        (p_cursor   OUT rst_cur,
  6         searchcode IN  VARCHAR2,
  7         reporttype IN  VARCHAR2);
  8  END your_pkg;
  9  /
Package created.
scott@ORA92> SHOW ERRORS
No errors.
scott@ORA92> CREATE OR REPLACE PACKAGE BODY your_pkg
  2  AS
  3    procedure get_cpl
  4        (p_cursor   OUT rst_cur,
  5         searchcode IN  VARCHAR2,
  6         reporttype IN  VARCHAR2)
  7    is
  8    begin
  9        OPEN p_cursor FOR
10        'SELECT C1.CIPIDI_NR,
11             C1.CIPIDI_NAME,
12             C2.TEAM_MEMBER
13         FROM      TBL_CIPIDI C1, TBL_TEAM_MEMBERS C2
14         WHERE  C1.CIPIDI_NR = :b_searchcode
15         AND      C1.CIPIDI_NR = C2.CIPIDI_NR (+)
16         AND ' || get_report_type (reporttype)
17        USING searchcode;
18    end get_cpl;
19  END your_pkg;
20  /
Package body created.
scott@ORA92> SHOW ERRORS
No errors.
scott@ORA92> -- tests:
scott@ORA92> VARIABLE g_ref REFCURSOR
scott@ORA92> SET AUTOPRINT ON
scott@ORA92> EXECUTE your_pkg.get_cpl (:g_ref, 1, 0)
PL/SQL procedure successfully completed.
CIPIDI_NR CIPIDI_NAME TEAM_MEMBER
         1 name1       team1
scott@ORA92> EXECUTE your_pkg.get_cpl (:g_ref, 1, 1)
PL/SQL procedure successfully completed.
CIPIDI_NR CIPIDI_NAME TEAM_MEMBER
         1 name2       team1
scott@ORA92> EXECUTE your_pkg.get_cpl (:g_ref, 1, 2)
PL/SQL procedure successfully completed.
CIPIDI_NR CIPIDI_NAME TEAM_MEMBER
         1 name1       team1
         1 name2       team1
scott@ORA92>