Using Collection in a sql statement.

Question

Hi I want to perform the following statement:
DELETE FROM ALLOCATION_ELEC_MATRIX
WHERE dgo_ean_id in (lt_inter_dgos);
The collection lt_inter_dgos holds my dgo_ean_id's(varchars).
I can't find a way to get it to work.
The collection is declared as follows:
TYPE Interface_param_dgos IS TABLE OF VARCHAR2(20);
lt_inter_dgos Interface_param_dgos := Interface_param_dgos();
then later on the collection gets filled. But how can i get it to work to use it in my sql statement?
I don't won't to use a for loop around it since it would give me problems if I use more collections with a different amount of values in it.

Answer 1

The standard approach is to use SQL collection type and table function,
for example
SQL> create TYPE Interface_param_dgos IS TABLE OF VARCHAR2(20);
  2  /
Type created.
SQL> create or replace package my_pkg
  2  is
  3   lt_inter_dgos Interface_param_dgos := Interface_param_dgos();
  4   function get_coll return Interface_param_dgos;
  5  end;
  6  /
Package created.
SQL> create or replace package body my_pkg
  2  is
  3   function get_coll return Interface_param_dgos
  4   is
  5   begin
  6    return lt_inter_dgos;
  7   end;
  8  end;
  9  /
Package body created.
SQL> begin
  2   my_pkg.lt_inter_dgos.extend(3);
  3   my_pkg.lt_inter_dgos(1) := 'SMITH';
  4   my_pkg.lt_inter_dgos(2) := 'KING';
  5   my_pkg.lt_inter_dgos(3) := 'ALLEN';
  6  end;
  7  /
PL/SQL procedure successfully completed.
SQL> select ename from emp;
ENAME
SMITH
ALLEN
WARD
JONES
MARTIN
BLAKE
CLARK
SCOTT
KING
TURNER
ADAMS
JAMES
FORD
MILLER
14 rows selected.
SQL> delete from emp where ename in (select column_value from table(my_pkg.get_coll));
3 rows deleted.
SQL> select ename from emp;
ENAME
WARD
JONES
MARTIN
BLAKE
CLARK
SCOTT
TURNER
ADAMS
JAMES
FORD
MILLER
11 rows selected.Rgds.