Automatic material master creation

Question

Using BAPI_MATERIAL_GET_ALL I transfer the data of a template material to a new material and create it using BAPI_MATERIAL_SAVEDATA.
all works great EXCEPT...
The Inspection Setup Data is not transferred from the template material.
This Inspection Setup Data is entered in under the QM tab but can anybody suggest a solution as to how this data can be transferred automatically?
Thanks for your help, Mark

Answer 1

Hi Mark,
Use BAPI 'BAPI_MATINSPCTRL_SAVEREPLICA' to achieve this. I have attached a little program I have whipped up to modify the Average Inspection Duration field. It's pretty straight forward.
Hope this helps.
Cheers,
Pat.
PS. Kindly assign Points to the posts you find helpful.
*& Report  YPAT_QM_LOAD                                                *
REPORT  ypat_qm_load.
DATA: tbl_inspection TYPE TABLE OF bapi1001004_qmat WITH HEADER LINE,
      return         TYPE TABLE OF bapiret2         WITH HEADER LINE,
      st_qmat        TYPE qmat,
      st_inspection  TYPE bapi1001004_qmat.
DATA: BEGIN OF tbl_data OCCURS 0,
        art    TYPE qpart,
        matnr  TYPE matnr,
        werks  TYPE werks_d,
        mpdau  TYPE qmpdau,
      END OF tbl_data.
PARAMETERS: p_infile LIKE ibipparms-path OBLIGATORY
            DEFAULT 'C:'.
AT SELECTION-SCREEN ON VALUE-REQUEST FOR p_infile.
  CALL FUNCTION 'F4_FILENAME'
    IMPORTING
      file_name = p_infile.
START-OF-SELECTION.
  PERFORM get_file.
  PERFORM build_bapi_table.
END-OF-SELECTION.
  PERFORM call_bapi.
*&      Form  get_file
FORM get_file .
  DATA: l_filename TYPE string.
  l_filename = p_infile.
  CALL FUNCTION 'GUI_UPLOAD'
    EXPORTING
      filename                = l_filename
      filetype                = 'ASC'
      has_field_separator     = 'X'
    TABLES
      data_tab                = tbl_data
    EXCEPTIONS
      file_open_error         = 1
      file_read_error         = 2
      no_batch                = 3
      gui_refuse_filetransfer = 4
      invalid_type            = 5
      no_authority            = 6
      unknown_error           = 7
      bad_data_format         = 8
      header_not_allowed      = 9
      separator_not_allowed   = 10
      header_too_long         = 11
      unknown_dp_error        = 12
      access_denied           = 13
      dp_out_of_memory        = 14
      disk_full               = 15
      dp_timeout              = 16
      OTHERS                  = 17.
ENDFORM.                    " get_file
*&      Form  build_bapi_table
FORM build_bapi_table .
  REFRESH tbl_inspection.
  LOOP AT tbl_data.
    CLEAR: st_qmat,
           st_inspection.
    SELECT SINGLE *
           INTO st_qmat
           FROM qmat
           WHERE art   = tbl_data-art   AND
                 matnr = tbl_data-matnr AND
                 werks = tbl_data-werks.
    CALL FUNCTION 'MAP2E_QMAT_TO_BAPI1001004_QMAT'
      EXPORTING
        qmat             = st_qmat
      CHANGING
        bapi1001004_qmat = st_inspection.
    CLEAR tbl_inspection.
    tbl_inspection = st_inspection.
    tbl_inspection-function          = '004'.          "Change
    tbl_inspection-ave_insp_duration = tbl_data-mpdau. "New Ave Insp Dur
    APPEND tbl_inspection.
  ENDLOOP.
ENDFORM.                    " build_bapi_table
*&      Form  call_bapi
FORM call_bapi .
  CALL FUNCTION 'BAPI_MATINSPCTRL_SAVEREPLICA'
    TABLES
      return         = return[]
      inspectionctrl = tbl_inspection[].
  CALL FUNCTION 'BAPI_TRANSACTION_COMMIT'.
ENDFORM.                    " call_bapi