3061 Error related to an parameter query

Question

Hi,
I see I am not the only one encountering the 3061 error, but I would not be surprised I could be the only one not understanding how to solve it..
J
I am using the below function in a module XX (this is curtesy of Mr DbGuy) .
In query X , field B I have the following parameter referring to form C. [Forms]![FRUITS_FORM]![FRUIT_COMBO]
I do not understand how to apply previous suggestion in the below context. All this process is to be triggered from Button XX in Form XX.
Public Function SimpleCSV(strSQL As String, _
            Optional strDelim As String = " OR ") As String
'Returns a comma delimited string of all the records in the SELECT SQL statement
'Source: http://accessmvp.com/thedbguy
'v1.0 - 8/20/2013
Dim db As DAO.Database
Dim rs As DAO.Recordset
Dim strCSV As String
Set db = CurrentDb()
Set rs = db.OpenRecordset(strSQL, dbOpenSnapshot)
'Concatenate the first (and should be the only one) field from the SQL statement
With rs
    Do While Not .EOF
        strCSV = strCSV & strDelim & .Fields(0)
        .MoveNext
    Loop
    .Close
End With
'Remove the leading delimiter and return the result
SimpleCSV = Mid$(strCSV, Len(strDelim) + 1)
Set rs = Nothing
Set db = Nothing
End Function

Answer 1

If the SQL statement being passed into the function as a string expression references a query with parameters you won't be able to do that with this function as it stands.  Where it is necessary to establish a recordset object on the basis of a query
with parameters then you must firstly evaluate the parameters by looping though the querydef object's Parameters collection, and then call the OpenRecordset method of the querydef object.  Here's code snippet which illustrates this:
    Dim dbs As DAO.Database
    Dim rst As DAO.Recordset
    Dim qdf As DAO.QueryDef
    Dim prm As DAO.Parameter
    Set dbs = CurrentDb
    Set qdf = dbs.QueryDefs(strQuery)
    For Each prm In qdf.Parameters
        prm = Eval(prm.Name)
    Next prm
    Set rst = qdf.OpenRecordset
However, you have no reference to a querydef object in the code, so you'd need to amend the function to create a temporary querydef object on the basis of the SQL statement, whose parameters you can evaluate as above, and then call its OpenRecordset method.
Ken Sheridan, Stafford, England