XSL recursion losing value problem.

Question

I've created an XSL stylesheet that i'm using to create a pie chart in svg. Each slice of the pie is done in a recursive call to the draw function. The slice number is passed to each recursive call with the value of counter + 1.
This seems to be pretty straight forward and working fine until I hit a for-each loop in the template. For some reason the for-each is setting the counter back to 1.
for example:
counter is now 2
<xsl:for-each select=...>
counter is now 1 for some reason
<xsl:call-template with param counter + 1
</xsl:for-each>
So the result is whenever the for-each is enter, counter has a value of 1.
attached is the actual stylesheet and a sample xml. I'm using oraxsl to do the transform.
<xsl:stylesheet version="1.0" type="text/xsl"
xmlns:xsl ="http://www.w3.org/1999/XSL/Transform"
xmlns:Mayura ="http://www.mayura.com/"
exclude-result-prefixes="Mayura">
<xsl:include href="CoolColors.xsl"/>
<xsl:include href="math.xsl"/>
<xsl:output standalone="yes" doctype-system="svg-19990812.dtd"
media-type="image/svg" indent="yes"/>
<xsl:template match="/">
<xsl:apply-templates select="/graph"/>
</xsl:template>
<xsl:template name="drawPie" match="graph">
<xsl:param name="x_origin" select="0"/>
<xsl:param name="y_origin" select="0"/>
<xsl:param name="gWidth" select="800"/>
<xsl:param name="gHeight" select="600"/>
<g id="pie chart" transform="translate({$x_origin}, {$y_origin})">
<xsl:variable name="count1" select="sum(values/value/@amount)"/>
count1 = <xsl:value-of select="$count1"/>
num_values = <xsl:value-of select="count(values/value)"/>
<xsl:call-template name="drawSlice">
<xsl:with-param name="x_origin" select="0"/>
<xsl:with-param name="y_origin" select="0"/>
<xsl:with-param name="gWidth" select="$gWidth"/>
<xsl:with-param name="gHeight" select="$gHeight"/>
<xsl:with-param name="counter" select="1"/>
</xsl:call-template>
</g>
</xsl:template>
<xsl:template name="drawSlice">
<xsl:param name="counter" select="1"/>
<xsl:param name="x_origin" select="0"/>
<xsl:param name="y_origin" select="0"/>
<xsl:param name="gWidth" select="800"/>
<xsl:param name="gHeight" select="600"/>
<xsl:param name="rotateMe" select="0"/>
DRAWSLICE1: <xsl:value-of select="$counter"/>
<xsl:for-each select="values/value">
DRAWSLICE2: <xsl:value-of select="$counter"/>
<xsl:if test="position()=$counter">
<xsl:call-template name="drawSlice">
<xsl:with-param name="counter" select="$counter + 1"/>
<xsl:with-param name="x_origin" select="$x_origin"/>
<xsl:with-param name="y_origin" select="$y_origin"/>
<xsl:with-param name="gWidth" select="$gWidth"/>
<xsl:with-param name="gHeight" select="$gHeight"/>
</xsl:call-template>
</xsl:if>
</xsl:for-each>
</xsl:template>
</xsl:stylesheet>
some xml for it is:
<?xml version = '1.0' encoding = 'UTF-8'?>
<graph width="600" height="400" type="PIE">
<legend font_size="14"/>
<title font_size="30" font_color="red" fill_color="red">Monthly PIRs</title>
<title2 font_size="20" font_color="red" fill_color="red">2001</title2>
<values>
<value name="JANUARY" amount="25">
<graph width="600" height="400" type="PIE">
<title> JANUARY</title>
<values>
<value name="ENGINEERING" amount="3"/>
<value name="NEW BUSINESS/PROGRAMS" amount="2"/>
<value name="OPERATIONS" amount="16"/>
<value name="QUALITY" amount="3"/>
<value name="SAFETY" amount="1"/>
</values>
</graph>
</value>
<value name="FEBRUARY" amount="14">
<graph width="600" height="400" type="PIE">
<title> FEBRUARY</title>
<values>
<value name="ENGINEERING" amoun t="4"/>
<value name="HUMAN RESOURCES" amount="1"/>
<value name="INFO SYSTEMS" amount="1"/>
<value name="OPERATIONS" amount="7"/>
<value name="QUALITY" amount="1"/>
</values>
</graph>
</value>
<value name="MARCH" amount="5">
<graph width="600" height="400" type="PIE">
<title>MARCH</title>
<values>
<value name="ENGINEERING" amount="1"/>
<value name="HUMAN RESOURCES" amount="1"/>
<value name="INFO SYSTEMS" amount="1"/>
<value name="OPERATIONS" amount="1"/>
<value name="QUALITY" amount="1"/>
</values>
</graph>
</value>
</values>
</graph>
I've deleted alot of stuff out of it. The important lines are the DRAWSLICE.
The expected output would have each value of DRAWSLICE1 = DRAWSLICE2, however if you run it you'll see that DRAWSLICE2 is always = 1.
Any help appreciated,
Jeff

