Aperture 3 Places Data not Imported Into iPhoto

Question

I tagged the location of a set of photos in Aperture 3 using Places. Then i went to iPhoto, and used the import from Aperture function to bring the whole set into iPhoto in a single move. One of the 24 images carried the Places data with it; the rest had no location associated with them. I suppose this is a bug, but if anyone else had this experience or has a suggestion for a fix, please weigh in. Thanks.

Answer 1

Ok, just discovered that it's not an issue with the handling of zero's in GPS coordinates, but a problem with filename or file paths containing invalid characters - I've had folders such as "FA Cup final (mum's photos)".
So I've picked up a tiny amount of apple script and tweaked the code some more. PLEASE CAN I STRESS I KNOW VERY LITTLE ABOUT APPLE SCRIPT SO USE AT YOUR OWN RISK; it does work fine for me though!
All credit to Juri Pakaste at http://juripakaste.fi/cgi/pyblosxom.cgi/iphoto-geodata-applescript.html
-- This applescript will geotag the selected photos with the
-- location information set in iPhoto.
-- You must have exiftool installed; by default it's loaded from
-- /opt/local/bin, where MacPorts installs it from the package
-- p5-image-exiftool.
-- Author: Juri Pakaste (http://www.juripakaste.fi/)
-- Based on the Set Geo Data.scpt script by
-- Andrew Turner (http://highearthorbit.com)
property exifToolOriginal : "_original"
property exifToolPath : "/usr/bin/exiftool"
on extract_decimal(realnum)
log "extracting decimal from " & realnum
repeat while realnum > 1
log "realnum now " & realnum & ", subtracting 1"
set the realnum to realnum - 1
end repeat
realnum
end extract_decimal
on roundFloat(n, precision)
set x to 10 ^ precision
(((n * x) + 0.5) div 1) / x
end roundFloat
on d2s(degs)
log "enter d2s"
if the degs < 0 then
set the degs to degs * -1
end if
set the degrees to round degs rounding down
set the minssecs to extract_decimal(degs)
log "minssecs: " & minssecs
set the minssecs to minssecs * 60
set the mins to round minssecs rounding down
set the minssecs to extract_decimal(minssecs)
log "minssecs 2: " & minssecs
set the secs to minssecs * 60
"" & degrees & "," & mins & "," & roundFloat(secs, 2)
end d2s
on exportCoords(image_file, lat, lng, alt)
set the northSouth to "N"
set the eastWest to "E"
if the lat is less than 0 then
set the northSouth to "S"
set the lat to the lat * -1
end if
if the lng is less than 0 then
set the eastWest to "W"
set the lng to the lng * -1
end if
log "calling d2s on " & lat
set the latstr to my d2s(lat)
set the lngstr to my d2s(lng)
set exifCommand to exifToolPath & " -GPSMapDatum=WGS-84 -gps:GPSLatitude='" & latstr & "' -gps:GPSLatitudeRef='" & northSouth ¬
& "' -gps:GPSLongitude='" & lngstr & "' -gps:GPSLongitudeRef='" & eastWest ¬
& "' -xmp:GPSLatitude='" & latstr & northSouth & "' -xmp:GPSLongitude='" & lngstr & eastWest & "' -xmp:GPSMapDatum='WGS-84'" & " -xmp:GPSVersionID='2.2.0.0'" & " \"" & image_file & "\""
-- display dialog of ("running: " & exifCommand)
set output to do shell script exifCommand
-- display dialog of output
do shell script "rm \"" & image_file & "\"" & exifToolOriginal
end exportCoords
tell application "iPhoto"
activate
try
copy (my selected_images()) to these_images
if these_images is false or (the count of these_images) is 0 then ¬
error "Please select one or more images."
repeat with i from 1 to the count of these_images
set this_photo to item i of these_images
tell this_photo
set the image_file to the image path
set lat to the latitude
set lng to the longitude
set alt to the altitude
end tell
if lat < 90.1 and lng < 180.1 then
my exportCoords(image_file, lat, lng, alt)
else
display alert ("No location set for " & name of this_photo)
end if
log "read image, lat: " & lat & ", lng: " & lng
end repeat
display dialog "Geo Exif write complete."
on error error_message number error_number
if the error_number is not -128 then
display dialog of ("failed on: " & image_file)
display dialog error_message buttons {"Cancel"} default button 1
end if
end try
end tell
on selected_images()
tell application "iPhoto"
try
-- get selection
set these_items to the selection
-- check for single album selected
if the class of item 1 of these_items is album then error
-- return the list of selected photos
return these_items
on error
return false
end try
end tell
end selected_images