IPhoto Import Script

Question

I am attempting to write a script (droplet) that when I drop a folder on it, it will import the photos in that folder into iPhoto into an album name that is the name of the folder I dropped on it. Here is what I have so far:
--on open (this_folder)
tell application "Finder"
set this_folder to name of (choose folder)
set AlbumName to this_folder
end tell
tell application "iPhoto"
activate
if not (exists (album AlbumName)) then
new album name AlbumName
end if
set the_album to album AlbumName
import from this_folder to the_album without force copy
end tell
--end open
I have a question about the "on open" piece. If I uncomment it out and change the (choose folder) to this_folder, I get the error "can't get name of alias...", but as it is above it can get the name of the alias.
How do I turn what I have into what I need?

Answer 1

on open (dragged_Items) -- 'dragged_Items' assumes a list of folders only.
tell application "iPhoto" -- Use 'iPhoto' commands.
activate -- Launch and bring forth 'iPhoto'.
repeat with i in dragged_Items -- Cycle through list of dragged items.
-- Obtain name of item i..
tell application "Finder" to set folder_Name to (name of i)
display dialog folder_Name
-- Create new album (based on dragged folders' name) if not already exists.
if not (exists (album folder_Name)) then new album name folder_Name
-- Import 'this_folder's contents.
import from i to album folder_Name without force copy
end repeat
end tell
end open
  Mac OS X (10.4.4)