How to pass ranges to the subroutine

Question

hi all,
my requirement is i need a write a program where i am having fields like kunnr, matnr, maktx, customer name etc.
the user gives any of above values in diff input boxes (parameter).
for every text entry that gets, i need to populate the value of the (maktx, customer name, etc) in ranges. for different kinds of  entries i want to write the subroutine since i am carrying out the same functionality for all the inputs that i get.
is it possible to do?

Answer 1

My 2 cents, if you don't want to use macros: define a FORM routine, as follows:
FORM fill_range  USING    i_parameter TYPE any
                 CHANGING et_range    TYPE table.
  CONSTANTS:
    lc_sign   TYPE bapisign VALUE 'I',
    lc_option TYPE bapioption VALUE 'EQ'.
  FIELD-SYMBOLS:
    <sign>     TYPE bapisign,
    <option>   TYPE bapioption,
    <low>      TYPE ANY,
    <ls_range> TYPE ANY.
  DATA:
    lr_range TYPE REF TO data.
You may want to catch exceptions starting from here
  CREATE DATA lr_range LIKE LINE OF et_range.
  ASSIGN lr_range->* TO <ls_range>.
  ASSIGN COMPONENT 'SIGN'   OF STRUCTURE <ls_range> TO <sign>.
  ASSIGN COMPONENT 'OPTION' OF STRUCTURE <ls_range> TO <option>.
  ASSIGN COMPONENT 'LOW'    OF STRUCTURE <ls_range> TO <low>.
  <sign>   = lc_sign.
  <option> = lc_option.
  <low>    = i_parameter.
ENDCATCH.
  APPEND <ls_range> TO et_range.
ENDFORM.                    " fill_range
Assuming that your parameter is called p_matnr, and the range you want to fill is lr_matnr, you would call this routine as follows:
PERFORM fill_range
  USING
    p_matnr
  CHANGING
    lr_matnr[].
This may seem tremendously complicated, but it's clean, fast, "debuggable", and it works.
Greetz
Rainer