Adding events in calendar from numbers or text file

Question

Hey guys,
Ive had a look around and it seems like theres a few similar requests, but I'm not great at scripting and the like.
Essentially we have our shifts in either .txt or .numbers format and am just wanting to import them into ical as events with a start time, end time, location and name.
Any help or direction would be greatly appreciated.
I've attached a copy of what i get, hopefully its helpful.
Thnaks, Ben.

Answer 1

Had to guess about your Numbers table format. You mention start, end, location, and "name" but I can only see start and end.
If you have a source table in Numbers somewhat like this:
start date
end date
location
summary
9/15/14 12:00:00 PM
9/15/14 1:00:00 PM
The office
Event Title 1
9/15/14 2:00:00 PM
9/15/14 3:00:00 PM
The office
Event Title 2
Then a script like this should work (copy into AppleScript Editor, click anywhere in source table, and run):
property calendarName : "Test" -- name of target calendar -- must exist in Calendar App
property firstDataRow : 2 -- 2 if have a Header Row in table
-- map these to column numbers in your table:
property sdtCol : 1 --  start date-time column number
property edtCol : 2 --  end date-time column number
property locCol : 3 -- location column number
property summCol : 4 -- summary (title) column number
property localTimeAdj : (time to GMT) -- to convert back to local time
tell application "Numbers"
  set t to front document's active sheet's first table whose selection range's class is range
  set vv to t's rows's cells's value -- place values in "list of lists"
  repeat with r from firstDataRow to count vv
   tell vv's item r
    try
     set startDT to (item sdtCol) - localTimeAdj
     set endDT to (item edtCol) - localTimeAdj
     set locat to item locCol
     set summary to item summCol
   end try
   if item 1 is not missing value then my createEvent(calendarName, summary, startDT, endDT, locat)
   end tell
  end repeat
end tell
to createEvent(calName, cSumm, cStart, cEnd, cLoc)
  tell application "Calendar"
   tell (first calendar whose name is calName)
    make new event at end of events with properties ¬
  {summary:cSumm, start date:cStart, end date:cEnd, location:cLoc}
   end tell
  end tell
end createEvent
Usage notes:
Be sure to click somewhere in the table before running the script. Otherwise it won't know which table you mean.
This assumes you have Numbers 3.  Numbers 2 would require some adjustments.
Be sure to edit the calendarName property to match the name of your target calendar in the Calendar app, and the other properties to match your table.
SG