Applescript error -10000

Question

I have used, for a long time, an applescript I wrote to save out email attachments I get from students. The script gives the files new filenames so that I can tell which student the attachment is from, and so that another script I wrote for the finder can send the files back to the students after I've inserted my comments. After upgrading to Mountain Lion the script seems to be crapping out at the save step with an error number -10000. I can't seem to find any documentation on this error, and I have no idea what might have changed in applescript or OS X on Mountain Lion to cause this. Any ideas?
Here's my script:
set theOutputFolder to (choose folder) as string
tell application "Mail"
          set msgList to selection
          repeat with msg in msgList
                    set currentName to (sender of msg as rich text)
                    set theAttachments to every mail attachment of msg
                    repeat with a from 1 to length of theAttachments
                              set theAttachment to item a of theAttachments
                              set theAttachmentName to name of theAttachment as string
                              set AppleScript's text item delimiters to "."
                              set theAttachmentDelimit to the text items of theAttachmentName
                              set theAttachmentType to last item of theAttachmentDelimit
                              try
                                        set thefileName to currentName & a & "." & theAttachmentType
                                        set theSavePath to theOutputFolder & thefileName
  save theAttachment in theSavePath
                              end try
                    end repeat
          end repeat
end tell
And here's the relevant error (stripped of identifying information with ******):
save mail attachment id "3" of message id 85686 of mailbox "INBOX" of account "UAF" in "Steinitz:Users:*****:Dropbox:Courses:UAF:12Fall:631:HomeworkSolutions:HW1:***** ***** <*****@*****.edu>2.pdf"
  --> error number -10000

Answer 1

OK, I have a cludgy solution worked out, using a shell script to move the file from a location Applescript/Mail can save to, to the location I actually want the file to go. Here's the modified script that works.
set theOutputFolder to (choose folder) as string
tell application "Mail"
  activate
          set msgList to selection
          repeat with msg in msgList
                    set currentName to extract name from msg's sender
                    set theAttachments to every mail attachment of msg
                    repeat with a from 1 to length of theAttachments
                              set theAttachment to item a of theAttachments
                              set theAttachmentName to name of theAttachment as string
                              set AppleScript's text item delimiters to "."
                              set theAttachmentDelimit to the text items of theAttachmentName
                              set theAttachmentType to last item of theAttachmentDelimit
                              try
                                        set thefileName to currentName & a & "." & theAttachmentType
                                        set theSavePath to "drivename:Users:usename:Downloads:" & thefileName
  save theAttachment in theSavePath
                                        set posixSaved to quoted form of POSIX path of theSavePath
                                        set posixSaveto to POSIX path of theOutputFolder
                                        set posixSaveto to posixSaveto & thefileName
                                        set sscommand to "mv " & posixSaved & " " & quoted form of posixSaveto
  do shell script sscommand
                              end try
                    end repeat
          end repeat
end tell