Analyze dbms_profiler

Question

Hi folks!
I'm at the beginning of analyze PL/SQL code. I'm using dbms_profiler. For one of our packages, dbms_profiler show me:
Top 10 profiled source lines in terms of Total Time (plsql_profiler_data)
Top Total Time1 Times Executed Min Time2 Max Time2 Unit Owner Name Type Line Text
1 75.76 431010 0.00 0.01 1 USER package PACKAGE BODY 165 fetch c_IconsByDist bulk collect into l_IDs; 
2 72.13 431010 0.00 0.01 1 USER package PACKAGE BODY 161 fetch c_CountByDist bulk collect into tmp_NumsAs you can see this row of code fetches cursor into collection. Cursor:
cursor c_IconsByDist is
      select i.icon_id
      from (select rownum as num, column_value as icon_id
            from table(tmp_IDs)) i,
           (select rownum as num, column_value as dist
            from table(tmp_Distances)) d,
           (select column_value as dist
            from table(tmp_Nums)) t
      where i.num = d.num and
            d.dist = t.dist
      order by d.dist;May be, I can speed up this piece of code? Any ideas :)
Regards,
Pavel.

Answer 1

Thanks for reply. Code of this function:
function get_icon(
    p_Table varchar2,
    p_ID number)
    return number
  as
    l_ID      number;
    l_x       number;
    l_y       number;
    l_flag    boolean;
    l_Table   varchar2(128);
    arr_IDs   gg_utils.TSuperNumberArray := gg_utils.TSuperNumberArray();
    l_IDs     TNumberArray := TNumberArray();
    tmp_IDs   TNumberArray := TNumberArray(null);
    tmp_TypeIDs TNumberArray := TNumberArray(null);
    cursor c_RegulationProt is
      select p.object_id, u.type as object_type_id
      from   regulation_prot p, units u
      where  p.id = p_ID AND u.id = p.object_id;
    -- more simple than regulation_ascr view
    cursor c_Regulations is
      SELECT DISTINCT object_id, object_type_id
      FROM reg_ascr
      WHERE id = p_ID;
  begin
    DBMS_APPLICATION_INFO.SET_MODULE(G_MODULE_NAME, 'get_icon');
    l_Table := upper(p_Table);
    if l_Table IN ('PROTS', 'CHEMS', 'UNITS') then
      -- Some kind of Units
      l_IDs := get_icon_ids(p_ID);
    elsif l_Table = 'REACTS' then
      -- Reactions
      l_IDs := get_icon_ids(p_ID, -1);
    elsif l_Table = 'GENES' then
      -- Genes
      l_IDs := get_icon_ids(p_ID, -2);
    elsif l_Table = 'FUNCS' then
      -- Enzymes (funxtions)
      l_IDs := get_icon_ids(p_ID, -3);
    elsif l_Table = 'CLASS' then
      -- For this type of p_Table forms Collection of Collections (TSuperNumberArray)
      -- First source of object types and IDs
      open c_RegulationProt;
      fetch c_RegulationProt bulk collect into tmp_IDs, tmp_TypeIDs;
      close c_RegulationProt;
      if tmp_IDs.count = 0 then
        -- Second source of object types and IDs when first source is empty
        open c_Regulations;
        fetch c_Regulations bulk collect into tmp_IDs, tmp_TypeIDs;
        close c_Regulations;
      end if;
      -- fill arr_IDs with collections of get_icon_ids
      if tmp_IDs.count = 0 then
        l_IDs := get_icon_ids(p_ID);
        arr_IDs.extend;
        arr_IDs(1) := l_IDs;
      else
        arr_IDs.extend(tmp_IDs.count);
        for i in 1..tmp_IDs.count loop
          l_IDs := get_icon_ids(tmp_IDs(i), tmp_TypeIDs(i));
          arr_IDs(i) := l_IDs;
        end loop;
      end if;
    else
      sys_error.raise_error(sys_error.UNKNOWN_ICON_TYPE, l_Table);
    end if;
    l_ID := -1;
    -- for 'CLASS' use collection of collections "arr_IDs" insted of single collection "l_IDs"
    if l_Table = 'CLASS' then
      l_x := arr_IDs.count;
    else
      l_x := l_IDs.count;
    end if;
    if l_x = 0 then
      l_ID := 3;
    elsif l_x = 1 then
      l_ID := l_IDs(1);
    else
      if arr_IDs.count > 0 then
        l_IDs := TNumberArray();
        -- put in l_IDs only IDs, which exists in all of arrays
        -- first, get array with maximum count of elements
        l_x := 0;
        l_y := 0;
        for i in 1..arr_IDs.count loop
          if arr_IDs(i).count > l_x then
            l_x := arr_IDs(i).count;
            l_y := i;
          end if;
        end loop;
        -- now tmp_IDs have maximum of elements
        tmp_IDs := arr_IDs(l_y);
        -- trying find any elements of tmp_IDs in other arrays
        for i in 1..tmp_IDs.count loop
          l_flag := true;
          for j in 1..arr_ids.count loop
            l_flag := l_flag AND (tmp_IDs(i) member of arr_IDs(j));
            exit when not l_flag;
          end loop;
          if l_flag then
            l_IDs.extend;
            l_IDs(l_IDs.LAST) := tmp_IDs(i);
          end if;
        end loop;
      end if;
      if l_IDs.count > 0 then
        l_ID := l_IDs(1);
      end if;
    end if;
    if l_ID < 0 then
      l_ID := 1;
    end if;
    DBMS_APPLICATION_INFO.SET_MODULE(null, null);
    return l_ID;
  end get_icon;And this function call another function as you can see:
  function get_icon_ids(
    p_ID integer,
    p_TypeID integer default null)
    return TNumberArray
  as
    l_TypeID      integer;
    is_gene       integer;
    l_IDs         TNumberArray := TNumberArray(null);
    tmp_IDs       TNumberArray := TNumberArray(null);
    tmp_Distances TNumberArray := TNumberArray(null);
    tmp_Nums      TNumberArray;
   cursor c_KndUnitIcons(p_TypeID integer) is
      select default_icon_id as icon_id, 1000 as dist
      from   knd_units
      where  ID = p_TypeID;
    cursor c_SelfIcons is
      select icon_id, 0 as dist
      from proticons
      where prot_id = p_ID;
    cursor c_UnitIcons is
      select distinct i.icon_id, r.dist
      from proticons i, unitrelflat r
      where r.unitg = i.prot_id and
            r.unitm = p_ID and
            r.dist >= 0
      order by r.dist;
    cursor c_IconsG is
      select i.icon_id, 0 as dist
      from proticons i, geneprot g
      where i.prot_id = g.prot and
            g.gene = p_ID;
    cursor c_IconsG2 is
      select i.icon_id, r.dist
      from protrelflat r, proticons i, geneprot g
      where r.protgrp = i.prot_id and
            r.protmbr = g.prot and
            r.dist >= 0 and
            g.gene = p_ID
      order by r.dist;
    -- get distances with only icon
