Aim to process all files in folders on desktop to run through photoshop and save in multiple locations

Question

Aim to process all files in folders on desktop to run through photoshop and save in multiple locations
Part one:-
Gather information from desktop to get brand names and week numbers from the folders
Excluding folders on desktop beginning with "2" or "Hot"
Not sure about the list of folders
but I have got this bit to work with
set folderPath to "Hal 9000:Users:matthew:Desktop:DIVA_WK30_PSD" --<<this would be gained from the items on the desktop
set {oldTID, my text item delimiters} to {my text item delimiters, ":"}
set folderName to last text item of folderPath
set my text item delimiters to "_WK"
set FolderEndName to last text item of folderName
set brandName to first text item of folderName
set my text item delimiters to "_PSD"
set weekNumber to first text item of FolderEndName
set my text item delimiters to oldTID
After running this I have enough information to create folders in multiple locations, (i need to know where they are so that photoshop can later save them in those multiple locations
So I need the following folders created
Locally
Hal 9000:Users:matthew:Pictures:2011-2012:"WK" + weekNumber
Hal 9000:Users:matthew:Pictures:2011-2012:"WK" + weekNumber: brandName
Hal 9000:Users:matthew:Pictures:2011-2012:"WK" + weekNumber: brandName: brandName + "_WK" + weekNumber + "_LR" --(Set path for Later)PathA
Hal 9000:Users:matthew:Pictures:2011-2012:"WK" + weekNumber: brandName: brandName + "_WK" + weekNumber + "_HR"--(Set path for Later)PathB
Network
Volumes:GEN:Brands:Zoom:Brands - Zoom:Upload Photos:2012:"Week" + weekNumber
Volumes:GEN:Brands:Zoom:Brands - Zoom:Upload Photos:2012:"Week" + weekNumber:brandName + "_WK" + weekNumber + "_LR"  --(Set path for Later)PathC
Volumes:GEN:Website_Images --(no need to create folder just set path)PathD
FTP (Still as a normal Volume) So like another Network
Volumes:impulse:"Week" + weekNumber
Volumes:impulse:"Week" + weekNumber:Brand
Volumes:impulse:"Week" + weekNumber:Brand:brandName + "_WK" + weekNumber + "_LR"  --(Set path for Later)PathE
Volumes:impulse:"Week" + weekNumber:Brand:brandName + "_WK" + weekNumber + "_HR"  --(Set path for Later)PathF
I like to think that is end of Part 1
Part 2
Take the images  (PSD's) from those folders relevant to the Brand then possibly run more applescript that opens flattens and then saves it in the locations above.
For example….
An image in folder DIVA_WK30_PSD will then run an applescript in Photoshop, lets call it DivaProcessImages within this we then save to PathA, PathB, PathC, PathD, PathE, PathF the folder path of C should therefore look like this
Volumes:GEN:Brands:Zoom:Brands - Zoom:Upload Photos:2012:Week30:DIVA_WK30_LR and of course save the image as original filename.
Then from the next folder
An image in folder Free_WK30_PSD will then run an applescript in Photoshop, lets call it FreeProcessImages within this we then save to PathA, PathB, PathC, PathD, PathE, PathF the folder path of C should therefore look like this
Volumes:GEN:Brands:Zoom:Brands - Zoom:Upload Photos:2012:Week30:Free_WK30_LR and of course save the image as original filename.
The photoshop applescript i'm hoping will be easier as it should be a clearer step by step process without any if's and but's
Now for the coffee!!

Answer 1

Hi,
MattJayC wrote:
Now to the other part, where each folder was created (and those that already existed) how do I set them as varibles?
For example,
set localBrandFolder_High_Res to my getFolderPath(brandName & "_WK" & weekNumber & "_HR", localBrandFolder)
This line was used to create more than one folder as it ran though the folders on the desktop. The next part is I will need to reference them to save files to them.
You can use a records
Examples
if you want the path of localBrandFolder_High_Res  of "Diva", if "Diva" is the second folder of the Desktop
You get the path with this : localBrandFolder_High_Res of record 2 of myRecords
if you want the path of localWeekFolder  in the first folder of the Desktop
You get the path with this : localWeekFolder of record 1 of myRecords
Here is the script
set myRecords to {}
set dtF to paragraphs of (do shell script "ls -F ~/Desktop | grep '/' | cut -d'/' -f1")
repeat with i from 1 to number of items in dtF
    set this_item to item i of dtF
    if this_item does not start with "2_" and this_item does not start with "Hot" then
        try
            set folderPath to this_item
            set {oldTID, my text item delimiters} to {my text item delimiters, ":"}
            set folderName to last text item of folderPath
            set my text item delimiters to "_WK"
            set FolderEndName to last text item of folderName
            set brandName to first text item of folderName
            set my text item delimiters to "_PSD"
            set weekNumber to first text item of FolderEndName
            set my text item delimiters to oldTID
        end try
        try
            set this_local_folder to "Hal 9000:Users:matthew:Pictures:2011-2012"
            set var1 to my getFolderPath("WK" & weekNumber, this_local_folder)
            set var2 to my getFolderPath(brandName, var1)
            set var3 to my getFolderPath(brandName & "_WK" & weekNumber & "_LR", var2)
            set var4 to my getFolderPath(brandName & "_WK" & weekNumber & "_HR", var2)
            --set up names to destination folders and create over Netwrok including an already exisiting folder
            set this_Network_folder to "DCKGEN:Brands:Zoom:Brand - Zoom:Upload Photos:2012:"
            set var5 to my getFolderPath("WK" & weekNumber, this_Network_folder)
            set var6 to my getFolderPath(brandName, var5)
            set var7 to my getFolderPath(brandName & "_WK" & weekNumber & "_LR", var6)
            set website_images to "DCKGEN:Website_Images:"
            --set up names to destination folders and create over Netwrok for FTP collection (based on a mounted drive)
            set this_ftp_folder to "Impulse:"
            set var8 to my getFolderPath("Week" & weekNumber, this_ftp_folder)
            set var9 to my getFolderPath(brandName, var8)
            set var10 to my getFolderPath(brandName & "_WK" & weekNumber & "_LR", var9)
            set var11 to my getFolderPath(brandName & "_WK" & weekNumber & "_HR", var9)
            set end of myRecords to ¬
  {localWeekFolder:var1, localBrandFolder:var2, localBrandFolder_Low_Res:var3, localBrandFolder_High_Res:var4, networkWeekFolder:var5, networkBrandFolder:var6, networkBrandFolder_Low_Res:var7, ftpWeekFolder:var8, ftpBrandFolder:var9, ftpBrandFolder_Low_Res:var10, ftpBrandFolder_High_Res:var11}
        end try
    end if
end repeat
localBrandFolder_High_Res of record 2 of myRecords -- get full path of localBrandFolder_High_Res in the second folder of Desktop
on getFolderPath(tName, folderPath)
    tell application "Finder" to tell folder folderPath
        if not (exists folder tName) then
            return (make new folder at it with properties {name:tName}) as string
        else
            return (folder tName) as string
        end if
    end tell
end getFolderPath