ALV not getting refreshed when call screen is executed second time

Question

I have 2 screens 9001 and 9002. In 9001 , I am displaying the fields of a database table in a Table Control. The user has to select some of those fields and click on a button 'Generate ALV'. After clicking , the control navigates to 9002 where I am displaying ALV with data in the selected fields(the other fields remain empty). (using custom container)
Now there is BACK button in 9002 where i have written LEAVE TO SCREEN  9001. After this if the user again make changes in column selection and click on 'Generate ALV' , then still the old alv data is displayed. (Mind you the structure of alv is same , only the selected fields should show data).
I am using REFRESH_ALV_DISPLAY also and when i tested this function independently , its working fine (although for interactive alv in the same screen).
I am making use of <fs> for dynamic internal table and i checked it using breakpoints , during the 2nd time , it contains the correctly updated data so i think the problem lies with alv
Kindly check this code
MODULE STATUS_9002 OUTPUT.
  SET PF-STATUS 'ZALV'.
*  SET TITLEBAR 'xxx'.
  CREATE OBJECT C_CONT
    EXPORTING
      CONTAINER_NAME               = 'CUST_CONT'
  IF SY-SUBRC <> 0.
*   MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*              WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
  ENDIF.
IF OBJ_ALV IS INITIAL.
  CREATE OBJECT OBJ_ALV
    EXPORTING
      I_PARENT           = C_CONT
  CALL METHOD OBJ_ALV->SET_TABLE_FOR_FIRST_DISPLAY
     EXPORTING
       I_STRUCTURE_NAME              = INP_TABLE
     CHANGING
      IT_OUTTAB                      = <itab>
ELSE.
   CALL METHOD OBJ_ALV->REFRESH_TABLE_DISPLAY
  ENDIF.
ENDMODULE.                 " STATUS_9002  OUTPUT
Edited by: amber22 on Sep 16, 2011 6:45 PM

Answer 1

Amber,
Something like:
*&      Module  STATUS_9001  OUTPUT
MODULE status_9001 OUTPUT.
  SET PF-STATUS 'ST9001'.
ENDMODULE.                 " STATUS_9001  OUTPUT
*&      Module  USER_COMMAND_9001  INPUT
MODULE user_command_9001 INPUT.
  CASE sy-ucomm.
    WHEN 'GEN'.
      SELECT * FROM spfli INTO TABLE gt_outtab.
      CALL SCREEN 9002.
    WHEN 'BACK'.
      LEAVE.
  ENDCASE.
ENDMODULE.                 " USER_COMMAND_9001  INPUT
*&      Module  STATUS_9002  OUTPUT
MODULE status_9002 OUTPUT.
  SET PF-STATUS 'ST9002'.
  IF obj_alv IS INITIAL.
    CREATE OBJECT c_cont
      EXPORTING
        container_name = 'CUST_CONT'.
    CREATE OBJECT obj_alv
      EXPORTING
        i_parent = c_cont.
    CALL METHOD obj_alv->set_table_for_first_display
      EXPORTING
        i_structure_name = 'SPFLI'
      CHANGING
        it_outtab        = gt_outtab.
  ELSE.
    CALL METHOD obj_alv->refresh_table_display.
  ENDIF.
ENDMODULE.                 " STATUS_9002  OUTPUT
*&      Module  USER_COMMAND_9002  INPUT
MODULE user_command_9002 INPUT.
  CASE sy-ucomm.
    WHEN 'BACK'.
      CALL METHOD: obj_alv->free, c_cont->free.
      CLEAR: obj_alv, c_cont.
      CALL METHOD cl_gui_cfw=>flush.
      LEAVE TO SCREEN 9001.
  ENDCASE.
ENDMODULE.                 " USER_COMMAND_9002  INPUT
Altough it's not a really nice solution... Why using 2 screens for example? you could use two containers instead...
Also I would recommand playing with the new salv class for your grids.
Anyway don't hesitate to give feed-back.
Kr,
m.