AppleScript for renaming new folders from filenames??

Question

I want to put a bunch of files in their own individual folders with the foldername matching the file inside without the file extension.
So say I select 30 files > create folder for each file > move these files into their own folder > name the folder the filename w/o extension
I want to be able to do this with a single file or a batch. I've been messing around in Automator but haven't achieved what I want to do fully. I'd greatly appreciate anyone's help with this Thanks!!

Answer 1

You can use Automator to create a Service, and place a script in a Run AppleScript action, for example:
Service receives selected files or folders in Finder
Run AppleScript:
on run {input, parameters} -- create folders from file names and move
  set output to {} -- this will be a list of the moved files
  repeat with anItem in the input -- step through each item in the input
    set {theContainer, theName, theExtension} to (getTheNames from anItem)
    try
      set destination to (makeNewFolder for theName at theContainer)
      tell application "Finder"
        move anItem to destination
        set the end of the output to the result as alias -- success
      end tell
    on error errorMessage -- duplicate name, permissions, etc
      log errorMessage
      # handle errors if desired - just skip for now
    end try
  end repeat
  return the output -- pass on the results to following actions
end run
to getTheNames from someItem -- get a container, name, and extension from a file item
  tell application "System Events" to tell disk item (someItem as text)
    set theContainer to the path of the container
    set {theName, theExtension} to {name, name extension}
  end tell
  if theExtension is not "" then
    set theName to text 1 thru -((count theExtension) + 2) of theName -- just the name part
    set theExtension to "." & theExtension
  end if
  return {theContainer, theName, theExtension}
end getTheNames
to makeNewFolder for theChild at theParent -- make a new child folder at the parent location if it doesn't already exist
  set theParent to theParent as text
  if theParent begins with "/" then set theParent to theParent as POSIX file as text
  try
    return (theParent & theChild) as alias
  on error errorMessage -- no folder
    tell application "Finder" to make new folder at theParent with properties {name:theChild}
    return the result as alias
  end try
end makeNewFolder