About web.show_document

Question

Hi to All,
Before: I use the release 10g 10.1.2.0.2 R2.
In a Form that initialize Parameters, I have the procedure Start_Report calling with button:
PROCEDURE Start_Report IS
  rep_id     REPORT_OBJECT ;
  v_rep      VARCHAR2(256);
  rep_status VARCHAR2(100);
  vjob_id           VARCHAR2(100);
  Cursor C_REP IS
  Select   *
  From     REPORTS
  Where    REP_CODICE = :REP.REP_LIST ;
  LR$Rec   C_REP%ROWTYPE ;
  LC$Target Varchar2(128) ;
  pl_id     ParamList ;
  pl_name   Varchar2(10) := 'REPTMP' ;
  LN$Params Pls_integer := 0 ;
BEGIN
  Open  C_REP ;
  Fetch C_REP Into LR$Rec ;
  Close C_REP ;
  pl_id := Create_Parameter_List(pl_name);
  LC$Target := Nvl( LR$Rec.REP_DESNOME, 'c:\reports\report.pdf' ) ;
  rep_id := find_report_object('REP');
  SET_REPORT_OBJECT_PROPERTY(rep_id, REPORT_FILENAME, LR$Rec.REP_NOME);
  SET_REPORT_OBJECT_PROPERTY(rep_id, REPORT_SERVER, LR$Rec.REP_SERVER);
  If LR$Rec.REP_EXEC_MODO = 'BATCH' Then
    SET_REPORT_OBJECT_PROPERTY(rep_id, REPORT_EXECUTION_MODE, BATCH);
  Else
       SET_REPORT_OBJECT_PROPERTY(rep_id, REPORT_EXECUTION_MODE, RUNTIME);
  End if ;
  If LR$Rec.REP_COMUN_MODO = 'SYNCHRONOUS' Then
    SET_REPORT_OBJECT_PROPERTY(rep_id, REPORT_COMM_MODE, SYNCHRONOUS);
  Else
    SET_REPORT_OBJECT_PROPERTY(rep_id, REPORT_COMM_MODE, ASYNCHRONOUS);
  End if ;
  If LR$Rec.REP_DESTIPO = 'FILE' Then
    SET_REPORT_OBJECT_PROPERTY(rep_id, REPORT_DESTYPE, FILE);
  ElsIf LR$Rec.REP_DESTIPO = 'PRINTER' Then
    SET_REPORT_OBJECT_PROPERTY(rep_id, REPORT_DESTYPE, PRINTER);       
  ElsIf LR$Rec.REP_DESTIPO = 'MAIL' Then
    SET_REPORT_OBJECT_PROPERTY(rep_id, REPORT_DESTYPE, MAIL);       
  ElsIf LR$Rec.REP_DESTIPO = 'CACHE' Then     
    SET_REPORT_OBJECT_PROPERTY(rep_id, REPORT_DESTYPE, CACHE);       
  End if ;
  If LR$Rec.REP_DESTIPO = 'FILE' Then
    SET_REPORT_OBJECT_PROPERTY(rep_id, REPORT_DESNAME, LC$Target );
  End if ;
  SET_REPORT_OBJECT_PROPERTY(rep_id, REPORT_DESFORMAT, LR$Rec.REP_DESFORMATO);
  -- Set the parameters --
    For i IN PKG_VARS.TB_Params.First .. PKG_VARS.TB_Params.Last Loop
         If PKG_VARS.TB_Items(i) IS NOT NULL Then
        Add_Parameter( pl_id, PKG_VARS.TB_Params(i).REP_PAR_REP_NOME, TEXT_PARAMETER, Name_In( PKG_VARS.TB_Items(i) ) ) ;
        LN$Params := LN$Params + 1 ;
         End if ;
    End loop ;
  If LN$Params > 0 Then
        v_rep := RUN_REPORT_OBJECT( rep_id, pl_id );
  Else
     v_rep := RUN_REPORT_OBJECT( rep_id );
  End if ;
  -- Run the report --
  vjob_id := substr(v_rep, length(LR$Rec.REP_SERVER)+2, length(v_rep));
  rep_status := REPORT_OBJECT_STATUS(v_rep);
  IF rep_status = 'FINISHED' THEN
       WEB.SHOW_DOCUMENT ('/reports/rwservlet/getjobid' || vjob_id || '?server='||LR$Rec.REP_SERVER,'_blank');
  ELSE
       DISP_ALERT(2, v_rep, rep_status);
  END IF;
  If NOT Id_Null(pl_id) Then
    Destroy_Parameter_List( pl_id ) ;
  End if ;
  Exception
       When Others Then
      If NOT Id_Null(pl_id) Then
         Destroy_Parameter_List( pl_id ) ;
      End if ;       
END;When this procedure run, this ALERT is displayed (DISP_ALERT):
Report <ServerReport+ReportNumber> failed with status ENQUEUED
I have inspect in the Application Server Control Console and the report <ReportNumber> is correctly created.
The Property of Report are BATCH, ASYNCHRONOUS, CACHE, PDF
Can You help me ?
Best Regards
Gaetano

Answer 1

Hello,
If you use the properties :
BATCH, ASYNCHRONOUS, CACHE, PDF
it means that RUN_REPORT_OBJECT will NOT wait for the Reports execution completion to return.
So, the bahaviour here is normal ..
If you don't want to get this alert, use SYNCHRONOUS mode ...
Regards