AppleScript Newbie - Display dialog box when quitting an application

Question

Hello.
I was wondering if it's possible to write a script that displays a dialog box (in this case one saying "BACK UP!!!!") everytime i quit Final Draft.
Thanks.
F.

Answer 1

A regular AppleScript does not have the ability to get system notifications, so you would have to do something like have the script continually check (poll) for applications that are running.  A Cocoa-AppleScript does have the ability to do Cocoa-y stuff such as register for system notifications, so you can create a new applet (AppleScript Editor > File > New from Template > Cocoa-AppleScript Applet), paste in the following, and save it as an application (uncheck the option to show the startup screen):
property theApps : {"Final Draft"} -- a list of applications to watch for
on run -- example
  # add observers for workspace notifications
  tell current application's NSWorkspace's sharedWorkspace's notificationCenter
    addObserver_selector_name_object_(me, "appQuit:", current application's NSWorkspaceDidTerminateApplicationNotification, missing value)
  end tell
  -- tell application "Final Draft" to activate
end run
on appQuit_(aNotification) -- an application quit
  # aNotification's userInfo record contains an NSRunningApplication instance that we can get properties from
  set theApplication to (aNotification's userInfo's NSWorkspaceApplicationKey's localizedName()) as text
  if theApplication is in theApps then
  tell current application -- me
    beep 3
    activate -- make sure dialog comes to front
    display dialog "BACK UP!!!!" with title "Final Draft quit notice" buttons {"OK"} default button 1
    quit
  end tell
  end if
end appQuit_
When the application is run it will sit there and receive notifications when other applications quit, and checks to see if it was the application you want.