Again..What elapse time you are expecting for this query..

Question

Hi Again want to confirm with you Oracle gurus ...
Does following plsql code really takes time in mins
I do not used to deal with clob data so can not say why there is so delay..
-> TableA has 3000 rows with text_data clob column holding large clob data...
-> TableB has some thing which i wnat to append in text_data column..
-> Trying to minimize elapse time..
declare
cursor c1 is select object_id from TableA where object_type = 'STDTEXT' and rownum < 1000;
TYPE v_object_id_t is table of TableA.object_id%type index by binary_integer;
v_object_id v_object_id_t;
cursor c2(p_object_id TableA.object_id%type) is
select to_clob('<IMG "MFI_7579(@CONTROL=' || ref_id || ',REF_ID=' || ref_id || ').@UDV">' || substr('abcdefghijklmnopqrstuvwxyzabcdefghijklmnopqrstuvwx',1, round(to_char(systimestamp,'FF2')/2)-1)) temp_data
from TableB where object_id = p_object_id;
TYPE v_text_data_t is table of TableA.text_data%type index by binary_integer;
v_text_data v_text_data_t;
v_temp clob ;
r2 c2%rowtype;
begin
open c1;
loop
FETCH c1 BULK COLLECT INTO v_object_id ;
for i in 1..v_object_id.count loop
dbms_lob.createtemporary(v_temp,TRUE);
open c2(v_object_id(i));
loop
fetch c2 into r2;
exit when c2%NOTFOUND;
dbms_lob.append(v_temp,r2.temp_data);
end loop;
close c2;
v_text_data(i) := '';
v_text_data(i) := v_temp;
-- DBMS_OUTPUT.PUT_LINE (length(v_text_data(i)));
dbms_lob.freetemporary(v_temp);
end loop;
forall counter in 1..v_text_data.count
update TableA
set text_data = concat(text_data,v_text_data(counter))
where object_id = v_object_id(counter);
DBMS_OUTPUT.PUT_LINE ('Update performed!');
commit;
EXIT WHEN c1%NOTFOUND;
end loop;
close c1;
exception
when others then
DBMS_OUTPUT.PUT_LINE ('Update not performed!');
end;
-- Last elapse time 333 sec for 8k text_data data if i use 16k block size
-- Last elapse time 1503 sec for 2k text_data data if i use 8k block size
->> Am I going rigth way???
Please Help...
Cheers :)
Rushang Kansara
Message was edited by:
Rushang Kansara
Message was edited by:
Rushang Kansara

Answer 1

