AppleScript to perform Safari file upload?

Question

I need an AppleScript to handle the file picker dialog in Safari for an upload operation.
I have most of it working, except for the small fact that I can't figure out how to actually SELECT the file from the list.
Mac OS X 10.7.3, Safari 5.1.3
Here's what I have so far:
on run argv
          if (count argv) = 1 then
                    set file_name to item 1 of argv
          else
                    return "Usage: FilePicker.scpt file"
          end if
          tell application "Safari"
                    if not frontmost then activate
                    tell front window
  activate
                              tell application "System Events"
  -- enable List View
  keystroke "2" using {command down}
  -- move input focus to the search field
  keystroke "f" using {command down}
  keystroke file_name
                                        delay 1
  -- select the "Filename Contains" suggestion
  keystroke (ASCII character 31) -- down arrow
  keystroke return
                                        delay 1
  -- TODO: select the first file from the list of matches
  keystroke return
                              end tell
                    end tell
          end tell
          return 0
end run
Any suggestions?

Answer 1

Finally got it working. Thank you for your help!
on run argv
          set returnVal to 0
          if (count argv) = 1 then
                    set file_name to item 1 of argv
          else
                    return "Usage: FilePicker.scpt file"
          end if
          tell application "Safari"
                    if not frontmost then activate
          end tell
          tell application "System Events"
                    tell process "Safari"
                              tell window 1
                                        if sheet 1 exists then
  -- enable List View
  keystroke "2" using {command down}
  -- move input focus to the search field
  keystroke "f" using {command down}
  keystroke file_name
                                                  delay 2
  -- select the "Filename Contains" suggestion
  keystroke (ASCII character 31) -- down arrow
  keystroke return
                                                  delay 3
                                                  tell sheet 1
                                                            tell group 1
                                                                      tell splitter group 1
                                                                                tell scroll area 2
                                                                                          tell outline 1
                                                                                                    select row 1
                                                                                          end tell
                                                                                end tell
                                                                      end tell
                                                            end tell
                                                            click button "Choose"
                                                  end tell
                                        else
                                                  set returnVal to -1
                                        end if
                              end tell -- window 1
                    end tell -- Safari
          end tell -- System Events
          return returnVal
end run