Via Form using TextBox to insert a Paragraph in the place of text

Question

I developed a form in VBA in Word but it shows error here, actually i a beginner to macros
The word "2Details2" to be replace with 5 to 8 line paagraph
So by searching internet I am doing this, 
Dim para As Paragraph
    para = TextBox23.Text
    Selection.MoveRight Unit:=wdCharacter, Count:=28, Extend:=wdExtend
    Selection.Copy
    Selection.Find.ClearFormatting
    Selection.Find.Replacement.ClearFormatting
    With Selection.Find
        .Text = "2Details2"
        .Replacement.Text = para
        .Forward = True
        .Wrap = wdFindContinue
        .Format = False
        .MatchCase = False
        .MatchWholeWord = False
        .MatchWildcards = False
        .MatchSoundsLike = False
        .MatchAllWordForms = False
    End With
    Selection.Find.Execute Replace:=wdReplaceAll
Thanks in advance

Answer 1

First, you have defined:
Dim para As Paragraph
yet you're trying to populate what you've defined as a paragraph object with what appears to be text:
para = TextBox23.Text
Second, you're doing a lot of stuff with Selection which is inefficient. In general, you should use range objects instead. Moreover, you have 'Selection.Copy', but it's not apparent that you doing anything with what you've copied to the clipboard.
It appears your code could be reduced to:
With ActiveDocument.Content.Find
  .ClearFormatting
  .Replacement.ClearFormatting
  .Text = "2Details2"
  .Replacement.Text = TextBox23.Text
  .Forward = True
  .Wrap = wdFindContinue
  .Format = False
  .MatchCase = False
  .MatchWholeWord = False
  .MatchWildcards = False
  .MatchSoundsLike = False
  .MatchAllWordForms = False
  .Execute Replace:=wdReplaceAll
End With
though, other than extending the selection, I don't know what you're trying to achieve with:
Selection.MoveRight Unit:=wdCharacter, Count:=28, Extend:=wdExtend
Cheers
Paul Edstein
[MS MVP - Word]