AppleScript that Finds Photos and Copys Created within Week

Question

Hello,
I have three folders where I download photos. Each folder has different types of photos. I'd like to create a new folder that contains the copied most recent photos from my three folders. I was able to do this in workflow, but I'm not sure how to start the AppleScript.
Plus with workflow, it only works when I manually run it. Ideally, I'd like to see the results when I open the recent folder. Someone mentioned a Folder Action, but I can't figure out how to get it to work when the folder is opened.
I feel like i'm missing something fairly simple and i'm too tired to figure it out.
Please help!
Thanks!

Answer 1

I remember a script I wrote back in 2005. I had run a KDX-Server and I wanted a folder that contains aliases of my latest uploads. The way the skripts works is a bit ehm... strange since I was only able to create symbolic links using a shell script together with find, and later on theses symbolic links had to be converted to aliases so that kdx could recognize them...
(Find is pretty fast on searching for the latest files)
well, in addition a short manual
--hubionmac.com 07.02.2005
--#################################--Preferences--############################## ###--
property daycount : 4
property depthscanswitch : "off" --(on/off)
property dirnameinaliasname : "off" --(on/off)
global maxfolderdeep, folderkind, destination_folder, currentfoldername, tempfolder
--## Set all working directories
tell application "Finder"
set folderkind to kind of folder 1 of startup disk
try
set aliasfolder to (folder "recentuploadsaliases" of startup disk) as alias
on error
make new folder at startup disk with properties {name:"recentuploadsaliases"}
set aliasfolder to (folder "recentuploadsaliases" of startup disk) as alias
--error "A folder called \"recentuploadsaliases\" has been created at your startup disk."
end try
try
set temp_folder to folder "_temp" of aliasfolder as alias
set tempfolder to POSIX path of temp_folder
on error
make new folder at (aliasfolder as alias) with properties {name:"_temp"}
set temp_folder to folder "_temp" of aliasfolder as alias
set tempfolder to POSIX path of temp_folder
end try
set scangroupfolders to every folder of (aliasfolder as alias)
end tell
--## Now scan every folder
repeat with currentscan_groupfolder in scangroupfolders
tell application "Finder" to set itemname to name of currentscan_groupfolder
if itemname as text ≠ "_temp" then
--## clean the tempdir and the destination folder from aliases and links
tell application "Finder" to set destination_folder to original item of alias file "destination_folder" of currentscan_groupfolder
do shell script "rm -f " & quoted form of (POSIX path of (destination_folder as alias)) & "*"
do shell script "rm -f " & quoted form of tempfolder & "*"
tell application "Finder" to set the_folders to every alias file of currentscan_groupfolder
repeat with the_folder in the_folders
if name of the_folder ≠ "destination_folder" then
tell application "Finder" to set thepath to original item of the_folder
if depthscanswitch = "on" then
set maxfolderdeep to (character 1 of ((name of the_folder) as text)) as integer
else
set maxfolderdeep to 1
end if
tell application "Finder" to set thefolder to original item of (the_folder as alias)
set currentfoldername to (name of thefolder) as text
makesymlinks(thepath)
end if
end repeat
-- ## create aliases of symbolic links at the destination directory
tell application "Finder"
set these_ to every item of temp_folder
repeat with this_ in these_
if dirnameinaliasname = "on" then
set name_01 to name of container of (original item of this_)
set name_00 to name of (original item of this_)
set aliasname to name_00 & " @ " & name_01 as string
make new alias file to ((original item of this_) as alias) with properties {name:aliasname} at destination_folder
else
make new alias file to ((original item of this_) as alias) at destination_folder
end if
end repeat
end tell
end if
end repeat
on makesymlinks(the_folder)
set thepath to POSIX path of (the_folder as alias)
do shell script "find " & quoted form of thepath & " -ctime -" & daycount & " -maxdepth " & maxfolderdeep & " -mindepth " & maxfolderdeep & " -exec ln -s {} " & quoted form of tempfolder & " \\;"
end makesymlinks
Maybe this helps in a way.