Would a 347 MB file be slow? Auto save and auto type turn off?

Question

I am doing an art inventory and add jpegs of the art. I don't resize them they range from 750k to 3MB. I guess if it is slowing the program down i should? It currently is 267 rows by about 18 columns.
Thanks in advance.
Oh can I turn off auto save and auto type? That may help. How do I do that?

Answer 1

Done.
Enter Scrip Editor
paste the posted script
File > Save > as Script  on the Desktop
Move the script to the folder :
Macintosh HD:Library:Scripts:Folder Action Scripts:
CAUTION, you will be asked to enter your pasword.
Create a folder to do the job. I named mine Normalized. I created mine on the Desktop where it's easy to reach.
Go to :
Macintosh HD:Library:Scripts:Folder Actions:
Double click the alias :  Configure Folder Actions
Below the left column, click
navigate to select your new folder
Below the right column, click
select the script image - normalize400.scpt
After that, drag and drop a picture file onto your folder.
The original will be move in the folder Originals (isn’t it original ?)
and a reduced copy  400 x height will be stored in the folder Normalized images.
And now, here is the script :
--{code}
Image - Normalize
This Folder Action handler is triggered whenever items are added to the attached folder.
The script rotates the image counter-clockwise (left).
Copyright © 2002–2007 Apple Inc.
You may incorporate this Apple sample code into your program(s) without
restriction.  This Apple sample code has been provided "AS IS" and the
responsibility for its operation is yours.  You are not permitted to
redistribute this Apple sample code as "Apple sample code" after having
made changes.  If you're going to redistribute the code, we require
that you make it clear that the code was descended from Apple sample
code, but that you've made changes.
modified by Yvan KOENIG (VALLAURIS, France)
2011/12/08
This version normalize pictures so that
(1) the greater dimension become the width one (rotate left if needed)
(2) this greater dimension is ruled by the property maxWidth defined below.
property maxWidth : 400
-- set it to fit your needs
property done_foldername : "Normalized Images"
property originals_foldername : "Original Images"
property newimage_extension : "jpg"
-- the list of file types which will be processed
-- eg: {"PICT", "JPEG", "TIFF", "GIFf"}
property type_list : {"TIFF", "GIFf", "PNGf", "PICT", "JPEG"}
-- since file types are optional in Mac OS X,
-- check the name extension if there is no file type
-- NOTE: do not use periods (.) with the items in the name extensions list
-- eg: {"txt", "text", "jpg", "jpeg"}, NOT: {".txt", ".text", ".jpg", ".jpeg"}
property extension_list : {"tif", "tiff", "gif", "png", "pict", "pct", "jpeg", "jpg"}
on adding folder items to this_folder after receiving these_items
          tell application "Finder"
                    if not (exists folder done_foldername of this_folder) then
  make new folder at this_folder with properties {name:done_foldername}
                    end if
                    set the results_folder to (folder done_foldername of this_folder) as alias
                    if not (exists folder originals_foldername of this_folder) then
  make new folder at this_folder with properties {name:originals_foldername}
                              set current view of container window of this_folder to list view
                    end if
                    set the originals_folder to folder originals_foldername of this_folder
          end tell
          try
                    repeat with i from 1 to number of items in these_items
                              set this_item to item i of these_items
                              set the item_info to the info for this_item
                              if (alias of the item_info is false and the file type of the item_info is in the type_list) or (the name extension of the item_info is in the extension_list) then
                                        tell application "Finder"
  --set name of this_item to "YK#" & (text -4 thru -1 of ("0000" & i))
                                                  my resolve_conflicts(this_item, originals_folder, "")
                                                  set the new_name to my resolve_conflicts(this_item, results_folder, newimage_extension)
                                                  set the source_file to (move this_item to the originals_folder with replacing) as alias
                                        end tell
  process_item(source_file, new_name, results_folder)
                              end if
                    end repeat
          on error error_message number error_number
                    if the error_number is not -128 then
                              tell application "Finder"
  activate
  display dialog error_message buttons {"Cancel"} default button 1 giving up after 120
                              end tell
                    end if
          end try
end adding folder items to
on resolve_conflicts(this_item, target_folder, new_extension)
          tell application "Finder"
                    set the file_name to the name of this_item
                    set file_extension to the name extension of this_item
                    if the file_extension is "" then
                              set the trimmed_name to the file_name
                    else
                              set the trimmed_name to text 1 thru -((length of file_extension) + 2) of the file_name
                    end if
                    if the new_extension is "" then
                              set target_name to file_name
                              set target_extension to file_extension
                    else
                              set target_extension to new_extension
                              set target_name to (the trimmed_name & "." & target_extension) as string
                    end if
                    if (exists document file target_name of target_folder) then
                              set the name_increment to 1
                              repeat
                                        set the new_name to (the trimmed_name & "." & (name_increment as string) & "." & target_extension) as string
                                        if not (exists document file new_name of the target_folder) then
  -- rename to conflicting file
                                                  set the name of document file target_name of the target_folder to the new_name
                                                  exit repeat
                                        else
                                                  set the name_increment to the name_increment + 1
                                        end if
                              end repeat
                    end if
          end tell
          return the target_name
end resolve_conflicts
-- this sub-routine processes files
on process_item(source_file, new_name, results_folder)
  -- NOTE that the variable this_item is a file reference in alias format
  -- FILE PROCESSING STATEMENTS GOES HERE
          try
  -- the target path is the destination folder and the new file name
                    set the target_path to ((results_folder as string) & new_name) as string
                    with timeout of 900 seconds
                              tell application "Image Events"
  launch -- always use with Folder Actions
                                        set this_image to open file (source_file as string)
                                        set {oldW, oldH} to dimensions of this_image
                                        if oldH > oldW then
                                                  set {oldW, oldH} to {oldH, oldW}
  rotate this_image to angle 270.0
                                        end if
                                        set |échelle| to maxWidth / oldW
                                        if |échelle| < 1 then scale this_image by factor |échelle|
  save this_image as JPEG in file target_path with icon
  close this_image
                              end tell
                    end timeout
          on error error_message
                    tell application "Finder"
  activate
  display dialog error_message buttons {"Cancel"} default button 1 giving up after 120
                    end tell
          end try
end process_item
--{code}
Yvan KOENIG (VALLAURIS, France)  jeudi 8 décembre 2011 21:25:33
iMac 21”5, i7, 2.8 GHz, 12 Gbytes, 1 Tbytes, mac OS X 10.6.8 and 10.7.2
My iDisk is : <http://public.me.com/koenigyvan>
Please : Search for questions similar to your own before submitting them to the community