XSLT Trasnformation (Error message)

Question

Hi,
I want to create a xslt transformation for xml. I have a string field where i have included the content of this xml.
When i want to call the transformation i get the message error in the debugger.
"Bei XML-ABAP Transformation wurde das Element abap erwartet."
In english it means that he excepted the element abap for the xslt transformation.
Here is my xslt transformation:
<xsl:transform version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:sap="http://www.sap.com/sapxsl"
xmlns:asx="http://www.sap.com/abapxml">
<xsl:output method="xml"/>
<xsl:template match="*">
<xsl:if test="@DateTime">
    <xsl:value-of select="@DateTime"/>
</xsl:if>
<xsl:if test="@ReaderID">
    <xsl:value-of select="@ReaderID"/>
</xsl:if>
</xsl:template>
</xsl:transform>
In this transformation I want to get the value of the tags date time and readerid, but i'm not sure ift the coding of my xslt is really ok.
Thanks in advance for your help.
Muhammet

Answer 1

Hi Muhammet,
I think now I understand your problem: 
You want a list of pmlcore:Tag data and each one contains the information of pmlcore:DateTime and the ReaderID element - but both elements are not children of pmlcore:Tag.
Of course this is possible in XSLT. Therefore there is an own language called XPath that address elements within the whole XML tree. You already used XPath within the select-Attribute in xsl:for-each, xsl:value-of and in xsl:template, too.
There are a lot of possibilities to solve this problem in XPath:
<xsl:transform version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:pmlcore="urn:autoid:specification:interchange:PMLCore:xml:schema:1" xmlns:pmluid="urn:autoid:specification:universal:Identifier:xml:schema:1">
  <xsl:template match="/">
    <asx:abap xmlns:asx="http://www.sap.com/abapxml" version="1.0">
      <asx:values>
        <ROOT>
          <LIST>
            <xsl:for-each select="/pmlcore:Sensor/pmlcore:Observation/pmlcore:Tag">
              <item>
                 <ID><xsl:value-of select="string(pmluid:ID)"/></ID>
                 <DATATIME><xsl:value-of select="string(../pmlcore:DateTime)"/></DATATIME>
                 <READERID>
                    <xsl:value-of select="string(../pmlcore:Data/pmlcore:XML/ReaderID)"/>
                 </READERID>
              </item>
            </xsl:for-each>
          </LIST>
        </ROOT>
      </asx:values>
    </asx:abap>
  </xsl:template>
</xsl:transform>
In this case I changed the result of the transformation (i.e. the ABAP structure). For the sake of simplicity I used a local structure but you can also create those types within the DDIC. We deserialize a list. Within each item there are four elements: ID, DATATUME and READERID. Because we want an entry for each tag we use xsl:foreach. The ID element gets the value for the pmluid:ID child. DATATIME and READERID are not within the same pmlcore:Tag elements because the belong to pmlcore:Observation . In XPath we can adress the this parent element using ".." and so the XPath expresseion for the wanted element is ../pmlcore:DateTime resp. ../pmlcore:Data/pmlcore:XML/ReaderID.
And this is the result:
<asx:abap xmlns:asx="http://www.sap.com/abapxml" xmlns:pmlcore="urn:autoid:specification:interchange:PMLCore:xml:schema:1" xmlns:pmluid="urn:autoid:specification:universal:Identifier:xml:schema:1" version="1.0">
  <asx:values>
    <ROOT>
      <LIST>
        <item>
          <ID>300833B2DDD9048035050000</ID>
          <DATATIME>2008-07-04T17:41:26</DATATIME>
          <READERID>Readpoint 1</READERID>
        </item>
        <item>
          <ID>3114F4E4E4BA2C2B15000000</ID>
          <DATATIME>2008-07-04T17:41:26</DATATIME>
          <READERID>Readpoint 1</READERID>
        </item>
      </LIST>
    </ROOT>
  </asx:values>
</asx:abap>
Please remark that the values for DATATIME and READERID are the same because there is only one observation in your sample document.
Of course there are even more possibilities. Now I show  a completly different and more generic approach that produces the same result:
<xsl:transform version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:pmlcore="urn:autoid:specification:interchange:PMLCore:xml:schema:1" xmlns:pmluid="urn:autoid:specification:universal:Identifier:xml:schema:1">
  <xsl:template match="/">
    <asx:abap xmlns:asx="http://www.sap.com/abapxml" version="1.0">
      <asx:values>
        <ROOT>
          <LIST>                         
            <xsl:apply-templates select="/pmlcore:Sensor/pmlcore:Observation/pmlcore:Tag"/>
          </LIST>
        </ROOT>
      </asx:values>
    </asx:abap>
  </xsl:template>
  <xsl:template match="/pmlcore:Sensor/pmlcore:Observation/pmlcore:Tag">
    <item>
      <ID><xsl:value-of select="string(pmluid:ID)"/></ID>
       <DATATIME><xsl:value-of select="string(../pmlcore:DateTime)"/></DATATIME>
       <READERID><xsl:value-of select="string(../pmlcore:Data/pmlcore:XML/ReaderID)"/></READERID>
    </item>
  </xsl:template>     
</xsl:transform>
Here we define two templates. The first matches for the root-element and then starts the processing using xsl:apply-templates for a specific set of nodes. Then the XSL processor select those nodes and looks for a certain template to apply - i.e. the second template in our case. With these techniques you can create very generic transformations and with the help of recursion you can code very elegant and powerful transformations.