Why can't I move a variable declaration from inside a Sub to the Declarations area?

Question

I'm writing an app and so far, so good. But I need wider access to an array defined in my "Form_Load" sub.
Private Sub frmMain_Load(sender As Object, e As EventArgs) Handles MyBase.Load
' Assign checkboxes to an array.
Dim Checkboxes() As CheckBox = {chkThumb01, chkThumb02, chkThumb03, chkThumb04, _
chkThumb05, chkThumb06, chkThumb07, chkThumb08, chkThumb09, chkThumb10}
Moving the declaration ("Dim Checkboxes()...") from "Sub frmMain_Load" up into the Declarations space just above it breaks my program. :(
I tried putting it in a Module and that fails too. The ONLY place it work's is in Form_Load (it's not related to being an array because at least one standard integer variable declaration has this problem too.)
I have other variables in the Declarations area that work fine (eg: "Dim bolChanges as Boolean"), but for some reason, I can't move others out into what
should be a more global namespace.
Anyone know what's going on? Thx.

Answer 1

No, because this makes no difference.
Background #1: If you do not write your own constructor (=Sub New), the VB compiler adds a default constructor. It contains a call to Sub InitializeComponent. In this Sub, the controls are created and assigned to chkThumb01 etc. You see it if you type "Sub
New[Enter]":
Sub New()
InitializeComponent()
End Sub
Background #2: If you write
Public Class Test
Private values As Integer() = {1, 2, 3}
End Class
it is identical to
Public Class Test
Private values As Integer()
Sub New()
values = New Integer() {1, 2, 3}
End Sub
End Class
As you can see, the assignments that you do to fields of the class in the declaration line are actually executed in the constructor (sub new).
Now put both backgrounds together. Consequently, this code
Public Class Form1
Private buttons As Button() = {Button1, Button2, Button3}
End Class
is identical to this one:
Public Class Form1
Private buttons As Button()
Sub New()
buttons = New Button() {Button1, Button2, Button3}
InitializeComponent()
End Sub
End Class
Obviously, the assignment to variable "buttons" is done before the call to Sub InitializeComponent. At this point, variables Button1, Button2 and  Button3 are still empty (Nothing) because they will be set in Sub InitializeComponent. Consequently,
the array buttons contains just {Nothing, Nothing, Nothing}
In opposite, if the array buttons is set in the Load event, Button1, Button2 and Button3 have already been set before, Consequently, the array buttons correctly contains references to the three buttons.
Armin