Add three stored procs in one big proc and add exception handling

Question

I have three proc's,
1. sp_staging
2.  sp_upload
3. sp_process.
Now, I have to create a new proc as sp_daily which has the other three proc's in it in the same order.
if the first proc sp_staging fails, then the sp_daily proc should stop executing the other proc's which are in the order.
CREATE PROCEDURE sp_daily
AS
BEGIN TRY
EXEC sp_staging (already has EXCEPTION handling IN it)
GO
EXEC sp_upload (already has EXCEPTION handling IN it)
GO
EXEC sp_process (already has EXCEPTION handling IN it)
GO
END TRY
BEGIN CATCH
-- If any of the above proc's fail, the next proc's should not be executed
END CATCH
Something like this????

Answer 1

Hi naveej,
Whether the Stored Procedure sp_daily stops executing if the first sp_staging fails depends on how you code. To give a better demonstration, I will show the scenario that sp_upload runs with error. Please see the below code.
--create the scenario
USE master;
IF db_id('TestDB') IS NULL
CREATE DATABASE TestDB;
USE TestDB;
IF OBJECT_ID('T1') IS NOT NULL
DROP TABLE T1;
GO
CREATE TABLE T1
procName varchar(99)
IF OBJECT_ID('sp_staging') IS NOT NULL
DROP PROCEDURE "sp_staging";
GO
CREATE PROCEDURE "sp_staging" @denominator FLOAT
AS
BEGIN TRY
DECLARE @quotient FLOAT;
SET @denominator=1/@denominator; -- when @denominator=0, error occurs
INSERT INTO T1 VALUES('sp_staging finished');
END TRY
BEGIN CATCH
END CATCH
GO
IF OBJECT_ID('sp_upload') IS NOT NULL
DROP PROCEDURE "sp_upload";
GO
CREATE PROCEDURE "sp_upload" @denominator FLOAT
AS
BEGIN TRY
DECLARE @quotient FLOAT;
SET @denominator=1/@denominator;
INSERT INTO T1 VALUES('sp_upload finished');
END TRY
BEGIN CATCH
DECLARE @ERRMSG VARCHAR(99);
SELECT @ERRMSG=ERROR_MESSAGE()+'sp_upload failed, process continues';
INSERT INTO T1 VALUES(@ERRMSG);
END CATCH
GO
IF OBJECT_ID('sp_process') IS NOT NULL
DROP PROCEDURE "sp_process";
GO
CREATE PROCEDURE "sp_process" @denominator FLOAT
AS
BEGIN TRY
DECLARE @quotient FLOAT;
SET @denominator=1/@denominator;
INSERT INTO T1 VALUES('sp_process finished');
END TRY
BEGIN CATCH
END CATCH
GO
IF OBJECT_ID('sp_daily') IS NOT NULL
DROP PROCEDURE "sp_daily";
GO
CREATE PROCEDURE "sp_daily" @p1Deno FLOAT,@p2Deno FLOAT,@p3Deno FLOAT
AS
BEGIN TRY
EXEC sp_staging @p1Deno;
EXEC sp_upload @p2Deno;
EXEC sp_process @p3Deno;
END TRY
BEGIN CATCH
INSERT INTO T1 SELECT ERROR_MESSAGE()+'error captured by sp_daily';
END CATCH
GO
--Test Example
TRUNCATE TABLE T1;
EXEC sp_daily 1,0,1;
SELECT * FROM T1;
We can judge from the rows in T1, sp_daily continued even when there came a error in sp_upload. The reason for the continuity is that the error which occurred in sp_upload was caught and handled by  sp_upload itself. Sp_daily's CATCH block didn't capture
any error(we didnt see any row like "error captured by sp_daily") so  sp_dailys continued running with no interruption.
Let’s make a little modification on the sp_upload. see the below code.
ALTER PROCEDURE "sp_upload" @denominator FLOAT
AS
BEGIN TRY
DECLARE @quotient FLOAT;
SET @denominator=1/@denominator;
INSERT INTO T1 VALUES('sp_upload');
END TRY
BEGIN CATCH
DECLARE @ERRMSG VARCHAR(99),@ErrSeverity INT;
SELECT @ERRMSG=ERROR_MESSAGE()+'sp_upload failed, process got terminated',@ErrSeverity=ERROR_SEVERITY();
RAISERROR(@ERRMSG ,@ErrSeverity,1);
END CATCH
GO
--Test Example
TRUNCATE TABLE T1;
EXEC sp_daily 1,0,1;
SELECT * FROM T1;
At this time,  sp_daily got terminated when  sp_upload encountered an error. Sp_upload didn’t handle the error, it threw the error instead. Then the CATCH block in  sp_daily caught  the error and interrupted sp_daily itself. If you don’t
need to handle the error which may occur inside of the inner called procedures, the TRY and CATCH block in the procedure which calls them would be enough to catch and handle the errors anywhere it occurs, just remove the blocks from the called ones.
ALTER PROCEDURE "sp_staging" @denominator FLOAT
AS
DECLARE @quotient FLOAT;
SET @denominator=1/@denominator;
INSERT INTO T1 VALUES('sp_staging finished');
GO
ALTER PROCEDURE "sp_upload" @denominator FLOAT
AS
DECLARE @quotient FLOAT;
SET @denominator=1/@denominator;
INSERT INTO T1 VALUES('sp_upload finished');
GO
ALTER PROCEDURE "sp_process" @denominator FLOAT
AS
DECLARE @quotient FLOAT;
SET @denominator=1/@denominator;
INSERT INTO T1 VALUES('sp_process finished');
GO
ALTER PROCEDURE "sp_daily" @p1Deno FLOAT,@p2Deno FLOAT,@p3Deno FLOAT
AS
BEGIN TRY
EXEC sp_staging @p1Deno;
EXEC sp_upload @p2Deno;
EXEC sp_process @p3Deno;
END TRY
BEGIN CATCH
INSERT INTO T1 SELECT ERROR_MESSAGE();
END CATCH
GO
--Test Example
TRUNCATE TABLE T1;
EXEC sp_daily 1,0,1;
SELECT * FROM T1;
As we can see from the above modification,  sp_daily calls  sp_staging, sp_upload, sp_process in order. Sp_staging runs fine so it finishes. When it comes to sp_upload, error gets captured so the execution terminates. Anyway if you hope that the 3
called procedures  work atomically(it is a pretty common business requirement), which means unless all of the three finish otherwise no one finishes, the TRAN block would help. Please see the below code.
ALTER PROCEDURE "sp_daily" @p1Deno FLOAT,@p2Deno FLOAT,@p3Deno FLOAT
AS
BEGIN TRY
BEGIN TRAN
EXEC sp_staging @p1Deno;
EXEC sp_upload @p2Deno;
EXEC sp_process @p3Deno;
COMMIT TRAN;
END TRY
BEGIN CATCH
ROLLBACK TRAN;
INSERT INTO T1 SELECT ERROR_MESSAGE();
END CATCH
GO
--Test Example
TRUNCATE TABLE T1;
EXEC sp_daily 1,0,1;
SELECT * FROM T1;
If you have question, feel free to let me know.
Best Regards,
Eric Zhang