Aged Debt Analysis by Sales Employee

Question

Hi Experts
I would like to be able to show our customer receivables ageing report by sales employee.  Can any of the experts suggest how to write a query which give me the same information but can limited by a user defined choice of the sales employee for the business partner.  This is required as on the road sales employees require information of outstanding debt of BPs before making further sales.
Regards
Jon

Answer 1

The following is filtered to show only Business Partner Balances for On Hold customers, but you should be able to tweak it for your purposes? Give it a try
/* SELECT FROM OINV T0 */
declare @AgingDate DateTime
/* WHERE */
SELECT @AgingDate = GetDate()
/* SELECT FROM OCRD T1 */
declare @CustomerFrom nvarchar(20)
/* WHERE */
set @CustomerFrom /* T1.CardCode */ = '' 
/* SELECT FROM OCRD T2 */
declare @CustomerTo nvarchar(20)
/* WHERE */ set @CustomerTo /* T2.CardCode */ = '' 
/* SELECT FROM OCRD T3 */
declare @OnHold nvarchar(20)
/* WHERE */ set @OnHold /* T3.FrozenFor */ = 'Y' 
/* SELECT FROM OSLP T4 */
declare @SalesRep nvarchar(30)
/* WHERE */
set @SalesRep /* T4.SlpName */ = [%0]
IF @AgingDate = CONVERT(datetime, '', 112)
            set @AgingDate = GetDate() 
select ocrd.CardCode [BP Code], 
        ocrd.CardName [BP Name],  
        ocrd.FrozenFor [On Hold], 
        @AgingDate [Aging Date], 
        isnull(T7.[BalanceDue],0) [Balance], 
        isnull(T7.[Current],0) [Current], 
        isnull(T7.[30Days],0) [1 Month], 
        isnull(T7.[60Days],0) [2 Months], 
        isnull(T7.[90Days],0) [3+ Months],                     
        ocrd.CreateDate, 
        T8.[Last Payment Date], 
        ( SELECT SUM(T1.DocTotal) FROM ORCT T1 WHERE T1.CardCode = T8.CardCode AND T1.DocDate = T8.[Last Payment Date]) [Total Last Payment],
        oslp.SlpName [Sales Rep], 
        ocrd.CntctPrsn [Key Contact], 
        ISNULL(ocpr.Tel1, ISNULL(ocpr.Cellolar, ocrd.Phone1)) [Contact Phone]
from ocrd   
        left outer join ocpr on ocpr.Name = ocrd.CntctPrsn and ocpr.CardCode = ocrd.CardCode  
        left outer join oslp on oslp.SlpCode = ocrd.SlpCode  
        left outer join   (
                    SELECT T0.CardCode,
                            SUM(T1.Original-T1.Cleared) [BalanceDue],
                            SUM(CASE WHEN T1.AgeDays < 0 THEN T1.Original+T1.Cleared ELSE 0 END) [Current],
                            SUM(CASE WHEN T1.AgeDays BETWEEN 0 AND 30 THEN T1.Original+T1.Cleared ELSE 0 END) [30Days],
                            SUM(CASE WHEN T1.AgeDays BETWEEN 31 AND 60 THEN T1.Original+T1.Cleared ELSE 0 END) [60Days],
                            SUM(CASE WHEN T1.AgeDays > 60 THEN T1.Original+T1.Cleared ELSE 0 END) [90Days],
                            SUM(CASE WHEN T1.AgeDays > 30 THEN T1.Original+T1.Cleared ELSE 0 END) [Overdue]
                    FROM ocrd T0
                            LEFT OUTER JOIN (
                                        SELECT T1.CardCode, T0.TransId, T0.Line_ID,
                                                DateDiff(m, T0.DueDate, @AgingDate) [AgeMonths],
                                                DateDiff(d, T0.DueDate, @AgingDate) [AgeDays],
                                                T0.Debit-T0.Credit [Original],
                                                SUM(ISNULL(T2.ReconSum,0)* CASE T2.IsCredit WHEN N'C' THEN 1 ELSE -1 END) [Cleared],
                                                (T0.Debit-T0.Credit) + SUM(ISNULL(T2.ReconSum,0)* CASE T2.IsCredit WHEN N'C' THEN 1 ELSE -1 END) [Balance]
                                        FROM jdt1 T0   
                                                inner join ocrd T1 on T1.CardCode = T0.ShortName
                                                left outer join itr1 T2 on T2.TransId = T0.TransId and T2.TransRowId = T0.Line_ID and T2.ReconNum = (select T3.ReconNum from oitr T3 where T3.ReconNum = T2.ReconNum and T3.Canceled = N'N' and T3.ReconType <> 7 and T3.ReconDate <= @AgingDate)
                                        WHERE T0.RefDate <= @AgingDate                                                                               
and T1.CardType = 'C'
                                                and (T1.CardCode >= @CustomerFrom OR @CustomerFrom = '')  
                                                and (T1.CardCode <= @CustomerTo OR @CustomerTo = '')  
                                        GROUP BY T1.CardCode, T0.TransId, T0.Line_ID, T0.DueDate, T0.Debit-T0.Credit
                                   ) T1 on T1.CardCode = T0.CardCode
                    WHERE T0.CardType = N'C'                                                     
                    GROUP BY T0.CardCode
            ) T7 on T7.CardCode = ocrd.CardCode
        left outer join (  
                    SELECT T1.CardCode,          
                                Max(T1.DocDate) [Last Payment Date]        
                    FROM ORCT T1        
                    WHERE (T1.CardCode >= @CustomerFrom OR @CustomerFrom = '')          
                                and (T1.CardCode <= @CustomerTo OR @CustomerTo = '')       
                    GROUP BY T1.CardCode  
               ) T8 on T8.CardCode = ocrd.CardCode
where ocrd.CardType = 'C'  
            and (oslp.SlpName = @SalesRep OR @SalesRep = '')  
            and (ocrd.CardCode >= @CustomerFrom OR @CustomerFrom = '')  
            and (ocrd.CardCode <= @CustomerTo OR @CustomerTo = '')  
               and (ocrd.ValidFor <>'Y')
            and ( (ocrd.FrozenFor = @OnHold
                         and (GetDate() Between isnull(ocrd.FrozenFrom, DateAdd(d,-1,GetDate())) and isnull(ocrd.FrozenTo, DateAdd(d,1,GetDate())))))
order by ocrd.CardCode