Address Book - find and display person

Question

I want to check whether a person in my database is also in the Address Book. I am using:
tell application "Address Book"
set theCount to 0
set firstName to "Joe"
set lastName to "Public"
try
set theCount to count (every person whose (first name is firstName) and (last name is lastName))
end try
if theCount is 0 then
display dialog "no person found" buttons {"none"} default button 1
else
set thePerson to (first person whose (first name is firstName) and (last name is lastName))
-- display the right card here
display dialog "Person found" buttons {"OK"} default button 1
end if
end tell
This finds the correct person if they exist, but the displayed record is not changed. Anyone know the trick?
PowerMac G4 MDD   Mac OS X (10.4.5)  

Answer 1

Paul Berkowitz, a rather brilliant AS scripter, suggested the following trick:
open location "addressbook://" & theID
theID being the unique ID of a person in addressbook.
so...
--begin script
tell application "Address Book"
set theCount to 0
set firstName to "Joe"
set lastName to "Public"
try
set theCount to count (every person whose (first name is firstName) and (last name is lastName))
end try
if theCount is 0 then
display dialog "no person found" buttons {"none"} default button 1
else
set thePerson to id of (first person whose (first name is firstName) and (last name is lastName))
my ShowPerson(thePerson)
display dialog "Person found" buttons {"OK"} default button 1
end if
end tell
on ShowPerson(theID)
open location "addressbook://" & theID
end ShowPerson
--end script
The reason I used a handler (the on showperson bit) is that the open location is not understood by AddressBook, so I "outsourced" that bit to a handler.
HTH,
J.