Here is an example that shows SQL and PL/SQL methods. Note that the DBMS_LOB.WriteAppend() call is the wrong call to use (as I did above. The correct call to use (for appending CLOB to a CLOB) is DBMS_LOB.Append() (as shown below).
SQL> create table my_docs
2 (
3 doc_id number,
4 doc CLOB
5 )
6 /
Table created.
SQL>
SQL> create sequence id
2 start with 1
3 increment by 1
4 nomaxvalue
5 /
Sequence created.
SQL>
SQL>
SQL> create or replace procedure AddXML( rowCount number DEFAULT 1000 ) is
2 cursor curXML is
3 select
4 XMLElement( "ORA_OBJECT",
5 XMLForest(
6 object_id as "ID",
7 owner as "OWNER",
8 object_type as "TYPE",
9 object_name as "NAME"
10 )
11 ) as "XML_DATA"
12 from all_objects
13 where rownum <= rowCount;
14
15 tmpClob CLOB;
16 xml XMLType;
17 lineCount number := 0;
18 docID number;
19 begin
20 DBMS_LOB.CreateTemporary( tmpClob, TRUE );
21
22 open curXML;
23 loop
24 fetch curXML into xml;
25 exit when curXML%NOTFOUND;
26
27 lineCount := lineCount + 1;
28
29 DBMS_LOB.Append(
30 tmpClob,
31 xml.GetCLOBVal() -- add the XML CLOB to our temp CLOB
32 );
33 end loop;
34 close curXML;
35
36 insert
37 into my_docs
38 ( doc_id, doc )
39 values
40 ( id.NextVal, tmpClob )
41 returning doc_id into docID;
42
43 commit;
44
45 DBMS_LOB.FreeTemporary( tmpClob );
46 DBMS_OUTPUT.put_line( lineCount||' XML object(s) were appended to document '||docID );
47 end;
48 /
Procedure created.
SQL> show errors
No errors.
SQL>
SQL> -- add 3 CLOBs of varying sizes
SQL> exec AddXML
1000 XML object(s) were appended to document 1
PL/SQL procedure successfully completed.
SQL> exec AddXML(100)
100 XML object(s) were appended to document 2
PL/SQL procedure successfully completed.
SQL> exec AddXML(500)
500 XML object(s) were appended to document 3
PL/SQL procedure successfully completed.
SQL>
SQL> -- what are the sizes of the CLOBs and the total size?
SQL> select
2 doc_id,
3 SUM( ROUND( LENGTH(doc)/1024 ) ) as "KB_SIZE"
4 from my_docs
5 group by
6 ROLLUP(doc_id)
7 /
DOC_ID KB_SIZE
1 98
2 9
3 47
154
SQL>
SQL> -- add an empty CLOB
SQL> insert into my_docs values( 0, NULL );
1 row created.
SQL> commit;
Commit complete.
SQL>
SQL> -- note that the new CLOB is zero KB in size
SQL> select
2 doc_id,
3 ROUND( LENGTH(doc)/1024 ) as "KB_SIZE"
4 from my_docs
5 /
DOC_ID KB_SIZE
1 98
2 9
3 47
0
SQL>
SQL> -- we add document 1 to 3 to document 0 using SQL
SQL> update my_docs
2 set doc = doc || (select t.doc from my_docs t where t.doc_id = 1 )
3 where doc_id = 0;
1 row updated.
SQL>
SQL> update my_docs
2 set doc = doc || (select t.doc from my_docs t where t.doc_id = 2 )
3 where doc_id = 0;
1 row updated.
SQL>
SQL>
SQL> update my_docs
2 set doc = doc || (select t.doc from my_docs t where t.doc_id = 3 )
3 where doc_id = 0;
1 row updated.
SQL>
SQL> commit;
Commit complete.
SQL>
SQL> -- what are the sizes now?
SQL> select
2 doc_id,
3 ROUND( LENGTH(doc)/1024 ) as "KB_SIZE"
4 from my_docs
5 /
DOC_ID KB_SIZE
1 98
2 9
3 47
0 154
SQL>
SQL>
SQL> -- we do the adds again, but time time using a PL/SQL procedure to do it
SQL> declare
2 cursor c is
3 select doc from my_docs where doc_id in (1,2,3);
4
5 updateClob CLOB;
6 appendClob CLOB;
7 begin
8 -- we must lock the row for update and then we can write directly
9 -- to that row's CLOB locator (without using the UPDATE SQL statement)
10 select
11 doc into updateClob
12 from my_docs
13 where doc_id = 0
14 for update;
15
16
17 open c;
18 loop
19 fetch c into appendClob;
20 exit when c%NOTFOUND;
21
22 -- we append the CLOBs to document 0
23 DBMS_LOB.Append( updateClob, appendClob );
24 end loop;
25
26 -- .. and commit the changes to document 0's CLOB locator
27 commit;
28 end;
29 /
PL/SQL procedure successfully completed.
SQL>
SQL>
SQL> -- what are the sizes now?
SQL> select
2 doc_id,
3 ROUND( LENGTH(doc)/1024 ) as "KB_SIZE"
4 from my_docs
5 /
DOC_ID KB_SIZE
1 98
2 9
3 47
0 308
SQL>