AppleScript: copy a file to a new location, changing its name

Question

I want to copy a selected file to a new location and change its name, both location and name adjustable by the user. It would seem natural to me (a neophyte) to use the Duplicate and Choose File Name commands to do this, so this is the module I came up with:
tell application "Finder"
          set myFile to the selection
          set textsAlias to alias "Campidoglio:Users:jeffreyjdean:Dropbox:Tinctoris:Editing Software:TextToJS:texts:"
          set fileForConversion to choose file name default name "shortname.txt" default location textsAlias
          try
  duplicate document file myFile to fileForConversion with replacing
          on error
                    display dialog "Error: Unable to save file."
          end try
end tell
This doesn't work. The error dialog comes up and this is the result report:
tell application "Finder"
  get selection
  --> {document file "12 De inventione et usu musice.txt" of folder "Edited texts" of folder "Desktop" of folder "jeffreyjdean" of folder "Users" of startup disk}
  choose file name default name "shortname.txt" default location alias "Campidoglio:Users:jeffreyjdean:Dropbox:Tinctoris:Editing Software:TextToJS:texts:"
  --> file "Campidoglio:Users:jeffreyjdean:Dropbox:Tinctoris:Editing Software:TextToJS:texts:shortname.txt"
  -- 'core'\'clon'{ 'insh':'furl'("file://localhost/Users/jeffreyjdean/Dropbox/Tinctoris/Editing%20 Software/TextToJS/texts/shortname.txt"), 'alrp':'true'("true"), '----':'obj '{ 'form':'indx', 'want':'docf', 'seld':[ 'obj '{ 'form':'name', 'want':'docf', 'seld':'utxt'("12 De inventione et usu musice.txt"), 'from':'obj '{ 'form':'name', 'want':'cfol', 'seld':'utxt'("Edited texts"), 'from':'obj '{ 'form':'name', 'want':'cfol', 'seld':'utxt'("Desktop"), 'from':'obj '{ 'form':'name', 'want':'cfol', 's…
  --> error number -1700 from {document file "12 De inventione et usu musice.txt" of folder "Edited texts" of folder "Desktop" of folder "jeffreyjdean" of folder "Users" of startup disk} to integer
  display dialog "Error: Unable to save file."
  --> {button returned:"OK"}
end tell
Result:
{button returned:"OK"}
Why is it telling me it can't duplicate a file to an integer? According to the AS Language Guide, the result of Choose File Name is "The selected location, as a file." How does this become an integer in my script?
That may be a side show. What I really want to work out is how to achieve the aim stated at the beginning: take a selected file (that part is working OK) and duplicate it to an arbitrary location with an arbitrary new name, decided by the user. What's the best way to go about this?
TIA,
Jeff
Message was edited by: Jeffrey Dean

Answer 1

I think you're misinterpreting the error message.
It's not complaining about your 'Choose File Name', per se.
There are two problems with your script.
First, you:
          set myFile to the selection
As far as the Finder is concerned, 'selection' is a list. It's always a list, even if only one item is selected - heck, it's still a list if no files are selected... just an empty list.
So that's the first thing the script is complaining about - you are using a list that you're trying to coerce to a file. Can't happen.
You have a couple of options here, depending on what you want to do.
You can tell the Finder to duplicate a list - it will simply duplicate all the files in the list. It has no problem with that, although you're going to run into problems when you try to set the file name(s). This highlights one of the design flaws with your script - how do you know the user only has one thing selected? At the very least you should check how many items are selected and react accordingly.
The other option is to iterate through the list, duplicating each file in turn. Again, it's not clear what you want/expect the outcome to be here - since you include 'with replacing', you'd likely end up with one file (the last one in the list) as being the named file and all other duplicates lost.
The third option is to expect there to be one item selected, and just act upon the first one - thereby ignoring multiple selections, although it's undefined as to which item is 'first' in the list.
Your call.
Once you get over the issue of identifying what you want to duplicate, the second issue with your script is how you're calling duplicate. You cannot duplicate one file to another file name. The duplicate command expects (demands?) a directory as the 'to' parameter, not a file name.
In other words, you can duplicate a file to a new directory. You cannot duplicate it to a new file name - at least not in one step. In order to do that you need to duplicate the file, then change its name (or use a shell script to do it 'under the hood').
This is complicated by the fact that it's the rename that requires you to check for duplicates, which you have to do manually.
So given the above, and assuming you expect/want one item to be selected, your script should look more like:
tell application "Finder"
          set myFile to item 1 of (get selection) -- ignore multiple selections
          set textsAlias to alias "Campidoglio:Users:jeffreyjdean:Dropbox:Tinctoris:Editing Software:TextToJS:texts:"
          set fileForConversion to choose file name default name "shortname.txt" default location textsAlias
          set fDir to do shell script "/usr/bin/dirname " & POSIX path of fileForConversion
          set fName to do shell script "/usr/bin/basename " & POSIX path of fileForConversion
          try
                    set newFile to duplicate myFile to POSIX file fDir with replacing
                    if (exists file fName of folder fDir) then
  delete file fName of folder fDir
                    end if
                    set name of newFile to fName
          on error
                    display dialog "Error: Unable to save file."
          end try
end tell
Incidentally, this is something that could be much more easily done with a shell command, since the shell isn't as sensitive about file paths and data types.