How to add page count of PDF to the file name?

Question

I need help with an applescript that can look at a pdf, determine the page count in file and then add that value to the end of the file name in front of the .pdf
ex.
original name "map with pages4c.pdf"
renamed "map with pages4c_48.pdf"
Any help would be appreciated or suggestions on how this could be done.
Thanks,
John

Answer 1

Hello
That's quite simple.
Just replace this chunk of code -
tell application "Finder"
set n to f's name
set f's name to (n's text 1 thru -5) & "_" & p & ".pdf"
end tell
with -
if 10 > p then set p to "0" & p
tell application "Finder"
set n to f's name
set f's name to (n's text 1 thru -5) & "_" & p & ".pdf"
end tell
By the way, if there are 10000 files in directory tree, I'm afraid Finder is too slow to get files list. In order to avoid Apple Events timeout error, at least, replace this line -
tell o to run
with -
with timeout of 3600 seconds
tell o to run
end timeout
Or try the following script, which employs find(1) instead of Finder to get files list.
All the best,
Hiroto
--SCRIPT3
on run
--main((choose folder with multiple selections allowed) as list)
main((choose folder) as list)
end run
on open aa
main(aa)
end open
on main(aa)
(* list aa : list of folder aliases *)
script o
property ff : {}
-- confirmation for safety
set AppleScript's text item delimiters to {ASCII character 0}
set aa to (aa as Unicode text)'s text items
set AppleScript's text item delimiters to {""}
set aa to (choose from list aa default items aa ¬
with prompt ("You're renaming pdf files in following folder tree(s).") ¬
with multiple selections allowed)
if aa = false then error number -128
-- process each folder
set k to 0
repeat with a in aa
set a to a as alias
-- get pdf files' POSIX path list (= ff)
set ff to {}
set sh to "find " & quoted form of POSIX path of a & " -type f -name \"*.pdf\" -print"
try
set t to (do shell script sh)
on error
set t to ""
end try
set px to count t's paragraphs
set p0 to 1
repeat -- in order to avoid stack overflow in getting large number of paragraphs at once
set p1 to p0 + 3500
if p1 ≥ px then set p1 to -1
set ff to my ff & t's paragraphs p0 thru p1
if p1 = -1 then exit repeat
set p0 to p1 + 1
end repeat
if ff = {""} then set ff to {}
-- process each pdf file
repeat with f in my ff
set f to f as POSIX file as alias
tell application "Adobe Acrobat 7.0 Professional"
--open f
open f with invisible
tell document 1
set p to count pages
close
end tell
end tell
if 10 > p then set p to "0" & p
tell application "Finder"
set n to f's name
set f's name to (n's text 1 thru -5) & "_" & p & ".pdf"
end tell
set k to k + 1
end repeat
end repeat
-- decent notice
tell application (path to frontmost application as string)
display dialog ("Total of " & k & " pdf file(s) renamed successfully.") ¬
with icon 1 giving up after 5
end tell
end script
with timeout of 3600 seconds -- just in case
tell o to run
end timeout
end main
--END OF SCRIPT3
Message was edited by: Hiroto (fixed typos)