Using variable coulmn name in sql function

Question

Hi there,
I am not an expert with PL/SQL and I can not figure out how to use variable column names in my function.
My function is:
CREATE OR REPLACE FUNCTION RESET_TRIGGERS(aTrigger VARCHAR2) RETURN NUMBER IS
TEMP_ID NUMBER;
TEMP_USER_ID NUMBER;
BEGIN
SELECT 'LIMS.'||'$aTrigger'||'.NEXTVAL' INTO TEMP_ID FROM DUAL;
SELECT 'LIMS.'||'$aTrigger'||'_USER.NEXTVAL' INTO TEMP_USER_ID FROM DUAL;
IF TEMP_ID > TEMP_USER_ID THEN
LOOP
SELECT LIMS.SQ_U_FINALRESULT_USER.NEXTVAL INTO TEMP_USER_ID FROM DUAL;
EXIT WHEN TEMP_USER_ID = TEMP_ID;
END LOOP;
ELSE
WHILE TEMP_ID < TEMP_USER_ID LOOP
SELECT LIMS.SQ_U_FINALRESULT.NEXTVAL INTO TEMP_ID FROM DUAL;
END LOOP;
END IF;
COMMIT;
RETURN (TEMP_ID);
END;
What I want is that I pass a seqencename with aTrigger and that two triggers will be equal if not.
eg ifaTrigger = 'SQ_U_FINALRESULT'
than I want the triggers LIMS.SQ_U_FINALRESULT and LIMS.SQ_U_FINALRESULT_USER to be set equal.
The above function will not work, but what will?????
I hope you can help me out!
Cheers

Answer 1

A very strange function indeed.
But here is what I think he meant to do:
SQL> create procedure reset_sequences
  2  ( p_sequence_name in  varchar2
  3  , p_nextval          out number
  4  )
  5  is
  6    l_nextval1 number;
  7    l_nextval2 number
  8    ;
  9    procedure reset_sequence_value
10    ( p_sequence_name in varchar2
11    , p_current_value in number
12    , p_new_value     in number
13    )
14    is
15      l_dummy number;
16    begin
17      execute immediate 'alter sequence ' || p_sequence_name || ' increment by ' || to_char(p_new_value-p_current_value);
18      execute immediate 'select ' || p_sequence_name || '.nextval from dual' into l_dummy;
19      execute immediate 'alter sequence ' || p_sequence_name || ' increment by 1';
20    end reset_sequence_value
21    ;
22  begin
23    execute immediate
24      'select ' || p_sequence_name || '.nextval,' || p_sequence_name || '_user.nextval from dual'
25    into l_nextval1, l_nextval2
26    ;
27    if l_nextval1 < l_nextval2
28    then
29      reset_sequence_value(p_sequence_name,l_nextval1,l_nextval2);
30    end if
31    ;
32    if l_nextval1 > l_nextval2
33    then
34      reset_sequence_value(p_sequence_name || '_user',l_nextval2,l_nextval1);
35    end if
36    ;
37    p_nextval := greatest(l_nextval1,l_nextval2)
38    ;
39  end reset_sequences;
40  /
Procedure is aangemaakt.
SQL> show err
Er zijn geen fouten.
SQL> create sequence testseq start with 5 increment by 1
  2  /
Reeks is aangemaakt.
SQL> create sequence testseq_user start with 2 increment by 1
  2  /
Reeks is aangemaakt.
SQL> declare
  2    l_new_value number;
  3  begin
  4    reset_sequences('testseq',l_new_value);
  5    dbms_output.put_line(l_new_value);
  6  end;
  7  /
5
PL/SQL-procedure is geslaagd.
SQL> select testseq.currval from dual
  2  /
                               CURRVAL
                                     5
1 rij is geselecteerd.
SQL> select testseq_user.currval from dual
  2  /
                               CURRVAL
                                     5
1 rij is geselecteerd.Regards,
Rob.