XSLT stylesheet template for Endeca Records

Question

Endeca Forge provides a Record Adapter which can load XML data, transformed (if required) to Endeca's XML record format by an XML Stylesheet Template (XSLT). This provides a way of getting XML into Endeca with a minimum of fuss, for data analysis, PoCs and for modest amounts of XML data in production applications.
There was an XSLT template posted to Endeca Eden prior to the acquisition. The thread is still available at:
http://eden.endeca.com/web/eden/forums/message_boards/message/99120
Does anyone have a copy of the template?
TG

Answer 1

Hi TG,
Template XSLT below. Its main feature is that it attempts to be XSLT-agnostic, other than identification of the start-record element/x-path. It could be optimized for specific XML structures, or modified to support more complex XML data.
Note also the remarks about XSLT and larger XML data - as your XML source data gets larger, XSLT will become less attractive, and you'll want to implement a streaming or pull-parser approach (SAX, StAX).
Best
Brett
<?xml version="1.0" encoding="utf-8"?>
<!-- Copyright 2012 Oracle, Inc. All Rights Reserved. -->
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" indent="yes" doctype-system="records.dtd" />
     <!--
          ========== About this stylesheet ==========
          This is a generic stylesheet for transforming an XML file into the XML record format accepted by Endeca Forge.
          The stylesheet is designed to be reasonably agnostic about the source XML format: the main configuration required is to identify
          one or more repeating record elements in the source XML.  The stylesheet creates the root RECORDS element, enclosing one RECORD element for each
          repeating element.
          Each RECORD element is then assigned any number of PROP name-value pairs created for each property, with each PROP containing
          a NAME attribute and a PVAL.  The stylesheet effectively "flattens" the XML into a RECORD, recursively fetching sub-elements and creating
          properties named according to the hierarchical path (think XPath).
          ========== Stylesheet configuration ==========
          Add your base source repeating elements as an xpath selector at ADD RECORD SELECTORS HERE below.
          The default example in the template is "item", which suites an RSS 2.0 feed.
          By default, the template will use full path property names.  To change to simple property names, change the variable
          use-simple-prop-names below to true().
          You can also change the path dividers used in full property names - see path-divider and attribute-divider variables below.
          ========== Examples ==========
          The first example used is an RSS 2.0 feed (note that there are other Endeca adapters for this type of data).
          Using full property names, this will produce records with the following properties:
          rss_channel_item_title
          rss_channel_item_description
          rss_channel_item_link
          rss_channel_item_guid_@isPermaLink
          and so on.  With simple prop names, only the last part of the name is used (after the last _ or @).
          The second example (sample.xml and sample_records.xml) shows how nested repeating elements within a record are folded-down to
          a multi-value property.
     -->
     <!-- change select to true() to use simple prop names -->
     <xsl:variable name="use-simple-prop-names" select="false()" />
     <xsl:variable name="path-divider">
          <xsl:text>_</xsl:text>
     </xsl:variable>
     <xsl:variable name="attribute-divider">
          <xsl:text>_@</xsl:text>
     </xsl:variable>
     <xsl:template match="/">
          <xsl:element name="RECORDS">
               <!-- apply templates for each "repeating element" representing a single record -->
               <!-- ADD RECORD SELECTORS HERE -->
               <xsl:apply-templates select="//item" />
          </xsl:element>
     </xsl:template>
     <!-- one template with RECORD element for each template type applied above -->
     <xsl:template match="item">
          <xsl:element name="RECORD">
               <xsl:call-template name="leaves-auto-subpaths" />
          </xsl:element>
     </xsl:template>
    <!-- calls the prop template for each leaf -->
    <xsl:template name="leaves-auto-subpaths">
        <!-- select all attributes-->
        <xsl:for-each select="@*">
            <xsl:call-template name="prop" />
        </xsl:for-each>
        <!-- select all leaf nodes -->
        <xsl:for-each select="*[not(*) and . != '']">
            <xsl:call-template name="prop" />
        </xsl:for-each>
        <!-- auto recurse subpaths -->
        <xsl:for-each select="*[*]|*[@*]">
            <xsl:call-template name="leaves-auto-subpaths" />
        </xsl:for-each>
    </xsl:template>
    <!-- creates the PROP element and calls prop-name and prop-pval -->
    <xsl:template name="prop">
        <xsl:element name="PROP">
             <xsl:if test="$use-simple-prop-names">
                  <xsl:call-template name="prop-name-simple" />
             </xsl:if>
             <xsl:if test="not($use-simple-prop-names)">
                  <xsl:call-template name="prop-name-full" />
             </xsl:if>
            <xsl:call-template name="prop-pval" />                 
        </xsl:element>
    </xsl:template>
    <!-- creates the NAME element -->
    <xsl:template name="prop-name-simple">
        <xsl:attribute name="NAME">
            <xsl:value-of select="name()" />
        </xsl:attribute>
    </xsl:template>
    <!-- creates the NAME attribute -->
    <xsl:template name="prop-name-full">
        <xsl:attribute name="NAME">
             <!-- walk from root to current node, print name and underscore  -->
            <xsl:for-each select="ancestor-or-self::*">
                <xsl:value-of select="name()" />
                <xsl:if test="position() != last()">
                    <xsl:value-of select="$path-divider" />
                </xsl:if>
            </xsl:for-each>
            <!-- pick up attributes -->
            <xsl:if test="not(namespace::*)">
                <xsl:value-of select="$attribute-divider" />
                <xsl:value-of select="name()" />
            </xsl:if>
        </xsl:attribute>
    </xsl:template>
    <!-- creates the PVAL element -->  
    <xsl:template name="prop-pval">
        <xsl:element name="PVAL">
            <xsl:value-of select="." />
        </xsl:element>
    </xsl:template>
</xsl:stylesheet>