Analyser: Presenting negative key figures in red font

Question

I need to show negative key figures with a red font within Analyser. I have got as far as creating a template workbook and in there changing the SAPBExStdData style to include number formatting that has red negatives. When I create a workbook based on this template and check the style of one of the negative values, then it is picking up my modified style. However, the style is not actually being applied unless I select each cell, open the style dialog and click OK! Even if I do this the colour reverts back to black at the first refresh. Any ideas?

Answer 1

I solved the requirement with the following code, this retains the formatting (currency etc) applied by BEx and also checks to see that the cell background is not set to red (for example by an exception).
Sub SAPBEXonRefresh(queryID As String, resultArea As Range)
    Dim negColour As String
    ' loop through all cells in the results area
    For Each c In resultArea.Cells
        ' ignore cells with no number formatting at all
        If c.NumberFormat > "" Then
            ' make sure that the number formatting includes actual numbers
            If InStr(c.NumberFormat, "0") > 1 Then
                ' if the background is red then use white to colour negative values
                If c.Interior.ColorIndex = 3 Then
                    negColour = "[White]"
                ' otherwise use red text for negatives
                Else
                    negColour = "[Red]"
                End If
                ' if the number format is already split for negative values
                If InStr(c.NumberFormat, ";") > 1 Then
                    ' insert just the negative colour formatting
                    c.NumberFormat = Replace(c.NumberFormat, ";", ";" & negColour)
                ' otherwise the split and formatting need to be added
                Else
                    c.NumberFormat = c.NumberFormat & ";" & negColour & "-" & c.NumberFormat
                End If
            End If
        End If
    Next
End Sub