Any suggestions about this program to improve performance and effective cod

Question

CREATE OR REPLACE PACKAGE SEODS02.ODS_ACCOUNT
AS
Package Name : ODS_ACCOUNT
/* Description : This procedure will be called to move the data from */
/* ACCT_ALT_ID_STG (staging) table to ACCT_ALT_ID table and EODS_ACCT */
/* table for all new accounts */
/**************** Change History ***********************************/
/* Date Version Author Description */
/* 15-04-2011 1.00 Lakshmi Draft version */
-- Global Specifications.
package_name_in VARCHAR2(50) :='ODS_ACCOUNT';
v_cntl_schema VARCHAR2(30) :='SCNTL02';
v_location INTEGER := 10;
-- Procedure Specifications.
PROCEDURE INSERT_SURR_ACCTS (job_name_in IN VARCHAR2,
proc_cd_in IN VARCHAR2,
proc_step_cd_in IN VARCHAR2,
bch_dte_in IN DATE,
fl_nbr_in IN NUMBER,
verbose_log_flag_in IN INTEGER,
pred_check_req_in IN INTEGER,
ibd_id_in IN NUMBER,
proc_step_status_out OUT INTEGER,
sp_hier_inout IN OUT VARCHAR2);
END ODS_ACCOUNT;
CREATE OR REPLACE PACKAGE BODY SEODS02.ODS_ACCOUNT
AS
Procedure Name : INSERT_SURR_ACCTS
Description : This procedure will be called to move the data from
ACCT_ALT_ID_STG (staging) table to ACCT_ALT_ID table
and EODS_ACCT table for all new accounts.
Release Date : 27 MAY 2011
Created By : C2119810
PROCEDURE INSERT_SURR_ACCTS (job_name_in IN VARCHAR2,
proc_cd_in IN VARCHAR2,
proc_step_cd_in IN VARCHAR2,
bch_dte_in IN DATE,
fl_nbr_in IN NUMBER,
verbose_log_flag_in IN INTEGER,
pred_check_req_in IN INTEGER,
ibd_id_in IN NUMBER,
proc_step_status_out OUT INTEGER,
sp_hier_inout IN OUT VARCHAR2)
AS
/* Local Variables Declaration*/
v_curr_date DATE := CURRENT_DATE;
procedure_name_in VARCHAR2(30) := 'INSERT_SURR_ACCTS';
stat_code_in VARCHAR2(30);
proc_step_start_out NUMBER(1);
proc_step_upd_out NUMBER(1);
error_msg_in VARCHAR2(1000);
option_in VARCHAR2(30);
v_cmit_nbr NUMBER(8);
v_query VARCHAR2(10000);
v_actl_inpt_cnt NUMBER(10):=0;
v_rec_inserted_cnt_in NUMBER(10):=0;
v_rec_errored_cnt_in NUMBER(10):=0;
v_proc_step_upd_out NUMBER(1);
handled_exception EXCEPTION;
CURSOR c1 IS
SELECT *
FROM acct_alt_id_stg
WHERE fl_nbr = fl_nbr_in AND
alt_acct_rec_proc_flag = 'N' AND
eods_acct_rec_proc_flag = 'N' AND
to_date(bch_dte,'DD-MON-YY') <= bch_dte_in;
TYPE sttg_cursor IS TABLE OF acct_alt_id_stg%ROWTYPE;
sttg_array sttg_cursor;
BEGIN
/* Enable the logging if verbose log flag is 0*/
IF verbose_log_flag_in = 0 THEN
DBMS_OUTPUT.ENABLE();
ELSE
DBMS_OUTPUT.DISABLE();
END IF;
/* Start the Insert Surrogate Accounts process step after all the predecessor process steps are complete */
ODS_CONTROL_UTILITY.PROC_STEP_START( proc_cd_in => proc_cd_in,
proc_step_cd_in => proc_step_cd_in,
ibd_id_in => ibd_id_in,
bch_dte_in => bch_dte_in,
job_name_in => job_name_in,
verbose_log_flag_in => verbose_log_flag_in,
pred_chk_reqd_in => pred_check_req_in,
proc_step_stat_out => proc_step_start_out,
sp_hier_inout => sp_hier_inout);
IF proc_step_start_out = 0 THEN
dbms_output.put_line('Process Step '|| proc_step_cd_in ||' started for Process '||proc_cd_in);
error_msg_in := 'Error in reading Commit point';
v_query := 'SELECT proc_cmit_nbr FROM '||v_cntl_schema||'.proc
WHERE proc_id = '|| chr(39) || proc_cd_in || chr(39) ||
' AND ibd_id = '|| ibd_id_in;
EXECUTE IMMEDIATE v_query INTO v_cmit_nbr;
dbms_output.put_line('Comit point number is : '||v_cmit_nbr);
OPEN c1;
LOOP
FETCH c1 BULK COLLECT INTO sttg_array LIMIT v_cmit_nbr;
FOR i IN 1..sttg_array.COUNT LOOP
error_msg_in := 'Error in inserting ACCT_ALT_ID table';
INSERT INTO acct_alt_id (acct_alt_id, ibd_id, acct_alt_id_cntx_cde, eods_acct_id, data_grp_cde, crte_pgm, crte_tstp, updt_pgm, updt_tstp)
VALUES (sttg_array(i).acct_alt_id, sttg_array(i).ibd_id, sttg_array(i).acct_alt_id_cntx_cde, seq_eods_acct_id.nextval, sttg_array(i).data_grp_cde, job_name_in, v_curr_date, job_name_in, v_curr_date);
error_msg_in := 'Error in inserting EODS_ACCT table';
INSERT INTO eods_acct (eods_acct_id, acct_typ_cde, data_grp_cde, updt_dte)
VALUES (seq_eods_acct_id.currval, sttg_array(i).acct_typ_cde, sttg_array(i).data_grp_cde, v_curr_date);
error_msg_in := 'Error in Updating process flag in ACCT_ALT_ID_STG table';
UPDATE acct_alt_id_stg
SET alt_acct_rec_proc_flag = 'Y',
eods_acct_rec_proc_flag = 'Y',
updt_pgm = job_name_in,
updt_tstp = v_curr_date
WHERE acct_alt_id = sttg_array(i).acct_alt_id
AND acct_alt_id_cntx_cde = sttg_array(i).acct_alt_id_cntx_cde
AND fl_nbr = sttg_array(i).fl_nbr;
/*Incrementing the count of records inserted*/
v_actl_inpt_cnt := v_actl_inpt_cnt + 1;
v_rec_inserted_cnt_in := v_rec_inserted_cnt_in + 1;
END LOOP;
EXIT WHEN c1%NOTFOUND;
END LOOP;
CLOSE c1;
/* Update the count of records inserted and total processed count to proc_step_exec table. */
ODS_CONTROL_UTILITY.PROC_STEP_UPDATE (proc_cd_in => proc_cd_in,
proc_step_cd_in => proc_step_cd_in,
ibd_id_in => ibd_id_in,
bch_dte_in => bch_dte_in,
job_name_in => job_name_in,
status_in => 'IN PROCESS',
rec_inserted_cnt_in => v_rec_inserted_cnt_in,
actl_inpt_cnt_in => v_actl_inpt_cnt,
verbose_log_flag_in => verbose_log_flag_in,
pred_chk_reqd_in => pred_check_req_in,
proc_step_upd_out => proc_step_upd_out,
sp_hier_inout => sp_hier_inout);
IF proc_step_upd_out = 0 THEN
COMMIT;
ELSE
error_msg_in := 'Issue in updating process step '||proc_step_cd_in||' for process '||proc_cd_in;
option_in := 'proc_step';
v_location := 30;
RAISE handled_exception;
END IF;
ODS_CONTROL_UTILITY.PROC_STEP_UPDATE (proc_cd_in => proc_cd_in,
proc_step_cd_in => proc_step_cd_in,
ibd_id_in => ibd_id_in,
bch_dte_in => bch_dte_in,
job_name_in => job_name_in,
status_in => 'COMPLETED',
verbose_log_flag_in => verbose_log_flag_in,
pred_chk_reqd_in => pred_check_req_in,
proc_step_upd_out => v_proc_step_upd_out,
sp_hier_inout => sp_hier_inout);
IF v_proc_step_upd_out = 0 THEN
COMMIT;
dbms_output.put_line('Data has been successfully inserted into ACCT_ALT_ID and EODS_ACCT tables');
proc_step_status_out := 0;
ELSE
error_msg_in := 'Issue in ending process step for process ' || proc_cd_in || ' and process step '|| proc_step_cd_in;
option_in := 'others';
v_location := 40;
RAISE handled_exception;
END IF;
ELSE
error_msg_in := 'Issue in starting the process step for process ' || proc_cd_in || ' and process step '|| proc_step_cd_in;
option_in := 'others';
RAISE handled_exception;
END IF;
EXCEPTION
WHEN handled_exception THEN
IF c1%ISOPEN THEN
CLOSE c1;
END IF;
ROLLBACK;
DBMS_OUTPUT.ENABLE();
ODS_CONTROL_UTILITY.COMM_SP_EXCEP_HNDLR(package_name_in => package_name_in,
procedure_name_in => procedure_name_in,
location_in => v_location,
error_mesg_in => error_msg_in,
proc_cd_in => proc_cd_in,
proc_step_cd_in => proc_step_cd_in,
ibd_id_in => ibd_id_in,
option_in => option_in,
job_name_in => job_name_in,
bch_dte_in => bch_dte_in,
sp_hier_inout => sp_hier_inout);
sp_hier_inout :=
CASE
WHEN sp_hier_inout IS NULL THEN package_name_in || '.' || procedure_name_in
WHEN sp_hier_inout IS NOT NULL THEN package_name_in || '.' || procedure_name_in || '-->' || sp_hier_inout
END;
proc_step_status_out := 1;
WHEN OTHERS THEN
IF c1%ISOPEN THEN
CLOSE c1;
END IF;
ROLLBACK;
error_msg_in := error_msg_in||' : '||SQLCODE || ' : '||SQLERRM;
DBMS_OUTPUT.ENABLE();
option_in := 'proc_step';
ODS_CONTROL_UTILITY.COMM_SP_EXCEP_HNDLR(package_name_in => package_name_in,
procedure_name_in => procedure_name_in,
location_in => v_location,
error_mesg_in => error_msg_in,
proc_cd_in => proc_cd_in,
proc_step_cd_in => proc_step_cd_in,
ibd_id_in => ibd_id_in,
option_in => option_in,
job_name_in => job_name_in,
bch_dte_in => bch_dte_in,
sp_hier_inout => sp_hier_inout);
sp_hier_inout :=
CASE
WHEN sp_hier_inout IS NULL THEN package_name_in || '.' || procedure_name_in
WHEN sp_hier_inout IS NOT NULL THEN package_name_in || '.' || procedure_name_in || '-->' || sp_hier_inout
END;
proc_step_status_out := 1;
END INSERT_SURR_ACCTS;
END ODS_ACCOUNT;
/

Answer 1

I assume that the parts taking time are in the
FOR i IN 1..sttg_array.COUNT LOOP In here you do 2 INSERTs and an UPDATE for every loop...
If you LOOP 1 Mill tiimes (how many??) then you do 2 Mill single inserts and 1Mill sinlge UPDATES.
A trace with TKPROF will tell you details.
You better do an INSERT ALL to do the two inserts and a MERGE to do the UDPATE. NO LOOP!!! That will reduce the code and maximize performance by a magniture.