Answer 1

The problem is related to the fact that a call-template does not change the current node or the current node list, while a for-each does.
When you recursively invoke call-template from within a for-each, you've changed the current node to I believe your <xsl:for-each select="values/value"> won't be finding what it thinks it will be finding.
I hope this working stylesheet gets you going in the right direction. Given your "jeff.xml" file, it produces the output:
<?xml version = '1.0' encoding = 'UTF-8'?>
<root>
<graph>
<slice name="JANUARY" amt="25" rel-id="1" abs-id="1">
<slice name="ENGINEERING" amt="3" rel-id="1" abs-id="2"/>
<slice name="NEW BUSINESS/PROGRAMS" amt="2" rel-id="2" abs-id="3"/>
<slice name="OPERATIONS" amt="16" rel-id="3" abs-id="4"/>
<slice name="QUALITY" amt="3" rel-id="4" abs-id="5"/>
<slice name="SAFETY" amt="1" rel-id="5" abs-id="6"/>
</slice>
<slice name="FEBRUARY" amt="14" rel-id="2" abs-id="7">
<slice name="ENGINEERING" amt="4" rel-id="1" abs-id="8"/>
<slice name="HUMAN RESOURCES" amt="1" rel-id="2" abs-id="9"/>
<slice name="INFO SYSTEMS" amt="1" rel-id="3" abs-id="10"/>
<slice name="OPERATIONS" amt="7" rel-id="4" abs-id="11"/>
<slice name="QUALITY" amt="1" rel-id="5" abs-id="12"/>
</slice>
<slice name="MARCH" amt="5" rel-id="3" abs-id="13">
<slice name="ENGINEERING" amt="1" rel-id="1" abs-id="14"/>
<slice name="HUMAN RESOURCES" amt="1" rel-id="2" abs-id="15"/>
<slice name="INFO SYSTEMS" amt="1" rel-id="3" abs-id="16"/>
<slice name="OPERATIONS" amt="1" rel-id="4" abs-id="17"/>
<slice name="QUALITY" amt="1" rel-id="5" abs-id="18"/>
</slice>
</graph>
</root>The stylesheet looks like:
<xsl:stylesheet version="1.0" xmlns:xsl ="http://www.w3.org/1999/XSL/Transform">
<xsl:output indent="yes"/>
<xsl:template match="/">
<root>
<xsl:apply-templates select="/graph"/>
</root>
</xsl:template>
<xsl:template match="graph">
<graph>
<xsl:apply-templates select="values/value" mode="drawSlice"/>
</graph>
</xsl:template>
<xsl:template match="value" mode="drawSlice">
<slice name="{@name}" amt="{@amount}"
rel-id="{position()}" abs-id="{count(preceding::value)+count(ancestor::value)+1}">
<xsl:apply-templates select="graph/values/value" mode="drawSlice"/>
</slice>
</xsl:template>
</xsl:stylesheet>I wasn't sure if you were trying to get the slice numbers to be relatively numbered to their siblings or absolutely numbered in document order, so I show both here.