Would Anyone Mind Giving A Few Tips To Make This Script More Robust?

Question

Hello. I haven't done any scripting before but I've written this script to run as a post-recording process in Audio Hijack Pro:
on process(theArgs)
-- This part of the script will disable any timers that are set to repeat exactly 7 days (±1 minute) after the recording started
-- Dates have the format "Monday 1 January 2007 12:00:00"
tell application "Audio Hijack Pro"
set allSessions to every session
repeat with eachSession in allSessions
set allTimers to every timer in eachSession
repeat with eachTimer in allTimers
try -- The try protects against empty values of "next run date"
set nextDate to word 1 of ((next run date of eachTimer) as string)
set nextDay to word 2 of ((next run date of eachTimer) as string)
set nextMonth to word 3 of ((next run date of eachTimer) as string)
set nextYear to word 4 of ((next run date of eachTimer) as string)
set nextHour to word 5 of ((next run date of eachTimer) as string)
set nextMin to word 6 of ((next run date of eachTimer) as string) as number
set weekOn to ((current date) + (60 * 60 * 24 * 7) - (duration of eachTimer)) -- This calculates the date in 7 days, less the duration of the timer
set weekOnDate to word 1 of (weekOn as string)
set weekOnDay to word 2 of (weekOn as string)
set weekOnMonth to word 3 of (weekOn as string)
set weekOnYear to word 4 of (weekOn as string)
set weekOnHour to word 5 of (weekOn as string)
set weekOnMin to word 6 of (weekOn as string) as number
if nextDate is equal to weekOnDate and nextDay is equal to weekOnDay and nextMonth is equal to weekOnMonth and nextYear is equal to weekOnYear and nextHour is equal to weekOnHour and nextMin is greater than (weekOnMin - 60) and nextMin is less than (weekOnMin + 60) then
set enabled of eachTimer to false
end if
end try
end repeat
end repeat
end tell
-- The script then goes on to import the recordings into iTunes (as wavs), set tags and copy the wavs up to the server
if class of theArgs is not list then -- This is a standard Audio Hijack Pro routine
set theArgs to {theArgs}
end if
set recordedFiles to {} -- This will protect against theArgs being changed by Audio Hijack Pro whilst this script is still running
set recordedFiles to theArgs
set convertedFileList to {} -- This will keep track of the paths to the imported files
tell application "iTunes"
set current encoder to encoder "WAV Encoder"
copy (convert recordedFiles) to trackList -- Do the conversion
if class of trackList is not list then
set trackList to {trackList}
end if
repeat with eachTrack in trackList -- Set the tags
set artist of eachTrack to "Theatre Archive"
set album of eachTrack to word 1 of ((name of eachTrack) as string)
set convertedFileList to convertedFileList & (location of eachTrack as alias)
end repeat
end tell
tell application "Finder"
repeat with eachFile in convertedFileList
-- This section (down to HERE) is a subroutine to delay the file copy until iTunes has finished creating the files
set currentSize to size of (info for eachFile)
delay 1
set latestSize to size of (info for eachFile)
repeat until currentSize is equal to latestSize -- Keep checking the size every second to see if it's stopped changing
set currentSize to size of (info for eachFile)
delay 1
set latestSize to size of (info for eachFile)
end repeat
-- ...HERE
duplicate eachFile to "Server HD:" as alias -- Copy the files up to the server
end repeat
end tell
end process
The idea is that it disables the repeating timer that created the recording (as I don't necessarily want it to repeat every week), converts the recording to wav in iTunes and then copies the wav up to our server. If I run it too many times in quick succession some files don't get converted, and then some wavs don't get copied to the server. I'd like to know a way of getting it to tell me why not!
Thanks for any advice you can give.
Rich

Answer 1

Since you specifically ask if people can make it 'more robust', it would help if you indicated which areas, if any, were of particular concern.
For example, does the script frequently fail in one particular area?
That would help narrow it down significantly. There's little point in people deeply analyzing code that works just fine.
If, on the other hand, you're looking for optimizations, there are several that come to mind.
Firstly, you're making repeated coercions of a date to a string in order to compare them. String comparisons for dates are inherently dangerous for many reasons.
For one, different users might have different settings for their date format.
Both "Monday May 28th 2007 1:02:03am" and "28th May 2007 1:02:03am" are valid coercions of a date to a string, depending on the user's preferences.
You might expect the former format whereas the current system settings use the latter so now 'word 1" returns "28th" rather than "Monday" as you expect.
The problem is exascerbated by the fact that since you're coercing to strings you're now using alphabetical sorting, not numeric sorting. This is critical because in an alpha sort "3rd" comes AFTER "20th" because the character '3' comes after the character '2'. However I'm guessing you'd want events on the 3rd of the month to be sorted before events on the 20th.
So the solution here is to throw away the entire block of code that does the date-to-string coercions. If my reading of the code and the expected values is correct it can all be reduced from:
<pre class=command>set nextDate to word 1 of ((next run date of eachTimer) as string)
set nextDay to word 2 of ((next run date of eachTimer) as string)
set nextMonth to word 3 of ((next run date of eachTimer) as string)
set nextYear to word 4 of ((next run date of eachTimer) as string)
set nextHour to word 5 of ((next run date of eachTimer) as string)
set nextMin to word 6 of ((next run date of eachTimer) as string) as number
set weekOn to ((current date) + (60 * 60 * 24 * 7) - (duration of eachTimer)) -- This calculates the date in 7 days, less the duration of the timer
set weekOnDate to word 1 of (weekOn as string)
set weekOnDay to word 2 of (weekOn as string)
set weekOnMonth to word 3 of (weekOn as string)
set weekOnYear to word 4 of (weekOn as string)
set weekOnHour to word 5 of (weekOn as string)
set weekOnMin to word 6 of (weekOn as string) as number
if nextDate is equal to weekOnDate and nextDay is equal to weekOnDay and nextMonth is equal to weekOnMonth and nextYear is equal to weekOnYear and nextHour is equal to weekOnHour and nextMin is greater than (weekOnMin - 60) and nextMin is less than (weekOnMin + 60) then
set enabled of eachTimer to false
end if</pre>
to:
<pre class=command>set nextDate next run date of eachTimer
set weekOn to ((current date) + (60 * 60 * 24 * 7) - (duration of eachTimer)) -- This calculates the date in 7 days, less the duration of the timer
if nextDate is greater than (weekOn - 60) and nextDate is less than (weekOn + 60) then
set enabled of eachTimer to false
end if</pre>
The next area of concern is your copying of the files to the server. I don't understand why you have all the delays and file size comparisons.
Given a list of aliases convertedFileList, you can simply:
<pre class=command>tell application "Finder"
duplicate convertedFileList to "Server HD" as alias
end tell</pre>
The Finder will copy all the files in one go and you don't need the repeat loop or the delays.