ALV reprot With four internal tables

Hi all,
Could any one please tell what is function module we have to use for displaying four internal tables in a single ALV REPORT.
Thanks & regards
Vardhan

This is the code for displaying ALV using containers.. u need to create 4 containers in one screen and need to display data...
I would suggest you to get all the data into one internal table and display.. for more clarity u can give diff colors for diff table data using field catalog..
 *& Report ZTRPSD110 *
 * TITLE: Statement of Export Report for Tata Tetley *
 * PURPOSE:Statement of Export Report for Tata Tetley *
 * A. Start-of-selection: *
 * 1. In get_billing_data using the selection screen parameters get the *
 * billing data from billing header(VBAK) and Item (VBAP) *
 * 2. Get the SHIP-TO partner data from VBPA using Customer number as *
 * one condition and store in it_vbpa_sh
 * 9. Popultae the ALV display table
 * B. End-of-selection:
 * Call screen 9000 and display data in ALV
 REPORT ztrps110 MESSAGE-ID zttl LINE-SIZE 130.
 TABLES: vbrk.
 * CONSTANTS
 CONSTANTS :
 c_x(1) TYPE c VALUE 'X',
 c_zxto TYPE vbak-auart VALUE 'ZXTO',
 c_e TYPE spras VALUE 'E',
 c_000000 TYPE posnr VALUE '000000',
 c_ship_to TYPE parvw VALUE 'WE'. "Ship To Party
 * Table Types
 TYPES: BEGIN OF ty_vbrk_vbrp,
 vbeln TYPE vbrk-vbeln, "Billing doc
 posnr TYPE vbrp-posnr, "Billing item
 aubel TYPE vbrp-aubel, "Sales order
 waerk TYPE vbrk-waerk, "Doc currency
 mvgr1 TYPE vbrp-mvgr1, "Material group 1
 mvgr3 TYPE vbrp-mvgr3, "Material group 3
 mvgr4 TYPE vbrp-mvgr4, "Material group 4
 matnr TYPE vbrp-matnr, "Material no
 ntgew TYPE vbrp-ntgew, "Net wt
 gewei TYPE vbrp-gewei, "Wt unit
 kzwi1 TYPE vbrp-kzwi1, "Subtotal 1
 kursk TYPE vbrp-kursk, "Exchange rate
 END OF ty_vbrk_vbrp.
 TYPES: BEGIN OF ty_data,
 land1 TYPE vbpa-land1,
 landx TYPE t005t-landx,
 mvgr3 TYPE vbrp-mvgr3,
 mvgr4 TYPE vbrp-mvgr4,
 bezei3 TYPE tvm3t-bezei,
 bezei4 TYPE tvm4t-bezei,
 ntgew_tea_bag TYPE vbrp-ntgew,
 ntgew_pkt_tea TYPE vbrp-ntgew,
 ntgew_bulk_tea TYPE vbrp-ntgew,
 kzwi1_tea_bag TYPE vbrp-kzwi1, "Subtotal 1 Tea Bag
 kzwi1_pkt_tea TYPE vbrp-kzwi1, "Subtotal 1 Pkt Tea
 kzwi1_bulk_tea TYPE vbrp-kzwi1, "Subtotal 1 Bulk Tea
 ntgew_tot TYPE vbrp-ntgew,
 kzwi1_tot TYPE vbrp-kzwi1,
 line_color(4) TYPE c, "For line color
 END OF ty_data.
 TYPES: BEGIN OF ty_vbpa,
 vbeln TYPE vbpa-vbeln,
 land1 TYPE vbpa-land1,
 END OF ty_vbpa.
 TYPES: BEGIN OF ty_t005t,
 land1 TYPE t005t-land1,
 landx TYPE t005t-landx,
 END OF ty_t005t.
 TYPES: BEGIN OF ty_tvm3t,
 mvgr3 TYPE tvm3-mvgr3,
 bezei TYPE tvm3t-bezei,
 END OF ty_tvm3t.
 TYPES: BEGIN OF ty_tvm4t,
 mvgr4 TYPE tvm4-mvgr4,
 bezei TYPE tvm4t-bezei,
 END OF ty_tvm4t.
 DATA: it_vbrk_vbrp TYPE STANDARD TABLE OF ty_vbrk_vbrp,
 wa_vbrk_vbrp TYPE ty_vbrk_vbrp,
 it_vbpa TYPE STANDARD TABLE OF ty_vbpa,
 wa_vbpa TYPE ty_vbpa,
 it_data TYPE STANDARD TABLE OF ty_data,
 wa_data TYPE ty_data,
 it_t005t TYPE STANDARD TABLE OF ty_t005t,
 wa_t005t TYPE ty_t005t,
 it_tvm3t TYPE STANDARD TABLE OF ty_tvm3t,
 wa_tvm3t TYPE ty_tvm3t,
 it_tvm4t TYPE STANDARD TABLE OF ty_tvm4t,
 wa_tvm4t TYPE ty_tvm4t.
 * Global data for grand total
 DATA:
 w_tot_ntgew_tea_bag TYPE vbrp-ntgew,
 w_tot_ntgew_pkt_tea TYPE vbrp-ntgew,
 w_tot_ntgew_bulk_tea TYPE vbrp-ntgew,
 w_tot_ntgew_tot TYPE vbrp-ntgew,
 w_tot_kzwi1_tea_bag TYPE vbrp-kzwi1,
 w_tot_kzwi1_pkt_tea TYPE vbrp-kzwi1,
 w_tot_kzwi1_bulk_tea TYPE vbrp-kzwi1,
 w_tot_kzwi1_tot TYPE vbrp-kzwi1.
 * Global data definitions for ALV
 DATA :
 * ALV Grid container
 w_alv_container TYPE REF TO cl_gui_custom_container,
 * ALV Grid
 w_alv_grid TYPE REF TO cl_gui_alv_grid,
 w_layo TYPE lvc_s_layo, "For layout
 wt_fieldcat TYPE lvc_t_fcat, "For field catalog
 okcode TYPE okcode, "OK Code
 w_to(2) TYPE c,
 w_title TYPE string.
 *-------------- START OF SELECTION SCREEN ----------------------------*
 SELECTION-SCREEN: BEGIN OF BLOCK b1 WITH FRAME TITLE text-001.
 * Billing Date
 SELECT-OPTIONS: s_fkdat FOR vbrk-fkdat MEMORY ID vf OBLIGATORY NO-EXTENSION.
 SELECTION-SCREEN:SKIP 1.
 SELECTION-SCREEN: END OF BLOCK b1.
 *-------------- END OF SELECTION SCREEN ------------------------------*
 *------------- EVENT START-OF-SELECTION -------------------------------*
 START-OF-SELECTION.
 * Get billing data from Delivery header(VBRK) and item (VBRP)
 PERFORM get_billing_data.
 * Get ship-to country
 PERFORM get_ship_to_data.
 * Get material group description 3
 PERFORM get_material_group_3.
 * Get material group description 4
 PERFORM get_material_group_4.
 * Form the ALV Grid title
 PERFORM form_title.
 * Process data
 PERFORM process_data.
 * Populate text descriptions
 PERFORM populate_description.
 *------------- EVENT END-OF-SELECTION -------------------------------*
 END-OF-SELECTION.
 * Set the text to when date high is there
 IF NOT s_fkdat-high IS INITIAL.
 w_to = 'to'(c16).
 ENDIF.
 * Call the scren 9000 for ALV Display
 CALL SCREEN 9000.
 *& Form get_billing_data
 * Get billing data from Delivery header(VBRK) and item (VBRP)
 * & store in internal table it_vbrk_vbrp
 FORM get_billing_data .
 REFRESH: it_vbrk_vbrp.
 * Select Billing data by joining VBRK & VBRP and store in it_vbrk_vbrp
 SELECT a~vbeln
 b~posnr
 b~aubel
 a~waerk
 b~mvgr1
 b~mvgr3
 b~mvgr4
 b~matnr
 b~ntgew
 b~gewei
 b~kzwi1
 b~kursk
 FROM vbrk AS a INNER JOIN vbrp AS b
 ON a~vbeln = b~vbeln
 INTO TABLE it_vbrk_vbrp
 WHERE a~fkdat IN s_fkdat
 * Consider only non-deleted document
 AND fksto = space
 * Billing doc type should be ZXTB
 AND fkart = 'ZXTB'
 AND pstyv = c_zxto.
 IF sy-subrc <> 0.
 MESSAGE i999(zttl) WITH 'No data is there'(m06).
 LEAVE LIST-PROCESSING.
 ENDIF.
 ENDFORM. " get_billing_data
 *& Form get_ship_to_data
 * Get Ship-To party data
 FORM get_ship_to_data .
 DATA: l_it_vbpa TYPE STANDARD TABLE OF ty_vbpa.
 REFRESH: it_vbpa, it_t005t.
 IF NOT it_vbrk_vbrp[] IS INITIAL.
 SELECT vbeln
 land1
 FROM vbpa
 INTO TABLE it_vbpa
 FOR ALL ENTRIES IN it_vbrk_vbrp
 WHERE vbeln = it_vbrk_vbrp-aubel
 AND posnr = c_000000
 AND parvw = c_ship_to.
 IF sy-subrc <> 0.
 MESSAGE i999(zttl) WITH 'Exporter country not maintained'(m02).
 LEAVE LIST-PROCESSING.
 ELSE.
 SORT it_vbpa BY vbeln.
 * Create an unique and sorted driver table
 l_it_vbpa[] = it_vbpa[].
 SORT l_it_vbpa BY land1.
 DELETE ADJACENT DUPLICATES FROM l_it_vbpa COMPARING land1.
 IF NOT l_it_vbpa[] IS INITIAL.
 * Get the country description from T005t table
 SELECT land1
 landx
 FROM t005t
 INTO TABLE it_t005t
 FOR ALL ENTRIES IN l_it_vbpa
 WHERE spras = c_e
 AND land1 = l_it_vbpa-land1.
 IF sy-subrc = 0.
 SORT it_t005t BY land1.
 ENDIF.
 ENDIF.
 ENDIF.
 ENDIF.
 ENDFORM. " get_ship_to_data
 *& Form get_material_group_3
 * Get material group 3
 FORM get_material_group_3 .
 DATA: l_it_vbrk_vbrp TYPE STANDARD TABLE OF ty_vbrk_vbrp.
 REFRESH: it_tvm3t.
 * Create an unique and sorted driver table
 l_it_vbrk_vbrp[] = it_vbrk_vbrp[].
 SORT l_it_vbrk_vbrp BY mvgr3.
 DELETE ADJACENT DUPLICATES FROM l_it_vbrk_vbrp COMPARING mvgr3.
 IF NOT l_it_vbrk_vbrp[] IS INITIAL.
 SELECT mvgr3
 bezei
 FROM tvm3t
 INTO TABLE it_tvm3t
 FOR ALL ENTRIES IN l_it_vbrk_vbrp
 WHERE mvgr3 = l_it_vbrk_vbrp-mvgr3.
 IF sy-subrc = 0.
 SORT it_tvm3t BY mvgr3.
 ENDIF.
 ENDIF.
 ENDFORM. " get_material_group_3
 *& Form get_material_group_4
 * Get material group 4
 FORM get_material_group_4 .
 DATA: l_it_vbrk_vbrp TYPE STANDARD TABLE OF ty_vbrk_vbrp.
 REFRESH: it_tvm4t.
 * Create an unique and sorted driver table
 l_it_vbrk_vbrp[] = it_vbrk_vbrp[].
 SORT l_it_vbrk_vbrp BY mvgr4.
 DELETE ADJACENT DUPLICATES FROM l_it_vbrk_vbrp COMPARING mvgr4.
 IF NOT l_it_vbrk_vbrp[] IS INITIAL.
 SELECT mvgr4
 bezei
 FROM tvm4t
 INTO TABLE it_tvm4t
 FOR ALL ENTRIES IN l_it_vbrk_vbrp
 WHERE mvgr4 = l_it_vbrk_vbrp-mvgr4.
 IF sy-subrc = 0.
 SORT it_tvm4t BY mvgr4.
 ENDIF.
 ENDIF.
 ENDFORM. " get_material_group_4
 *& Form process_data
 * Process the data and do summation and populate final display table
 FORM process_data .
 LOOP AT it_vbrk_vbrp INTO wa_vbrk_vbrp.
 CLEAR: wa_data, wa_vbpa.
 READ TABLE it_vbpa INTO wa_vbpa WITH KEY
 vbeln = wa_vbrk_vbrp-aubel
 BINARY SEARCH.
 IF sy-subrc = 0.
 wa_data-land1 = wa_vbpa-land1.
 ENDIF.
 wa_data-mvgr3 = wa_vbrk_vbrp-mvgr3.
 wa_data-mvgr4 = wa_vbrk_vbrp-mvgr4.
 * Do an unit conversion of the quamtity
 CALL FUNCTION 'UNIT_CONVERSION_SIMPLE'
 EXPORTING
 input = wa_vbrk_vbrp-ntgew
 * NO_TYPE_CHECK = 'X'
 * ROUND_SIGN = ' '
 unit_in = wa_vbrk_vbrp-gewei
 unit_out = 'TO' "Metric tonn
 IMPORTING
 output = wa_vbrk_vbrp-ntgew
 EXCEPTIONS
 conversion_not_found = 1
 division_by_zero = 2
 input_invalid = 3
 output_invalid = 4
 overflow = 5
 type_invalid = 6
 units_missing = 7
 unit_in_not_found = 8
 unit_out_not_found = 9
 OTHERS = 10.
 IF sy-subrc <> 0.
 wa_vbrk_vbrp-ntgew = wa_vbrk_vbrp-ntgew.
 ENDIF.
 * Convert the currency from Customer currency to local
 * currency by multiplying with kursk
 wa_vbrk_vbrp-kzwi1 = wa_vbrk_vbrp-kzwi1 * wa_vbrk_vbrp-kursk.
 * Convert the amount to Lacks by dividing with 100000
 wa_vbrk_vbrp-kzwi1 = wa_vbrk_vbrp-kzwi1 / 100000. "DV1K905028
 * When MVGR1 is between A to F use the amount as TEA_BAG
 IF wa_vbrk_vbrp-mvgr1 BETWEEN 'A' AND 'F'.
 wa_data-ntgew_tea_bag = wa_vbrk_vbrp-ntgew.
 wa_data-kzwi1_tea_bag = wa_vbrk_vbrp-kzwi1.
 ENDIF.
 * When MVGR1 is between G to L use the amount as TEA_BAG
 IF wa_vbrk_vbrp-mvgr1 BETWEEN 'G' AND 'L'.
 wa_data-ntgew_pkt_tea = wa_vbrk_vbrp-ntgew.
 wa_data-kzwi1_pkt_tea = wa_vbrk_vbrp-kzwi1.
 ENDIF.
 * When MVGR1 is between G to L use the amount as TEA_BAG
 IF wa_vbrk_vbrp-mvgr1 = 'M'.
 wa_data-ntgew_bulk_tea = wa_vbrk_vbrp-ntgew.
 wa_data-kzwi1_bulk_tea = wa_vbrk_vbrp-kzwi1.
 ENDIF.
 COLLECT wa_data INTO it_data.
 ENDLOOP.
 ENDFORM. " process_data
 *& Form populate_description
 * Populate the description fields
 FORM populate_description .
 LOOP AT it_data INTO wa_data.
 CLEAR: wa_t005t.
 READ TABLE it_t005t INTO wa_t005t WITH KEY land1 = wa_data-land1
 BINARY SEARCH.
 IF sy-subrc = 0.
 wa_data-landx = wa_t005t-landx.
 ENDIF.
 * Read description of Material group 3
 CLEAR wa_tvm3t.
 READ TABLE it_tvm3t INTO wa_tvm3t WITH KEY
 mvgr3 = wa_data-mvgr3
 BINARY SEARCH.
 IF sy-subrc = 0.
 wa_data-bezei3 = wa_tvm3t-bezei.
 ENDIF.
 * Read description of Material group 4
 CLEAR wa_tvm4t.
 READ TABLE it_tvm4t INTO wa_tvm4t WITH KEY
 mvgr4 = wa_data-mvgr4
 BINARY SEARCH.
 IF sy-subrc = 0.
 wa_data-bezei4 = wa_tvm4t-bezei.
 ENDIF.
 * Get the grand totals
 wa_data-ntgew_tot = wa_data-ntgew_tea_bag
 + wa_data-ntgew_pkt_tea
 + wa_data-ntgew_bulk_tea.
 wa_data-kzwi1_tot = wa_data-kzwi1_tea_bag
 + wa_data-kzwi1_pkt_tea
 + wa_data-kzwi1_bulk_tea.
 MODIFY it_data FROM wa_data TRANSPORTING landx
 bezei3
 bezei4
 ntgew_tot
 kzwi1_tot.
 * Summattion of grand totals
 w_tot_ntgew_tea_bag = w_tot_ntgew_tea_bag + wa_data-ntgew_tea_bag.
 w_tot_ntgew_pkt_tea = w_tot_ntgew_pkt_tea + wa_data-ntgew_pkt_tea.
 w_tot_ntgew_bulk_tea = w_tot_ntgew_bulk_tea + wa_data-ntgew_bulk_tea.
 w_tot_ntgew_tot = w_tot_ntgew_tot + wa_data-ntgew_tot.
 w_tot_kzwi1_tea_bag = w_tot_kzwi1_tea_bag + wa_data-kzwi1_tea_bag.
 w_tot_kzwi1_pkt_tea = w_tot_kzwi1_pkt_tea + wa_data-kzwi1_pkt_tea.
 w_tot_kzwi1_bulk_tea = w_tot_kzwi1_bulk_tea + wa_data-kzwi1_bulk_tea.
 w_tot_kzwi1_tot = w_tot_kzwi1_tot + wa_data-kzwi1_tot.
 ENDLOOP.
 * Append a grand Total row at the end
 CLEAR wa_data.
 wa_data-landx = 'Grand Total:'.
 wa_data-ntgew_tea_bag = w_tot_ntgew_tea_bag.
 wa_data-ntgew_pkt_tea = w_tot_ntgew_pkt_tea.
 wa_data-ntgew_bulk_tea = w_tot_ntgew_bulk_tea.
 wa_data-ntgew_tot = w_tot_ntgew_tot.
 wa_data-kzwi1_tea_bag = w_tot_kzwi1_tea_bag.
 wa_data-kzwi1_pkt_tea = w_tot_kzwi1_pkt_tea.
 wa_data-kzwi1_bulk_tea = w_tot_kzwi1_bulk_tea.
 wa_data-kzwi1_tot = w_tot_kzwi1_tot.
 wa_data-line_color = 'C310'.
 APPEND wa_data TO it_data.
 ENDFORM. " populate_description
 *& Module STATUS_9000 OUTPUT
 * Initialise PF-STATUS and title
 MODULE status_9000 OUTPUT.
 SET PF-STATUS 'MAIN9000'.
 SET TITLEBAR 'TITLE_9000'.
 ENDMODULE. " STATUS_9000 OUTPUT
 *& Module initialize_9000 OUTPUT
 * text
 MODULE initialize_9000 OUTPUT.
 * Call the ALV grid to display data
 PERFORM display_alv_grid.
 ENDMODULE. " initialize_9000 OUTPUT
 *& Module USER_COMMAND_9000 INPUT
 * Module to handle User Command
 MODULE user_command_9000 INPUT.
 CASE okcode.
 WHEN 'BACK'.
 SET SCREEN 0.
 CLEAR okcode.
 LEAVE SCREEN.
 WHEN 'CANCEL'.
 SET SCREEN 0.
 CLEAR okcode.
 LEAVE SCREEN.
 WHEN 'EXIT'.
 CLEAR okcode.
 LEAVE PROGRAM.
 WHEN OTHERS.
 ENDCASE.
 ENDMODULE. " USER_COMMAND_9000 INPUT
 *& Form display_alv_grid
 * Display the data in ALV Grid
 FORM display_alv_grid .
 IF w_alv_container IS INITIAL.
 * Create the alv container object
 CREATE OBJECT w_alv_container
 EXPORTING
 container_name = 'ALV_GRID'
 EXCEPTIONS
 cntl_error = 1
 cntl_system_error = 2
 create_error = 3
 lifetime_error = 4
 lifetime_dynpro_dynpro_link = 5
 OTHERS = 6.
 IF sy-subrc <> 0.
 MESSAGE e999(zttl) WITH 'Problem in ALV display'(t04).
 ENDIF.
 * Create the ALV grid object. The parent is the ALV container
 CREATE OBJECT w_alv_grid
 EXPORTING
 i_parent = w_alv_container
 EXCEPTIONS
 error_cntl_create = 1
 error_cntl_init = 2
 error_cntl_link = 3
 error_dp_create = 4
 OTHERS = 5.
 IF sy-subrc <> 0.
 MESSAGE e999(zttl) WITH 'Problem in ALV display'(t04).
 ENDIF.
 * This subrotine creates the field catalog and
 * store in internal table lt_fieldcat
 PERFORM prepare_fieldcat CHANGING wt_fieldcat.
 * Layout design
 w_layo-no_toolbar = ''.
 * Not to allow totaling feature
 w_layo-no_totline = c_x.
 * Report title
 * w_layo-grid_title = text-004.
 w_layo-grid_title = w_title.
 w_layo-zebra = c_x. "Alternating line color (striped)
 w_layo-cwidth_opt = c_x. "Optimize column width
 w_layo-sel_mode = 'A'. "Selection Mode
 * Name of the color field
 w_layo-info_fname = 'LINE_COLOR'."For row color
 * Call the method to display the data in ALV grid
 CALL METHOD w_alv_grid->set_table_for_first_display
 EXPORTING
 i_save = 'A'
 is_layout = w_layo
 CHANGING
 it_outtab = it_data[]
 it_fieldcatalog = wt_fieldcat
 EXCEPTIONS
 invalid_parameter_combination = 1
 program_error = 2
 too_many_lines = 3
 OTHERS = 4.
 IF sy-subrc <> 0.
 MESSAGE e999(zttl) WITH text-t04.
 ENDIF.
 ELSE.
 * If the container & grid object is alreadt there reuse them
 CALL METHOD w_alv_grid->refresh_table_display
 EXCEPTIONS
 finished = 1
 OTHERS = 2.
 IF sy-subrc <> 0.
 MESSAGE e999(zttl) WITH text-t04.
 ENDIF.
 ENDIF.
 IF okcode = 'CANCEL'.
 EXIT.
 ENDIF.
 ENDFORM. " display_alv_grid
 *& Form prepare_fieldcat

