Read info about files in specific folder into internal table

Question

Hi Experts
I need to have last modified date and filename information read into an internal table. I need to read in the information of all files in a specific (UNIX) folder (I do not know the name of the single files).
I really hope someone can help.
Thanks a lot
Kind regards,
Torben

Answer 1

Hi Guys
Thanks a lot for you input.
I managed to get my program to works as follows:
REPORT  ZDELETE_ARCHIVING_FILES.
*Step 1: Get the list of files in the directory into internal table :
DATA: DLIST    LIKE EPSFILI OCCURS 0 WITH HEADER LINE,
      DPATH    LIKE EPSF-EPSDIRNAM,
      MDATE    LIKE SY-DATUM,
      MTIME    LIKE SY-UZEIT.
DATA: BEGIN OF FATTR OCCURS 0,
          FILE_NAME  LIKE EPSF-EPSFILNAM,
          FILE_SIZE  LIKE EPSF-EPSFILSIZ,
          FILE_OWNER LIKE EPSF-EPSFILOWN,
          FILE_MODE  LIKE EPSF-EPSFILMOD,
          FILE_TYPE  LIKE EPSF-EPSFILTYP,
          FILE_MTIME(12),
      END OF FATTR.
DATA: P_PATH(50) TYPE C.
CONCATENATE '/ARCHIVE/' sy-sysid '/archive' INTO P_PATH.
*        WRITE: / P_PATH.
DPATH = P_PATH.
*Get files in folder - read into internal table DLIST
*if filenames are longer than 40 characters
*then use FM SUBST_GET_FILE_LIST.
CALL FUNCTION 'EPS_GET_DIRECTORY_LISTING'
     EXPORTING
          DIR_NAME               = DPATH
     TABLES
          DIR_LIST               = DLIST
     EXCEPTIONS
          INVALID_EPS_SUBDIR     = 1
          SAPGPARAM_FAILED       = 2
          BUILD_DIRECTORY_FAILED = 3
          NO_AUTHORIZATION       = 4
          READ_DIRECTORY_FAILED  = 5
          TOO_MANY_READ_ERRORS   = 6
          EMPTY_DIRECTORY_LIST   = 7
          OTHERS                 = 8.
IF SY-SUBRC EQ 0.
*Step 2: Read the file attributes into an internal table
*Read info about the files (attributes) into the internal table FATTR
*as we need info about the last time it was changed (MTIME)
  LOOP AT DLIST.
    CALL FUNCTION 'EPS_GET_FILE_ATTRIBUTES'
         EXPORTING
              FILE_NAME              = DLIST-NAME
              DIR_NAME               = DPATH
         IMPORTING
              FILE_SIZE              = FATTR-FILE_SIZE
              FILE_OWNER             = FATTR-FILE_OWNER
              FILE_MODE              = FATTR-FILE_MODE
              FILE_TYPE              = FATTR-FILE_TYPE
              FILE_MTIME             = FATTR-FILE_MTIME
         EXCEPTIONS
              READ_DIRECTORY_FAILED  = 1
              READ_ATTRIBUTES_FAILED = 2
              OTHERS                 = 3.
    IF SY-SUBRC EQ 0.
      FATTR-FILE_NAME = DLIST-NAME.
      APPEND FATTR.
    ENDIF.
  ENDLOOP.
  SORT FATTR BY FILE_NAME.
  DATA: time(10), date LIKE sy-datum.
  DATA: months TYPE i.
  DATA: e_file TYPE string.
  LOOP AT FATTR.
  CLEAR: time, months, e_file.
    IF FATTR-FILE_NAME(10) = 'archive_BW'.
*Convert the unix time into readable time
      PERFORM p6_to_date_time_tz(rstr0400) USING FATTR-FILE_MTIME
                                                 time
                                                 date.
*Calculate the number of months between date (MTIME) and current day
*ex 31.03.2009 - 01.04.2009 = 1 month
*ex 01.02.2009 - 01.04.2009 = 2 month
    CALL FUNCTION 'MONTHS_BETWEEN_TWO_DATES'
      EXPORTING
        i_datum_von = date
        i_datum_bis = sy-datum
      IMPORTING
        e_monate = months.
        CONCATENATE DPATH '/' FATTR-FILE_NAME INTO e_file.
*        WRITE: / FATTR-FILE_NAME,
*                 FATTR-FILE_SIZE,
*                 date,
*                 time,
*                 sy-datum,
*                 months,
*                 e_file.
*Step 3: Delete files where months > 1
      IF months > 1.
        OPEN dataset e_file for output in text mode encoding default.
        DELETE dataset e_file.
        CLOSE dataset e_file.
      ENDIF. "months > 1
    ENDIF.
  ENDLOOP.
ENDIF.