Works within Automator, fails as service

Question

I'm still struggling to get Automator variables working correctly. Below actions work perfectly within Automator but fail when run as Service ("The action “Run AppleScript” encountered an error."). Myvar is a Storage Variable. I looked at dozens of posts on forum but unable to find a resolution.
Run AppleScript 1:
tell application "Automator"
set value of variable "myvar" in front workflow to "woooha"
end tell
Run AppleScript 2:
tell application "Automator"
set msg to get value of variable "myvar" of front workflow
end tell
tell application "System Events"
activate
display dialog msg
end tell

Answer 1

Apple has a AppleScript Studio Terminology Reference (Legacy) document (pdf) available. You can look up terminology from Automator and *Automator Runner* - the usage should be similar to the reference.
Following is a user defaults example - note that this should be saved as an application, otherwise the defaults will get saved to Automator's com.apple.Automator.plist instead of your application's plist. One test you can make is to get the *path to me*, and if it is the Automator application (e.g. Automator.app is in the path) then you are running from a workflow.
Example workflow (save as application):
1) *Get Specified Text* -- enter a few words separated by returns, for example:
          this
          is
          some
          testing
          text
2) *FIlter Paragraphs* { Return paragraphs that are not empty }
3) *Choose from List* -- when run, choose a few words to pass on to the script
4) *Run AppleScript*
<pre style="
font-family: Monaco, 'Courier New', Courier, monospace;
font-size: 10px;
font-weight: normal;
margin: 0px;
padding: 5px;
border: 1px solid #000000;
width: 720px; height: 340px;
color: #000000;
background-color: #DAFFB6;
overflow: auto;"
title="this text can be pasted into an Automator 'Run AppleScript' action">-- the defaults are saved in the com.apple.Automator.plist for a workflow (try not to do this)
-- the defaults are saved in com.apple.automator.YourApplicationNameHere.plist for an application
on run {input, parameters} -- user defaults example
-- format the input list (should be a few text items)
set tempTID to text item delimiters
set text item delimiters to space
set theInput to (input as text)
set text item delimiters to tempTID
-- some initial values
set someText to "some testing text this is" -- this will be the input text
set someNumber to 0 -- this number doesn't change
set anotherNumber to 0 -- 5 digits with leading zeros that increments each run
set theTime to time string of (current date) -- this will be the time the app was run last
tell user defaults
tell default entries
-- set up initial defaults entries
make new default entry at end with properties {name:"someText", contents:someText}
make new default entry at end with properties {name:"someNumber", contents:someNumber}
make new default entry at end with properties {name:"anotherNumber", contents:anotherNumber}
make new default entry at end with properties {name:"theTime", contents:theTime}
end tell
-- read current values
set someText to contents of default entry "someText"
set anotherNumber to contents of default entry "anotherNumber"
set theTime to contents of default entry "theTime"
end tell
display alert "default values read" message "someText:   " & someText & return & "someNumber:   " & someNumber & return & "prefix & time:   " & anotherNumber & tab & theTime
-- do something  (for this example, just change some values)
set someText to theInput
set anotherNumber to text -5 thru -1 of ((100000 + anotherNumber + 1) as text) -- leading zeros
set theTime to time string of (current date)
tell user defaults
-- save new values
set contents of default entry "someText" to someText
set contents of default entry "anotherNumber" to anotherNumber
set contents of default entry "theTime" to time string of (current date)
end tell
call method "synchronize" of object user defaults -- make sure everything updates
display alert "default values written" message "someText:   " & someText & return & "someNumber:   " & someNumber & return & "prefix & time:   " & anotherNumber & tab & theTime
return input
end run
</pre>
The above workflow will let you select a few words to input to the action, which will save them to the user defaults. Also saved is a number that gets incremented each run and the current time. To reset the defaults after experimenting, just delete the plist for your application - the plist will be recreated with default values as needed.