Applescript: prepend a string with folder name

Question

I’ve found this script that copies the names of multiple selected files in the Finder to clipboard:
try
     set theNames to {}
     tell application "Finder"
          repeat with i in (get selection)
               set end of theNames to name of i
          end repeat
       end tell
     set {TID, text item delimiters} to {text item delimiters, return}
     set the clipboard to theNames as text
     set text item delimiters to TID
end try
I need to prepend to each result a string like "www.domain-name.ext/folder", where “folder” is the parent folder relative to the files.
How can I do it? Thanks in advance.

Answer 1

You can do something like:
try
   set theNames to {}
   tell application "Finder"
      repeat with i in (get selection)
          set parentName to name of container of i
          set end of theNames to "www.domain-name.ext/" & parentName & "/" & name of i
      end repeat
    end tell
    if theNames is not {} then
      set {TID, text item delimiters} to {text item delimiters, return}
      set the clipboard to theNames as text
      set text item delimiters to TID
    end if
on error errmess
    log errmess
end try