Similar Messages

Coloring an ALV Cell with DYNAMIC INTERNAL TABLES

Hello Gurus,
I need your help regarding coloring of a cell in my ALV Grid report with DYNAMIC tables.
I have used the call method in calling my ALV. (CALL METHOD gr_alvgrid->set_table_for_first_display).
Now my problem is, I can not bring out the cellcolor succesfully, I always ended up to dump (GETWA_NOT_ASSIGNED = You attempted to access an unassigned field symbol
(data segment 32807).
What I have done:
I've created 2 internal tables:
*1st table
*After appended all of my columns to gt_fieldcat
CALL METHOD cl_alv_table_create=>create_dynamic_table
 EXPORTING
 it_fieldcatalog = gt_fieldcat
 IMPORTING
 ep_table = gp_both.
ASSIGN gp_both->* TO <i_xtab1>.
*2nd table
Appended these column for CellColor
CLEAR wa_gtfldcat.
wa_gtfldcat-fieldname = 'CELLCOLOR'.
wa_gtfldcat-ref_table = 'CALENDAR_TYPE'.
wa_gtfldcat-ref_field = 'COLTAB'.
APPEND wa_gtfldcat TO gt_fieldcat.
CALL METHOD cl_alv_table_create=>create_dynamic_table
 EXPORTING
 it_fieldcatalog = gt_fieldcat
 IMPORTING
 ep_table = gp_alvgrid.
ASSIGN gp_alvgrid->* TO <i_xtab2>.
*Work Areas for tab1 and tab2
CREATE DATA dref1 LIKE LINE OF <i_xtab1>.
ASSIGN dref1->* TO <wa_xtab1>.
CREATE DATA dref2 LIKE LINE OF <i_xtab2>.
ASSIGN dref2->* TO <wa_xtab2>.
*Move contents of table1 to table2 and modify cellcolor column
LOOP AT <i_xtab1> ASSIGNING <wa_xtab1>.
*-----Cell color assignment
 DESCRIBE TABLE gt_fieldcat.
 DO sy-tfill TIMES.
 READ TABLE gt_fieldcat INTO wa_gtfldcat INDEX sy-index.
 ASSIGN COMPONENT wa_gtfldcat-fieldname
 OF STRUCTURE <wa_xtab1> TO <fs4>.
 IF sy-subrc NE 0. EXIT .ENDIF.
 ASSIGN COMPONENT wa_gtfldcat-fieldname
 OF STRUCTURE <wa_xtab2> TO <fs3>.
 IF sy-subrc NE 0. EXIT .ENDIF.
 <fs3> = <fs4>.
 ENDDO.
 ASSIGN COMPONENT 'CELLCOLOR' OF STRUCTURE <wa_xtab2> TO <fs3>.
 IF sy-subrc = 0.
 PERFORM modify_cell_color USING 'ZZMATNR' <fs3>.
 ENDIF.
 APPEND <wa_xtab1> TO <i_xtab2>.
ENDLOOP.
*Call ALV
gs_layout-ctab_fname = 'COLORCELL'
 CALL METHOD gr_alvgrid->set_table_for_first_display
 EXPORTING
 is_layout = gs_layout
 CHANGING
 it_outtab = <i_xtab2d>[]
 it_fieldcatalog = gt_fieldcat
 it_sort = lt_sort
 EXCEPTIONS
 invalid_parameter_combination = 1
 program_error = 2
 too_many_lines = 3
 OTHERS = 4.
 IF sy-subrc <> 0.
*--->Exception handling
 ENDIF.
FORM modify_cell_color USING p_fieldname TYPE lvc_fname
 pt_cellcolor TYPE table.
DATA l_cellcolor TYPE lvc_s_scol.
CLEAR l_cellcolor.
l_cellcolor-fname = p_fieldname.
l_cellcolor-color-col = 6. " Red.
l_cellcolor-color-int = 0.
l_cellcolor-color-inv = 0.
INSERT l_cellcolor INTO TABLE pt_cellcolor.
ENDFORM. " MODIFY_CELL_COLOR

Hi,
The internal tabl which you are using to display the output should have one column in the end.
The cell in this column will contain an internal table of type 'lvc_s_scol'.
The contents of this internal table will be the field names of all other columns of your main internal table in the field FNAME and the required color in the field COLOR.
Please note that the field COLOR will have a hex value for different colors.
In the stucture is_layout whihc you pass to the method 'set_table_for_first_display'
the name of this last column should be given to the field 'ctab_fname'.
This will help you to give the colors to each cell.
for example
I have my data table as follows:-
ITAB1
MATNR MAKTX COLOR_TAB
1 ABC FNAME COLOR NOKEYCOL
 MATNR 8000
 MAKTX 8000
2 XYZ MATNR 10000
 MAKTX 10000
So my internal table ITAB1 had 3 columns MATNR MAKTX and COLOR_TAB.
And COLOR_TAB will contain an internal table with 3 columns FNAME COLOR and NOKEYCOL.
The value to importing parameter IS_LAYOUT-CTAB_FNAME will be COLOR_TAB.
This will help you to assign various colors to the cell of the internal table ITAB.
When you have to change any color, then you will have to just change the entries in cell COLOR_TAB for the particular row and cell.
Regards,
Ankur Parab

Binding ALV GRID with Deep Internal Table

Hello all,
I am looking for a way to display ALV Grid with the Deep ITAB.
My ITAB is not too complex.
It has One Structure which gets whole DB table + One extra field.
Therefore my Itab looks as follows.
TYPES: BEGIN OF TY_TRIP,
        ZPM_UPLOAD LIKE ZDBTABLE, "ZDBTABLE is custom database table.
        TDTIME TYPE STRING,
       END OF TY_TRIP.
DATA: ITAB TYPE TABLE OF TY_TRIP,
      WA_ITAB LIKE LINE OF ITAB.
Now i am able to populate data into Deep ITAB.
If i call ALV Grid with ITAB then i get error. So how to call 'REUSE_ALV_GRID_DISPLAY' with this ITAB?
Thanks in advance.

Hello,
My senior asked me to use the below definition.
TYPES: BEGIN OF TY_TRIP.
        INCLUDE STRUCTURE ZDBTABLE.
TYPES: TDTIME TYPE STRING,
       END OF TY_TRIP.
DATA: ITAB TYPE TABLE OF TY_TRIP,
      WA_ITAB LIKE LINE OF ITAB.
If anyone else is looking to print in ALV, they can use this type of ITAB definition though it gives you the flexiblity to create ITAB and also making it FLAT and not DEEP.
But i am still looking for an answer for my first post.
Thanks.

Display ALV GRID Using Dynamic Internal Table

Hi all,
I try to display ALV Grid using Dynamic Internal Table, but when i activate my program, i get an error message "DYN_TABLE" is not type-compatible with formal parameter "IT_OUTTAB". ( DYN_TABLE is my Dynamic Itab).
Anybody can help me how to passing Dynamic Itab into ALV Grid ?? Of ALV Grid only accept static Itab ??
Thanks,

Hi Vijay,
It's doesn't work, and make new error "Formal parameter "IT_OUTTAB[]" does not exist. However, the parameter "IT_OUTTAB" has a similar name."
Because the method is:
CALL METHOD <ref. var. to CL_GUI_ALV_GRID>->set_table_for_first_display
EXPORTING
I_BUFFER_ACTIVE = <any type (ANY)>
I_STRUCTURE_NAME = <string of type DD02L-TABNAME>
IS_VARIANT = <structure of type DISVARIANT>
I_SAVE = <var. of type CHAR01>
I_DEFAULT = <var. of type CHAR01>
IS_LAYOUT = <structure of type LVC_S_LAYO>
IS_PRINT = <structure of type LVC_S_PRNT>
IT_SPECIAL_GROUPS = <internal table of type LVC_T_SGRP>
IT_TOOLBAR_EXCLUDING = <internal table of type UI_FUNCTIONS>
IT_HYPERLINK = <internal table of type LVC_T_HYPE>
IT_ALV_GRAPHICS = <internal table of type DTC_T_TC>
CHANGING
IT_OUTTAB = <internal table>
IT_FIELDCATALOG = <internal table of type LVC_T_FCAT>
IT_SORT = <internal table of type LVC_T_SORT>
IT_FILTER = <internal table of type LVC_T_FILT>
Thanks,

ABAP to XML with several internal tables

hi,
i have to make a XML file with this structure :
<Order>
<OrderHeader>
 ...[fields of header]...
</OrderHeader>
<OrderItem>
 ...[fields of item 10]...
</OrderItem>
<OrderItem>
 ...[fields of item n]...
</OrderItem>
</Order>
and that for several orders...
I don't know anything about XML, XLST and since 1 day just start to read doc, tutorial.. and i can't say i'm understanding everythings..
so, in a first step, i have tried to export several Order headers :
I have done a XSLT (thanks to another topic/replies in the forum) and call it with CALL TRANSFORMATION and it works good...
now,and here i need a little help, i would like to know :
1-is it possible to work with 2 internal tables and in this case, how to make XLST looping all item for each header?
2-or should i use only one internal table with deep structure?
Regards,
Christophe
The XSLT
<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:sapxsl="http://www.sap.com/sapxsl" version="1.0">
<xsl:strip-space elements="*"/>
<xsl:template match="/">
 <Order>
 <xsl:for-each select="//item">
 <OrderHeader>
 <OrderNo>
 <xsl:value-of select="AUFNR"/>
 </NoOT>
 </OrderHeader>
 </xsl:for-each>
 </Order>
</xsl:template>
</xsl:transform>

Hi,
Here is the sample code.
* Databases
TABLES:
makt, "Mat description
marc, "Material / plant
t001w, "plant name
bhdgd. "Batch heading
* Internal tables
DATA:
BEGIN OF gt_marc OCCURS 0,
 werks LIKE marc-werks,
 matnr LIKE marc-matnr,
END OF gt_marc,
* Table to be downloaded as xml. Each line stores start and end tags
* and the value
BEGIN OF gt_xml OCCURS 0,
 line(120),
END OF gt_xml,
g_maktx(120).
* User-input
SELECT-OPTIONS:
s_werks FOR marc-werks,
s_matnr FOR marc-matnr.
START-OF-SELECTION.
* Extract all required data
PERFORM main_processing.
END-OF-SELECTION.
SORT gt_marc BY werks matnr.
LOOP AT gt_marc.
 AT FIRST. "First tag must be root
 CLEAR gt_xml.
 gt_xml-line = '<LOCATIONS>'.
 APPEND gt_xml.
 CLEAR gt_xml.
 ENDAT.
 AT NEW werks. "At new plant
 PERFORM read_plant.
 FORMAT COLOR 4 ON.
 SKIP 1.
 WRITE :/ gt_marc-werks, t001w-name1.
 FORMAT COLOR 4 OFF.
 CLEAR gt_xml.
 gt_xml-line = ' <PLANT>'.
 APPEND gt_xml.
 CLEAR gt_xml.
 CONCATENATE ' <NUMBER>' gt_marc-werks '</NUMBER>'
 INTO gt_xml-line.
 APPEND gt_xml.
 CLEAR gt_xml.
 CONCATENATE ' <NAME>' t001w-name1 '</NAME>' INTO gt_xml-line.
 APPEND gt_xml.
 CLEAR gt_xml.
 gt_xml-line = ' </PLANT>'.
 APPEND gt_xml.
 CLEAR gt_xml.
 ENDAT.
 PERFORM read_description.
 CLEAR gt_xml.
 gt_xml-line = ' <MATERIAL>'.
 APPEND gt_xml.
 CLEAR gt_xml.
 CONCATENATE ' <NAME>' g_maktx '</NAME>'
 INTO gt_xml-line.
 APPEND gt_xml.
 CLEAR gt_xml.
 CONCATENATE ' <NUMBER>' gt_marc-matnr '</NUMBER>'
 INTO gt_xml-line.
 APPEND gt_xml.
 CLEAR gt_xml.
 gt_xml-line = ' </MATERIAL>'.
 APPEND gt_xml.
 CLEAR gt_xml.
* display data
 FORMAT COLOR 2 ON.
 WRITE :/ gt_marc-matnr, makt-maktx.
 FORMAT COLOR 2 OFF.
ENDLOOP.
* The last tag must be the root closing tag --*
gt_xml-line = '</LOCATIONS>'.
APPEND gt_xml.
CLEAR gt_xml.
CALL FUNCTION 'DOWNLOAD'
 EXPORTING
 filename = 'C:PLANT1.XML'
 filetype = 'ASC'
 TABLES
 data_tab = gt_xml.
TOP-OF-PAGE.
MOVE sy-title TO bhdgd-line1.
MOVE sy-repid TO bhdgd-repid.
MOVE sy-uname TO bhdgd-uname.
MOVE sy-datum TO bhdgd-datum.
MOVE '0' TO bhdgd-inifl.
MOVE '132' TO bhdgd-lines.
FORMAT INTENSIFIED ON COLOR COL_HEADING.
PERFORM batch-heading(rsbtchh0). "report header
* Form READ_PLANT
FORM read_plant.
* Get plant name
CLEAR t001w.
SELECT SINGLE name1
 INTO t001w-name1
 FROM t001w
 WHERE werks EQ gt_marc-werks.
ENDFORM. " READ_PLANT
* Form MAIN_PROCESSING
FORM main_processing.
* Material and plant basic data
SELECT werks matnr
 INTO TABLE gt_marc
 FROM marc
 WHERE werks IN s_werks
 AND matnr IN s_matnr.
ENDFORM. " MAIN_PROCESSING
* Form READ_DESCRIPTION
FORM read_description.
* Material name
CLEAR g_maktx.
SELECT SINGLE maktx
 INTO g_maktx
 FROM makt
 WHERE matnr EQ gt_marc-matnr
 AND spras EQ 'E'.
* Replace special character
DO.
 REPLACE '&' WITH '*ù%;' INTO g_maktx.
 IF NOT sy-subrc IS INITIAL. EXIT.ENDIF.
ENDDO.
DO.
 REPLACE '*ù%;' WITH '&' INTO g_maktx.
 IF NOT sy-subrc IS INITIAL. EXIT.ENDIF.
ENDDO.
DO.
 REPLACE '/' WITH '/' INTO g_maktx.
 IF NOT sy-subrc IS INITIAL. EXIT.ENDIF.
ENDDO.
ENDFORM. " READ_DESCRIPTION
Hope this helps.If so,kindly reward points.

Using where condition with dynamic internal table

Hi Friends.
How to use where condition with dynamic internal table ?
Regards,
Amit Raut

Hai Amit
REPORT ZDYNAMIC_SELECT .
TABLES: VBAK.
DATA: CONDITION TYPE STRING.
DATA: BEGIN OF ITAB OCCURS 0,
VBELN LIKE VBAK-VBELN,
POSNR LIKE VBAP-POSNR,
END OF ITAB.
SELECT-OPTIONS: S_VBELN FOR VBAK-VBELN.
CONCATENATE 'VBELN' 'IN' 'S_VBELN.'
INTO CONDITION SEPARATED BY SPACE.
SELECT VBELN POSNR FROM VBAP INTO TABLE ITAB
WHERE (CONDITION).
LOOP AT ITAB.
WRITE 'hello'.
ENDLOOP.
Thanks & Regards
Sreenivasulu P

Im trying to update db table in user exit, with the internal table

Im trying to update db table in user exit, with the internal table
my scenario:
loop at itekpo.
updating itekpo -
> at the end of user exit the db table ekpo have to be updated
endloop.
Im updating internal table, using
MODIFY itekpo TRANSPORTING INCO1 INCO2 WHERE ebeln = itekpo-ebeln
where itekpo is internal table, but it is not updating the db table 'ekpo'.
i also tried updating ekpo directly !
Thanks in advance

Hi,
you can search in the forum itself,
Try this link for instance
https://www.sdn.sap.com/irj/sdn/advancedsearch?cat=sdn_all&query=tocreateaBADI&adv=false&sortby=cm_rnd_rankvalue
You can find a code for finding BADI as a report with the following Transaction
finding badis
How to find BADIs
Reward if helpful
Regards
Byju

2 different tables in the main window with same internal table data

Hi All,
can we have 2 diffterent tables with same internal table data into its work area in the main window.Is it possible or we will get any run time error.?
is it like having 2 nested loop with same internal table ?
ex : loop at itab1 into wa_itab.
loop at itab1 into wa_itab.
endloop.
endloop.
can we use like this?

Hi,
there will not be any error ...but what is the use of it...
do you need to have a controlled way of display ...of the data...
If so then you create another workarea in the global definitions of the same type and then use it...
Regards,
Ram

Alv with two internal tables

I have two separate internal tables. However , they have a common field matnr. In the report output, the two internal tables should be joined by this common field. Can this be done with an ALV . The common field Matnr should appear to the extreme left. Followed by itab1 and then itab2 . Its in a sense Matnr is the header , but it shows as rows. Each matnr has several item in both itab1 and itab2 , it is not necessary that total number of item data in itab1 and itab2 will be same .

You can see example program :
TYPE-POOLS: slis.
DATA: BEGIN OF itab OCCURS 0,
 vbeln TYPE vbeln,
 expand,
 END OF itab.
DATA: BEGIN OF itab1 OCCURS 0,
 vbeln TYPE vbeln,
 posnr TYPE posnr,
 matnr TYPE matnr,
 netpr TYPE netpr,
 END OF itab1.
DATA: t_fieldcatalog TYPE slis_t_fieldcat_alv.
DATA: s_fieldcatalog TYPE slis_fieldcat_alv.
s_fieldcatalog-col_pos = '1'.
s_fieldcatalog-fieldname = 'VBELN'.
s_fieldcatalog-tabname = 'ITAB'.
s_fieldcatalog-rollname = 'VBELN'.
s_fieldcatalog-outputlen = '12'.
APPEND s_fieldcatalog TO t_fieldcatalog.
CLEAR: s_fieldcatalog.
s_fieldcatalog-col_pos = '1'.
s_fieldcatalog-fieldname = 'VBELN'.
s_fieldcatalog-tabname = 'ITAB1'.
s_fieldcatalog-rollname = 'VBELN'.
s_fieldcatalog-outputlen = '12'.
APPEND s_fieldcatalog TO t_fieldcatalog.
CLEAR: s_fieldcatalog.
s_fieldcatalog-col_pos = '2'.
s_fieldcatalog-fieldname = 'POSNR'.
s_fieldcatalog-tabname = 'ITAB1'.
s_fieldcatalog-rollname = 'POSNR'.
APPEND s_fieldcatalog TO t_fieldcatalog.
CLEAR: s_fieldcatalog.
s_fieldcatalog-col_pos = '3'.
s_fieldcatalog-fieldname = 'MATNR'.
s_fieldcatalog-tabname = 'ITAB1'.
s_fieldcatalog-rollname = 'MATNR'.
APPEND s_fieldcatalog TO t_fieldcatalog.
CLEAR: s_fieldcatalog.
s_fieldcatalog-col_pos = '4'.
s_fieldcatalog-fieldname = 'NETPR'.
s_fieldcatalog-tabname = 'ITAB1'.
s_fieldcatalog-rollname = 'NETPR'.
s_fieldcatalog-do_sum = 'X'.
APPEND s_fieldcatalog TO t_fieldcatalog.
CLEAR: s_fieldcatalog.
DATA: s_layout TYPE slis_layout_alv.
s_layout-subtotals_text = 'SUBTOTAL TEXT'.
s_layout-key_hotspot = 'X'.
s_layout-expand_fieldname = 'EXPAND'.
SELECT vbeln UP TO 100 ROWS
 FROM
 vbak
 INTO TABLE itab.
IF NOT itab[] IS INITIAL.
SELECT vbeln posnr matnr netpr
 FROM vbap
 INTO TABLE itab1
 FOR ALL ENTRIES IN itab
 WHERE vbeln = itab-vbeln.
ENDIF.
DATA: v_repid TYPE syrepid.
v_repid = sy-repid.
DATA: s_keyinfo TYPE slis_keyinfo_alv.
s_keyinfo-header01 = 'VBELN'.
s_keyinfo-item01 = 'VBELN'.
CALL FUNCTION 'REUSE_ALV_HIERSEQ_LIST_DISPLAY'
 EXPORTING
 i_callback_program = v_repid
 is_layout = s_layout
 it_fieldcat = t_fieldcatalog
 i_tabname_header = 'ITAB'
 i_tabname_item = 'ITAB1'
 is_keyinfo = s_keyinfo
 TABLES
 t_outtab_header = itab
 t_outtab_item = itab1
 EXCEPTIONS
 program_error = 1
 OTHERS = 2.
IF sy-subrc <> 0.
MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
 WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
ENDIF.
Thanks
Seshu

Unable to Capture ALV output in an Internal Table, after CALL TRANSACTION

Dear all,
My requirement is to run multiple materials in T-code CK86_99 but as we know CK86_99 is only adequate to one material at a time.
So, I want to capture the Output of the T-code in my Internal table with respect to all the Material Numbers I use in the Select-Options of my Z Program.
Below is the Code I developed so far, but the Class
cl_salv_bs_runtime_info=>get_data_ref(
 IMPORTING r_data = lf_ref ).
is not capturing the Ouput...
Please have a look and enlighten me how it could be solved.
TABLES : mara.
DATA : BEGIN OF wa_mara,
matnr TYPE mara-matnr,
END OF wa_mara.
DATA: it_bdcdata TYPE TABLE OF bdcdata,
 wa_it_bdcdata LIKE LINE OF it_bdcdata,
 it_mara LIKE TABLE OF wa_mara.
* BELNR(10).
FIELD-SYMBOLS:<fs_tab> TYPE ANY TABLE,
<fs_line> TYPE any.
DATA:lf_ref TYPE REF TO data,
 lf_ref1 TYPE REF TO data.
SELECT-OPTIONS so_matnr FOR mara-matnr.
PARAMETERS p_werks LIKE t001w-werks.
*BELNR = 'Z92'. " Give Document Number here
SELECT matnr FROM mara INTO TABLE it_mara WHERE matnr IN so_matnr.
DATA opt TYPE ctu_params.
LOOP AT it_mara INTO wa_mara.
CLEAR wa_it_bdcdata.
wa_it_bdcdata-program = 'SAPMKKB0'.
wa_it_bdcdata-dynpro = '0300'.
wa_it_bdcdata-dynbegin = 'X'.
APPEND wa_it_bdcdata TO it_bdcdata.
CLEAR wa_it_bdcdata.
wa_it_bdcdata-fnam = 'BDC_CURSOR'.
wa_it_bdcdata-fval = 'KKB0-MATNR'.
APPEND wa_it_bdcdata TO it_bdcdata.
CLEAR wa_it_bdcdata.
wa_it_bdcdata-fnam = 'KKB0-MATNR'.
wa_it_bdcdata-fval = wa_mara-matnr.
APPEND wa_it_bdcdata TO it_bdcdata.
CLEAR wa_it_bdcdata.
wa_it_bdcdata-fnam = 'BDC_CURSOR'.
wa_it_bdcdata-fval = 'KKB0-WERKS'.
APPEND wa_it_bdcdata TO it_bdcdata.
CLEAR wa_it_bdcdata.
wa_it_bdcdata-fnam = 'KKB0-WERKS'.
wa_it_bdcdata-fval = p_werks.
APPEND wa_it_bdcdata TO it_bdcdata.
CLEAR wa_it_bdcdata.
wa_it_bdcdata-fnam = 'BDC_OKCODE'.
wa_it_bdcdata-fval = 'OSNY'."'ONLI'."=CRET'.
APPEND wa_it_bdcdata TO it_bdcdata.
* CLEAR wa_it_bdcdata.
* wa_it_bdcdata-program = 'SAPLKKRSOO'.
* wa_it_bdcdata-dynpro = '0100'.
* wa_it_bdcdata-dynbegin = 'X'.
* APPEND wa_it_bdcdata TO it_bdcdata.
* CLEAR wa_it_bdcdata.
* wa_it_bdcdata-fnam = 'BDC_OKCODE'.
* wa_it_bdcdata-fval = 'BACK'."=CRET'.
* APPEND wa_it_bdcdata TO it_bdcdata.
* CLEAR wa_it_bdcdata.
* wa_it_bdcdata-program = 'SAPMKKB0'.
* wa_it_bdcdata-dynpro = '0300'.
* wa_it_bdcdata-dynbegin = 'X'.
* APPEND wa_it_bdcdata TO it_bdcdata.
* CLEAR wa_it_bdcdata.
* wa_it_bdcdata-fnam = 'BDC_OKCODE'.
* wa_it_bdcdata-fval = 'EXIT'."=CRET'.
* APPEND wa_it_bdcdata TO it_bdcdata.
opt-dismode = 'N'.
cl_salv_bs_runtime_info=>set(
 EXPORTING display = abap_false
 metadata = abap_true
data = abap_true ).
CALL TRANSACTION 'CK86_99' USING it_bdcdata OPTIONS FROM opt.
TRY.
cl_salv_bs_runtime_info=>get_data_ref(
 IMPORTING r_data = lf_ref ).
 ASSIGN lf_ref->* TO <fs_tab>.
 CATCH cx_salv_bs_sc_runtime_info.
 MESSAGE 'Unable to retrieve ALV data' TYPE 'E'.
ENDTRY.
cl_salv_bs_runtime_info=>clear_all( ).
IF <fs_tab> IS ASSIGNED.
 CREATE DATA lf_ref1 LIKE LINE OF <fs_tab>.
 ASSIGN lf_ref1->* TO <fs_line>.
ENDIF.
*LOOP AT <FS_TAB> ASSIGNING <FS_LINE>.
*ENDLOOP.

Hi Abhay,
 If you go to Transaction code SE93, enter the tcode "CK86_99" and click display, you may see the default value for transaction is "KKBB" and the screen field for P_SCREEN = 0300, P_TCODE = ck86_99.
 You may need to copy the transaction code "KKBB" and go to SE93 again, enter the tcode for "KKBB" then click display, now you may see the program name is "RKKB1000".
 Hope this answer your question.
Thanks
Hock Lin

How to get total in ALV report in same Internal table?

Data : Begin of it_data,
        kunnr type kunnr,
        name1 type name1,
        amt1 type btrt01, " CURR 15,2
       end of it_data.
loop at it_data into wa_data
endloop.
Hello friends,
I am developing one ALV report with 20 rows.
I have filled one internal table with some fileds like amount.
I want to get total of all amount1 in AMT1 field.
So, How to get total of amount in same internal table in ALV report ?
It is ok if i get duplicate rows in internal table.
Points 'll be awarded soon.
Regards,
NVM

Hi Ronny,
the alv output will display the sum at the last row.
for this functionality u have do this logic.
data: lw_fcat type slis_fieldcat_alv.
data: lt_fcat type slis_t_fieldcat_alv/
wa_fcat-fieldname = 'AMT1'.
wa_fcat-tabname = 'ITAB'.
wa_fcat-do_sum = 'X'.
append wa_fcat to lt_fcat.
and then pass it to reuse_alv_grid_display function,
regards,
Santosh Thorat

Editable ALV-No change in internal table

Hello Experts,
   I have an ALV output, in which I have a column as editable. I have generated the output using 'REUSE_ALV_GRID_DISPLAY'. I got to know that after changing the editable cell's value, if we double click the cell or if operate with any PF-status components, the value will automatically get changed in internal table also. For double click I am getting the expected result. But If I click a button the value doesn't get changed in internal table. Is there any other change I have to do for this. If I have checkbox in ALV will it be rectified. But my requirement is when I click the button only It has to be modified in the database table.
Thanks and regards,
Venkat.

Hi Venkat,
In your form for User Command
write following
DATA ref1 TYPE REF TO cl_gui_alv_grid.
      CALL FUNCTION 'GET_GLOBALS_FROM_SLVC_FULLSCR'
        IMPORTING
          e_grid = ref1.
      CALL METHOD ref1->check_changed_data.
Case 'User-Command'.
Endcase.
or
data : i_grid_settings type lvc_s_glay.
"Calling ALV grid for display
call function 'REUSE_ALV_GRID_DISPLAY'
    exporting
      i_callback_program             = sy-repid
      i_callback_user_command   = i_callback_user_command
      i_grid_settings                    = i_grid_settings
      is_layout                            = is_layout
      it_fieldcat                           = it_fieldcat
    tables
      t_outtab                             = it_final
"for call back values from editable grid cells
i_grid_settings-edt_cll_cb = 'X'.
Hope it helps you,
Pratik

Really urgent: reagrding alv format for like (internal tables)

Hi,
I making a report in which i am using the concept of 2 internal tables and i am usnig the concept of likes in a internal table .
for instance,
DATA : BEGIN OF ITAB OCCURS 0,
 ITEMID LIKE CHVW-MATNR,
 WERKS LIKE CHVW-WERKS,
 CHARG LIKE CHVW-CHARG,
 SHKZG LIKE CHVW-SHKZG,
 MENGE LIKE CHVW-MENGE,
 MEINS LIKE CHVW-MEINS,
END OF ITAB.
DATA: BEGIN OF ITAB1 OCCURS 0,
 MATNR TYPE BSEG-MATNR,
 LIFNR TYPE BSEG-LIFNR,
 AUGDT TYPE BSEG-AUGDT,
 WRBTR TYPE BSEG-WRBTR,
 END OF IT_BSEG.
and i am able to create ALV for 1 itab only as i had declared all fields in a 1 itab ,but now i have to declare 1 more itab and i dont know how to perform ALV with 2 itabs..
Plzz help me out as it is really urgent to me.
Edited by: ric .s on Apr 22, 2008 11:45 AM
Edited by: ric .s on Apr 23, 2008 7:21 AM
Edited by: ric .s on Apr 23, 2008 7:55 AM

Hi Ric,
Yes, You can .
Check the sample ALV program which helps u in displaying output using ALV . Comments have been made everywhere .
report zvenkat_alv_2_grid_description.
types:
 begin of t_mard,
 werks type mard-werks,
 lgort type mard-lgort,
 matnr type mard-matnr,
 insme type mard-insme,
 einme type mard-einme,
 speme type mard-speme,
 end of t_mard.
data:
 w_mard type t_mard.
data:
 i_mard type standard table of t_mard.
" ALV Declarations
" ALV internal tables and Structures
" To refer ALV tables(slis tables) and structures.SLIS must be
" declared under TYPE-POOLS(see below).SLIS is a Type group which is
" defined in Dictionary.Internal tables and structures and constants
" are defined under type group.(Double click on SLIS).
* Types Pools
type-pools:
 slis.
* Types
types:
 t_fieldcat type slis_fieldcat_alv,
 t_events type slis_alv_event,
 t_layout type slis_layout_alv.
* Workareas
data:
 w_fieldcat type t_fieldcat,
 w_events type t_events,
 w_layout type t_layout.
* Internal Tables
data:
 i_fieldcat type standard table of t_fieldcat,
 i_fieldcat1 type standard table of t_fieldcat,
 i_events type standard table of t_events.
*& START-OF-SELECTION
start-of-selection.
perform get_data_from_database .
" END-OF-SELECTION
" Steps to create simple ALV program
" 1. Pass an internal table with the set of output information
" 2. Pass a field catalog as an internal table
" 3. Pass a structure with general list layout details
end-of-selection.
perform build_fieldcatalog.
perform build_events.
perform build_layout.
perform display_data.
" Form build_fieldcatalog
" Fieldcatalog Internal table
" 1. It contains descriptions of the list output fields
" (usually a subset of the internal output table fields).
" 2. A field catalog is required for every ALV list output.
form build_fieldcatalog .
clear :
 w_fieldcat,
 i_fieldcat[].
perform build_fcat using:
 "Field Int.Table Column headings
 'WERKS' 'I_MARD' 'WERKS',
 'LGORT' 'I_MARD' 'LGORT',
 'MATNR' 'I_MARD' 'MATNR',
 'INSME' 'I_MARD' 'INSME',
 'EINME' 'I_MARD' 'EINME',
 'SPEME' 'I_MARD' 'SPEME'.
endform. " build_fieldcatalog
*& Form display_data
form display_data .
data :program like sy-repid value sy-repid.
call function 'REUSE_ALV_LIST_DISPLAY'
 exporting
 i_callback_program = program
 is_layout = w_layout
 it_fieldcat = i_fieldcat
 it_events = i_events
 tables
 t_outtab = i_mard.
if sy-subrc <> 0.
 message id sy-msgid type sy-msgty number sy-msgno
 with sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
endif.
endform. " display_data
*& Form get_data_from_database
* text
form get_data_from_database .
clear :i_mard,
 i_mard[].
select werks lgort matnr insme einme speme
from mard
into corresponding fields of table i_mard
 up to 100 rows.
endform. " get_data_from_database
*& Form top_of_page
* text
form top_of_page.
data :
i_header type slis_t_listheader,
w_header like line of i_header.
data:l_date1 type datum,
 l_date2 type datum.
w_header-typ = 'S'.
w_header-info = sy-title.
append w_header to i_header.
clear w_header.
w_header-typ = 'H'.
w_header-info = sy-repid.
append w_header to i_header.
clear w_header.
call function 'REUSE_ALV_COMMENTARY_WRITE'
 exporting
 it_list_commentary = i_header
 i_logo = 'ENJOYSAP_LOGO'.
endform. "top_of_page
*& Form BUILD_FCAT
form build_fcat using l_field l_tab l_text.
w_fieldcat-fieldname = l_field.
w_fieldcat-tabname = l_tab.
w_fieldcat-seltext_m = l_text.
append w_fieldcat to i_fieldcat.
clear w_fieldcat.
endform. " BUILD_FCAT
" Form build_events
" Events
" 1. When we use ALV,certain events TOP-OF-PAGE ,END-OF-PAGE,
" AT LINE-SELECTION,AT USER-COMMANDs are not triggered.
" 2. To perform those Functions ,we have to build Events table and
" pass this table through REUSE_ALV_LIST_DISPALY Function.
form build_events .
clear :
 w_events,i_events[].
w_events-name = 'TOP_OF_PAGE'.
w_events-form = 'TOP_OF_PAGE'.
append w_events to i_events.
clear w_events.
endform. " build_events
"& Form build_layout
" Layouts
" Use :We change the display of our list using layouts.
" ===
" Features
" ========
" The layouts that you can use vary according to the type of list:
" 1-->In all lists, you can do the following:
" (a).Choose one of the std layouts supplied with the std system.
" (b).Change the current layout of the list .
" 2-->In lists that use only the standard layouts in the std system
" you cannot save your changes to the current layout.When you
" choose the layouts, only the standard layouts will be proposed.
" 3-->In some lists, you can also save the layouts that you have
" defined as our own layouts.
" User-defined layouts are generally saved for all users. They can
" then be used by all users. All users will be able to choose from
" the user-defined layouts as well as the standard layouts.
" 4-->In some lists, you can also save user-specific layouts that you
" have defined . When you choose the current layout,only these
" layouts are available to you.
" 5-->You can delete or transport layouts, or define them as initial
" layouts
" 6-->STRUCTURE :SLIS_LAYOUT_ALV.
form build_layout .
clear:
 w_layout.
w_layout-colwidth_optimize = 'X'.
endform. " build_layout
Regards,
Venkat.O

Alv grid using dynamic internal table

hi i have an internal table
begin of itab
equipno like equi-equnr,
reading like imrg-readg
uom like imrg-uom
date like imrg-date
end of itab.
and many more fields in this table the reading, date, uom are dynamic its not fixed there can be five readings and 6 reading etc
if i get all the data populated into final table itab. how to display it throgh the alv grid
i can use fieldsymbols i have seen some documents i want to know how to populate the fieldname s of the dynamic internal table to the field catalog and the values of the dynamic internal table .its a alv grid display pls guide

Hi,
Before displaying the records in ALV, you integrate all the fields (Fixed fields as well as variable fields) into one table. To do so you need create one dynamic table. If you already created this dynamic table then in the same way (same sequence) you need to populate the field catalog and use normal FM REUSE_ALV_GRID_DISPLAY to display it.
If you not aware of how to create this dynamic internal table, please check the below way.
1. Populate the fixed field into one field catalog(NB. this to create dyn table not ALV).
*--- Cons Unit
wa_lvc_cat-fieldname = c_cons.
wa_lvc_cat-ref_field = c_rbunit.
wa_lvc_cat-ref_table = c_ecmca.
append wa_lvc_cat to it_lvc_cat.
*--- account description
wa_lvc_cat-fieldname = c_acctd.
wa_lvc_cat-ref_field = c_txtmi.
wa_lvc_cat-ref_table = c_tf101.
append wa_lvc_cat to it_lvc_cat.
2. For variable fields you have your own logic based on which you need to display the output. (like loop at one table and make each field as one column). Here one thing need to make sure every time field name should be different. You know in one structure there are 2 fields with same name is not allowed.
3. next use the below method to create the internal table
Create a new Table
call method cl_alv_table_create=>create_dynamic_table
 exporting
 it_fieldcatalog = it_lvc_cat
 importing
 ep_table = it_new_table.
Create a new Line with the same structure of the table.
assign it_new_table->* to <l_table>. " internal table
create data wa_new_line like line of <l_table>.
assign wa_new_line->* to <l_line>. " Work area
4. To populate the field catalog for ALV use the same sequence. Better while you populated it_lvc_cat for dynamic table also create one lookup table with three fields. (fieldname, Text, col_pos). Here loop into this look up table and populate the ALV field catalog.
5. Display it using REUSE_ALV_GRID_DISPLAY
call function 'REUSE_ALV_GRID_DISPLAY'
 exporting
 i_callback_program = c_rep_name
 i_callback_user_command = 'F_USER_DOUBLE_CLICK' "SD0K963313
 is_layout = l_wa_layout
 it_fieldcat = it_fieldcat
 it_sort = it_sort
 i_save = l_save
 is_variant = wa_variant1
 it_events = it_events
 tables
 t_outtab = <l_table>
 exceptions
 program_error = 1
 others = 2.
Thanks
Subhankar

How to upload data with dynamic internal table

Hi,
I have to upload the basic , sales, purchasing view data by using bapi depend on check box selected for views.
i have filled fieldcatalog for selected views and pass the field catalog structure to dynamic int table and
import it into the field symbol <fs_data>. this field symbol assigned to <fs_1>.
then callED the 'GUI_UPLOAD ' and when i pass field symbo for function module i am getting first 10 rows 0f the file .
flat file has basic data,sales ,purchase fields data
ex: i was selected basicview and purchase view and execute i am getting basic,sales view data.
how can i get only basic and purchase data.

hi ,
please find code.
CALL METHOD cl_alv_table_create=>create_dynamic_table
 EXPORTING
 it_fieldcatalog = lt_fieldcatalog
 IMPORTING
 ep_table = <fs_data>
 EXCEPTIONS
 generate_subpool_dir_full = 1
 OTHERS = 2.
IF sy-subrc <> 0. "#EC NEEDED
ENDIF.
So <FS_1> now points to our dynamic internal table.
ASSIGN <fs_data>->* TO <fs_1>.
Next step is to create a work area for our dynamic internal table.
CREATE DATA new_line LIKE LINE OF <fs_1>.
A field-symbol to access that work area
ASSIGN new_line->* TO <fs_2>.
ASSIGN new_line->* TO <fs_3>.
CALL FUNCTION 'GUI_UPLOAD'
 EXPORTING
 filename = p_f
 filetype = 'DAT'
 TABLES
 data_tab = <fs_1>
 EXCEPTIONS
 file_open_error = 1
 file_read_error = 2
 no_batch = 3
 gui_refuse_filetransfer = 4
 invalid_type = 5
 no_authority = 6
 unknown_error = 7
 bad_data_format = 8
 header_not_allowed = 9
 separator_not_allowed = 10
 header_too_long = 11
 unknown_dp_error = 12
 access_denied = 13
 dp_out_of_memory = 14
 disk_full = 15
 dp_timeout = 16
 OTHERS = 17.
IF sy-subrc <> 0.
 MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
 WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
ENDIF.

ALV reprot With four internal tables

Similar Messages

Maybe you are looking for