Bulk rename of files in subfolders

Question

Hello All
I have a folder containing 40 subfolders, and inside each of these subfolders are a number of files (between 4 and 45 each) totalling over 500 files.
Each filename starts with a string "orginalstring".
What I would like is the easiest way (whether using Automator or not) to replace all 500+ "orginalstring" with "replacementstring".
Many thanks for your help. Philip

Answer 1

Although the original poster's problem is long solved and it doesn't directly help.  Here is an appleapplescript that will perform a batch rename of selected files with ne names provided in a .csv file.  SImply open applescript, paste in an run.  Its not the most robust - it will fail if you try to create duplicate files, but for the most part it does a good job for a quick and dirty.... Beanlander
-- Bulk Rename files from .csv file
on run {}
    set file_NewFilenames to choose file with prompt "Choose .csv file containing new filenames"
    set files_ToBeRenamed to choose file with prompt "Choose files to be renamed" with multiple selections allowed
    set filedata_NewFilenames to read file_NewFilenames
    set list_NewFilenames to paragraphs of filedata_NewFilenames
    -- determine the maximum number of files that can be renamed
    set num_MaxFilesToRename to count of list_NewFilenames
    if num_MaxFilesToRename > (count of files_ToBeRenamed) then
        set num_MaxFilesToRename to count of files_ToBeRenamed
    end if
    --display dialog "Renaming " & num_MaxFilesToRename & " files…"
    repeat with i from 1 to num_MaxFilesToRename
        try
            set fileToBeRenamed to item i of files_ToBeRenamed
            set newName to item i of list_NewFilenames
            set AppleScript's text item delimiters to "\""
            set newName to (text items of newName)
            set AppleScript's text item delimiters to ""
            set newName to (newName as string)
            --display dialog newName as text
            tell application "Finder"
                set filenameExtension to name extension of fileToBeRenamed
                set name of fileToBeRenamed to newName & "." & filenameExtension
            end tell
        on error
            display dialog "Could not rename: " & fileToBeRenamed giving up after 3
        end try
    end repeat
end run