-->>>>Spent the most time of execution
    cursor c_CountByDist is
      select d.dist
      from (select rownum as num, column_value as icon_id
            from table(tmp_IDs)) i,
           (select rownum as num, column_value as dist
            from table(tmp_Distances)) d
      where i.num = d.num
      having count(icon_id) = 1
      group by dist
      order by dist;
    -- found distances for only icons from c_CountByDist
-->>>>Spent the most time of execution
    cursor c_IconsByDist is
      select i.icon_id
      from (select rownum as num, column_value as icon_id
            from table(tmp_IDs)) i,
           (select rownum as num, column_value as dist
            from table(tmp_Distances)) d,
           (select column_value as dist
            from table(tmp_Nums)) t
      where i.num = d.num and
            d.dist = t.dist
      order by d.dist;
    procedure fill_by_default(
      p_TypeID integer,
      p_DefaultID number default 1)
    as
      l_ID       number;
      l_Distance number;
    begin
      open c_KndUnitIcons(p_TypeID);
      fetch c_KndUnitIcons into l_ID, l_Distance;
      close c_KndUnitIcons;
      tmp_IDs.extend(1);
      tmp_IDs(tmp_IDs.count) := nvl(l_ID, p_DefaultID);
      tmp_Distances.extend(1);
      tmp_Distances(tmp_Distances.count) := nvl(l_Distance, 2000);
    end fill_by_default;
    procedure fill_for_units(
      p_TypeID integer)
    as
    begin
      -- first, find self icon
      open c_SelfIcons;
      fetch c_SelfIcons bulk collect into tmp_IDs, tmp_Distances;
      close c_SelfIcons;
      if tmp_IDs.count = 0 then
        open c_UnitIcons;
        fetch c_UnitIcons bulk collect into tmp_IDs, tmp_Distances;
        close c_UnitIcons;
      end if;
      fill_by_default(p_TypeID);
    end fill_for_units;
  begin
    DBMS_APPLICATION_INFO.SET_MODULE(G_MODULE_NAME, 'get_icon_ids');
    l_TypeID := nvl(p_TypeID, unit_service.get_type_id(p_ID));
    case l_TypeID
      when -2 then
        -- for Genes
        open c_IconsG;
        fetch c_IconsG bulk collect into tmp_IDs, tmp_Distances;
        close c_IconsG;
        if tmp_IDs.count = 0 then
          open c_IconsG2;
          fetch c_IconsG2 bulk collect into tmp_IDs, tmp_Distances;
          close c_IconsG2;
        end if;
        if tmp_IDs.count = 0 then
          tmp_IDs.extend(1);       -- tmp_IDs is null after empty bulk collect
          tmp_IDs(1) := 1;
          tmp_Distances.extend(1); -- tmp_Distances is null after empty bulk collect
          tmp_Distances(1) := 1;
        end if;
      when -1 then
        fill_by_default(l_TypeID);
      when -3 then
        fill_by_default(l_TypeID);
      else
        fill_for_units(l_TypeID);
    end case;
    open c_CountByDist;
    fetch c_CountByDist bulk collect into tmp_Nums;
    close c_CountByDist;
    open c_IconsByDist;
    fetch c_IconsByDist bulk collect into l_IDs;
    close c_IconsByDist;
    if l_IDs.count = 0 then
      l_IDs.extend(1);
      if p_TypeID = -1 then
        l_IDs(1) := 54;
      else
        l_IDs(1) := 1;
      end if;
    end if;
    DBMS_APPLICATION_INFO.SET_MODULE(null, null);
    return l_IDs;
  end get_icon_ids;Now, I reviewing the code. Any help is appreciated.
Regards,
Pavel.