Video-shoutbox with iMac, QT or iMovie and a DV-Cam

Question

I want to make a Video-Shoutbox on a Party.
My idea: An iMac with a Kiosk-Software. Maybe QT-Pro can make the clips. And a DV-Cam the Videos.
What i need is a possibility to push one Button, and you can 30 seconds record on the mac. After the 30 seconds you have to push or click the button again to make a new record.
After the evening you have a folder with all the clips in it and can now edit this clips in imovie or elsewhere.
How can i do that?

Answer 1

One way is with an Applescript script written to run in QuickTime Player. Here's such a script. It would be called from the kiosk screen.
Be sure to read the notes in the script.
Karl
-- Script by: Karl D. Petersen
-- 7/20/2006
-- This script records a 30 second movie, or whatever duration you set.
-- Copy this script and Paste into a new document in Script Editor, the
-- Applescript editor.
-- WARNING: This script requires that the checkbox "Enable access for assistive devices" in
-- Universal Access control panel of System Preferences be turned ON.
-- Otherwise an error will occur.
-- To prevent a timeout failure with some cameras, remove tape from camera.
-- Set camera to record mode.
-- If QuickTime Player fails to see camera, re-launch QT Player.
-- Before the recording begins, the script will play a "5, 4, 3, 2, 1 Action!" movie that
-- you've recorded. (The Action! movie must be open in QuickTime Player.) Enter the name of your
-- Action! movie in the property below.
-- When the recording ends, it will also play a "Cut!" movie that you've recorded.
-- (The Cut! movie must be open in QuickTime Player.) Enter the name of your
-- Cut! movie in the property below.
-- To control how this script behaves, use Script Editor to set these five properties:
property recordingTime : 30 -- set this to the desired recording time, in seconds
property ActionMovieName : "Action!.mov" -- optional. The name of your Action movie. Must be open.
property CutMovieName : "Cut! That's a wrap.mov" -- optional. The name of your Cut movie. Must be open.
property countdownBeeps : 5 -- set this to the desired countdown beeps before recording begins. Optional
property saveRecordingWhenDone : true -- save & close recording when done?
property savePlayFrontSoundOnly : "" -- Not set by user. Will be set by script.
tell application "QuickTime Player"
try
set weClickedRecordButton to false
-- save the user's QuickTime preference to play sound of front movie ONLY.
-- It will be restored later.
set savePlayFrontSoundOnly to only front movie plays sound
set only front movie plays sound to false -- so we can hear Action/Cut
activate
-- open recording window...
new movie recording
-- do countdown beeps, or play your own "5, 4, 3, 2, 1 Action!" movie
if ActionMovieName is not "" then
-- activate your own "Action!" movie window and play it
if exists window ActionMovieName then
rewind movie ActionMovieName -- so plays from beginning
play movie ActionMovieName
repeat while the playing of movie ActionMovieName
-- did user close recording window?
if name of window 1 is not "Movie Recording" then
stop movie ActionMovieName
error "Recording canceled."
end if
end repeat
end if
else -- play beeps instead
repeat countdownBeeps times
beep
delay 1
end repeat
end if
-- did user close recording window?
if name of window 1 is not "Movie recording" then error "Recording canceled."
-- use System Events to click Record button in window
tell application "System Events" -- see WARNING above if doesn't work
tell process "QuickTime Player"
tell window "Movie Recording"
click UI element 4
set weClickedRecordButton to true
end tell
end tell
end tell
-- limit the recording to <recordingTime> seconds
repeat recordingTime times
delay 1 -- one second
-- did user close recording window?
if name of window 1 is not "Movie recording" then error "Recording canceled."
end repeat
-- stop the recording
tell application "System Events"
tell process "QuickTime Player"
tell window 1
click UI element 4
end tell
end tell
delay 1
end tell
-- beep, or play your own Cut! movie
if CutMovieName is not "" then
if exists window CutMovieName then
play movie CutMovieName
repeat while the playing of movie CutMovieName
end repeat
end if
else
beep
end if
-- save the recording and close?
if saveRecordingWhenDone then
set tDefaultName to the name of window 1
set tPath to choose file name with prompt "Name movie" default name tDefaultName
-- if user cancels, error is returned here.
save window tDefaultName in tPath
close window tDefaultName without saving
end if
return "successful"
on error errMsg
-- restore QuickTime Player preference
if savePlayFrontSoundOnly is not "" then set only front movie plays sound to savePlayFrontSoundOnly
if exists window "Movie Recording" then
with timeout of 2 seconds
close window "Movie Recording" without saving
end timeout
end if
-- ignore canceled recordings
if "cancel" is not in errMsg then
if not weClickedRecordButton then set errMsg to "Unable to record movie. Check camera."
display dialog "Script Error: " & errMsg
end if
return errMsg
end try
end tell