AppleScript for marking up footnotes in MS Word

Question

Hello. I'm trying to write a script for marking up footnotes in MS Word (2008) that takes this:
and does this to it:
Any suggestions, pointers welcome, even if they don't amount to a full solution.
Here is what I have. At the moment it handles one replacement at a time (so I have to run it several times to go through a document full of footnotes), and not very well. It replaces the superscript footnote reference number with "\footnote{}<footnote text>" -- so puts the text after rather than within the two braces.
tell application "Microsoft Word"
    set myFind to find object of selection
    clear formatting of myFind
    set style of myFind to "Footnote Reference"
    set content of myFind to ""
    execute find myFind -- replace replace all
    if found of myFind is true then
        copy object text object of footnote 1 of selection
        set superscript of font object of selection to false
        set style of selection to "normal"
        type text selection text "\\footnote{"
        set myRange to collapse range text object of selection direction collapse start
        paste special myRange data type paste text
        type text selection text "}"
    end if
end tell
[footnote 1 of the selection should always be the footnote text corresponding to the footnote reference number selected by a find -- that bit seems to work]

Answer 1

Hi,
mephisto8 wrote:
I would be happy if I could get the whole script to either i) find italicized text in footnotes and replace it with \emph{italicized text}.
This works
tell application "Microsoft Word"
     set {tStart, tEnd} to {start of content, end of content} of text object of selection
     set oldSel to create range (active document) start tStart end tEnd
     select first character of text object of footnote 1 of active document
     move range (text object of selection) by a character item count -1
     set myFind to find object of selection
     clear formatting of myFind
     set italic of font object of myFind to true
     set content of myFind to ""
     clear formatting replacement of myFind
     set content of replacement of myFind to "\\emph{^&}"
     set italic of font object of replacement of myFind to false
     execute find myFind replace replace all
     select oldSel
     clear formatting of myFind
     set style of myFind to "Footnote Reference"
     repeat while execute find myFind
          tell selection
               set x to end of content of text object of footnote 1
               copy object text object of footnote 1
               set superscript of font object to false
               set style to "normal"
               type text text "\\footnote{"
               paste special (collapse range text object direction collapse start) data type paste text
               delete first character -- remove the space before the pasted text
               move range (text object) by a character item count (x - 2)
               type text text "}"
          end tell
     end repeat
end tell