Applescript: How do i loop a script between two sheets in one workbook?

Question

My office uses excel for its invoices and they have tasked me with finding a way to automatically name the invoice tabs in the workbook which are set up between two dummy sheets. What I have works but does not do exactly what they asked.
This is what I have so far:
tell application "Microsoft Excel"
          repeat with x in (get selected sheets of active window)
                    try
                              set name of x to string value of range "T18" in ws
                    on error
                              display dialog "Re-name failed" buttons {"Cancel"} with icon 0
                    end try
          end repeat
end tell
As of now I have to highlight the sheets in the workbook I want the script to run on. I would like to be able is to run the set name script between two sheets (Dummy 1 & Dummy 2) without having to highlight any scripts. I thought of using a from to with the repeat function but that has to be an integer. Any ideas would be welcome as at best I would call myself an ametuer with just enough knowledge to get in trouble.

Answer 1

Ah, that is a little tricky.  try this instead.
tell application "Microsoft Excel"
          tell workbook 1
                    set sheetHolder to sheet "Dummy 1"
                    repeat
  -- get next sheet
                              set currentSheet to next of sheetHolder
  -- check for end sheet and exit
                              if name of currentSheet is "Dummy 2" then exit repeat
  -- rename (exit on failure)
                              try
                                        set name of currentSheet to string value of cell "T18" of currentSheet
                              on error
                                        display dialog "Re-name failed" buttons {"Cancel"} with icon 0
                                        exit repeat
                              end try
  -- crawl across sheets, inchworm style
                              set sheetHolder to currentSheet
                    end repeat
          end tell
end tell