What is wrong in this query?

Question

Hi All,
Could anybody please help me in identifying the issue in the below code as i am getting error as:
declare
ERROR at line 1:
ORA-01006: bind variable does not exist
ORA-06512: at "SYS.DBMS_SYS_SQL", line 846
ORA-06512: at "SYS.DBMS_SQL", line 52
ORA-06512: at line 14
Below is my code :
declare
vSql varchar2(1000);
vSal number(10);
vName varchar2(20) := 'King';
hcur number;
lexe number;
Begin
hcur := dbms_sql.open_cursor;
vSql := 'select salary into :sal from employees where last_name = :name ';
dbms_sql.parse(hcur,vsql,dbms_sql.native);
dbms_sql.bind_variable(hcur,':name',vname);
dbms_sql.bind_variable(hcur,':sal',vSal,10);
lexe := dbms_sql.execute(hcur);
Loop
exit when dbms_sql.fetch_rows(hcur) = 0;
dbms_sql.variable_value(hcur,':sal',vSal);
end loop;
dbms_sql.close_cursor(hcur);
end;

Answer 1

Tandra:
Sorry, there were a couple of errors in my code. This should work (I actually tested this time)
DECLARE   vsql VARCHAR2(1000);
   vsal NUMBER(10);
   vname VARCHAR2(20) := 'King';
   hcur NUMBER;
   lexe NUMBER;
BEGIN
   hcur := DBMS_SQL.Open_Cursor;
   vsql := 'select salary from employees where last_name = :name ';
   DBMS_SQL.Parse(hcur,vsql,DBMS_SQL.Native);
   DBMS_SQL.Define_Column(hcur, 1, vsal);
   DBMS_SQL.Bind_Variable(hcur,':name',vname);
   lexe := DBMS_SQL.Execute(hcur);
   LOOP
      EXIT WHEN DBMS_SQL.Fetch_Rows(hcur) = 0;
      DBMS_SQL.Column_Value(hcur, 1, vSal);
   END LOOP;
   DBMS_SQL.Close_Cursor(hcur);
END; You need to define the columns in the SELECT list of the query and match them with a variable of the correct type (the call to DBMS_SQL.Define_Column). Note that the variable noes not need to be the same one that you will alter use to get the column value (the call to DBMS_SQL.Column_Value), not does it need to be of the same length as the actual column, only the same type. For VARCHAR2, CHAR and RAW columns you need to pass the length of the column as well. A slightly more complex version:
SQL> DECLARE   vsql VARCHAR2(1000);
  2     vsal NUMBER(10);
  3     vname VARCHAR2(20) := 'King';
  4     vfirst VARCHAR2(20);
  5     hcur NUMBER;
  6     lexe NUMBER;
  7     x NUMBER;
  8     y VARCHAR2(1);
  9  BEGIN
10     hcur := DBMS_SQL.Open_Cursor;
11     vsql := 'select first_name, salary from employees where last_name = :name ';
12     DBMS_SQL.Parse(hcur,vsql,DBMS_SQL.Native);
13     -- Note the dummy variables x and y in the call to Define_Column
14     DBMS_SQL.Define_Column(hcur, 1, y, 20);
15     DBMS_SQL.Define_Column(hcur, 2, x);
16     DBMS_SQL.Bind_Variable(hcur,':name',vname);
17     lexe := DBMS_SQL.Execute(hcur);
18     LOOP
19        EXIT WHEN DBMS_SQL.Fetch_Rows(hcur) = 0;
20        DBMS_SQL.Column_Value(hcur, 2, vSal);
21        DBMS_SQL.Column_Value(hcur, 1, vfirst);
22        DBMS_OUTPUT.Put_Line('First name: '||vfirst||' Salary: '||vsal);
23     END LOOP;
24     DBMS_SQL.Close_Cursor(hcur);
25  END;
26  /
First name: Janette Salary: 10000
First name: Steven Salary: 24000
PL/SQL procedure successfully completed.Now, I'm off to write "I will not post untested code" 100 times on the whiteboard.
HTH
John