Automate Creation of Folder based on Filename

Question

Hi,
I am a total newbie to Automator, and although I have some programming background, I have not wrapped my brain around how this wonderful tool works yet. I need to perform a task on several hundred files and I need to do it soon, so no time to learn and play with Automator right now.
I was wondering if someone can give me a true step by step instructions for creating a script that will do the following:
This is how I would like the flow to behave:
1. I select a file and run the script (hopefully based on a keystroke). The script will then:
2. Create a new folder in the same directory as the file.
3. Name the new folder based on the filename (minus the extension) of the above selected file.
4. Move the selected file into the new folder.
So basically I am enveloping the selected file in a new folder that is named the same as the file itself (minus the extension).
Thank you in advance.

Answer 1

OK, I reworked and tested it, so I think I've got all the oddities found. I wound up just using an AppleScript, since about the only thing Automator was used for was getting Finder Items (and it didn't do so well at that). Paste the script into the Script Editor and save it as an application (make sure the Startup Screen option is unchecked). You can either drop items on it or double-click it, in which case it will prompt for items. Document files are the only things processed, and packages/bundles are handled correctly (getting subfolders will not go into them), so you don't have to worry about things like application bundles and .rtfd files.
<pre style="
font-family: Monaco, 'Courier New', Courier, monospace;
font-size: 10px;
margin: 0px;
padding: 5px;
border: 1px solid #000000;
width: 720px; height: 340px;
color: #000000;
background-color: #FFDDFF;
overflow: auto;"
title="this text can be pasted into the Script Editor">
-- make new folders with the name of document files, then move them into their respective new folders
-- the following properties affect the operation of the script
property GetFiles : false -- get individual files?  true chooses files, false chooses folders
property GetSubFolders : true -- get contents of subfolders?  true gets contents of subfolders, false skips them
property DestinationFolder : "" -- if a folder path is specified, it is used as the destination for file moves
on run -- application double-clicked
if GetFiles then
choose file with prompt "Choose a file:" default location (path to desktop) with multiple selections allowed without invisibles
else
choose folder with prompt "Choose a folder:" default location (path to desktop) with multiple selections allowed without invisibles
end if
open the result
end run
on open TheItems -- items dropped onto the application
if DestinationFolder is not missing value then try -- verify destination path
DestinationFolder as alias
on error
set DestinationFolder to (choose folder with prompt "Invalid destination folder path - where do you want to move the items?")
end try
set SkippedItems to {} -- this will be a list of skipped items (errors)
set TheFiles to {} -- this will be a list of items to process
repeat with AnItem in TheItems -- expand folders
set AnItem to the contents of AnItem
set FileInfo to (info for AnItem)
if (folder of FileInfo) and not (package folder of FileInfo) then -- a folder
if GetSubFolders then
repeat with SubItem in (ListFiles from AnItem)
set the end of TheFiles to (contents of SubItem)
end repeat
else
tell application "Finder" to (get files of AnItem) as alias list
set TheFiles to TheFiles & the result
end if
else
set the end of TheFiles to AnItem
end if
end repeat
repeat with MyFile in TheFiles -- do stuff with the resulting items
set {TheClass, TheName, TheExtension, TheContainer} to (GetTheNames from MyFile)
if TheClass is «class docf» then try -- just document files
tell application "Finder"
if DestinationFolder is not missing value then
make new folder at DestinationFolder with properties {name:TheName}
else
make new folder at TheContainer with properties {name:TheName}
end if
move MyFile to the result
end tell
on error ErrorMessage -- the folder already exists, permissions, etc
log ErrorMessage
set the end of SkippedItems to (TheName & TheExtension)
-- set the end of SkippedItems to (AnItem as text) -- the full file path
end try
end repeat
if SkippedItems is not {} then -- handle skipped items
set AlertText to "Error with moving files to folders"
if (count SkippedItems) is greater than 1 then
set TheMessage to ((count SkippedItems) as text) & space & "items were skipped:"
else
set TheMessage to "1 " & "item was skipped:"
end if
set {TempTID, AppleScript's text item delimiters} to {AppleScript's text item delimiters, return}
set {SkippedItems, AppleScript's text item delimiters} to {SkippedItems as text, TempTID}
display alert AlertText message TheMessage & return & SkippedItems
end if
end open
to GetTheNames from SomeFile
get a class, name, extension, and container from a file path
parameters - SomeFile [mixed]: a file path
returns [list] - item 1 [constant]: the class of the file object
item 2 [text]: the name of the file
        item 3 [text]: the .extension (if no extension, the value returned is "")
item 4 [alias]: the containing folder of the file
set SomeFile to SomeFile as alias -- the Finder likes aliases
tell application "Finder"
set TheClass to class of (get properties of SomeFile)
set TheName to name of SomeFile
set TheExtension to name extension of SomeFile
if TheExtension is in {missing value, ""} then
set TheExtension to ""
else
set TheExtension to "." & TheExtension
end if
set TheName to text 1 thru -((count TheExtension) + 1) of TheName -- just the name part
set TheContainer to (container of SomeFile) as alias
end tell
return {TheClass, TheName, TheExtension, TheContainer}
end GetTheNames
to ListFiles from SomeItem
return a list of files contained in SomeItem, drilling down into subfolders (not packages)
parameters - SomeItem [mixed]: the item to get the contents of
  returns [list]: a list of aliases
set {FilesList, SomeItem} to {{}, SomeItem as text}
set FileInfo to (info for SomeItem as alias)
if (folder of FileInfo) and not (package folder of FileInfo) then -- a folder
try
tell application "Finder" to set SubItems to (items of folder SomeItem)
on error
return {}
end try
repeat with AnItem in SubItems -- drill down
set FilesList to FilesList & (ListFiles from AnItem)
end repeat
else
set the end of FilesList to (SomeItem as alias)
end if
return FilesList
end ListFiles
</pre>