Calling all regex masters

Question

All,
I am trying to meet a requirement where the user can use regular expression like entries to filter data. For instance if the input was "1-4,6" then the user would get records containing 1,2,3,4,6. I tried wrapping the input in brackets and sending it through regexp_instr, however it does not work with multiple digits.
with test_data as(
  SELECT level data
    FROM DUAL
CONNECT BY LEVEL <= 10
SELECT data
  FROM test_data
WHERE regexp_instr(data, '[1-4,6]',1,1,0,'i') > 0
-- returns 1,2,3,4,6,10
-- the 10 should not be thereI changed the code by adding the start of string and end of string modifier but its still not quite right.
with test_data as(
  SELECT level data
    FROM DUAL
CONNECT BY LEVEL <= 10
SELECT data
  FROM test_data
WHERE regexp_instr(data, '^[1-4,6,10]$',1,1,0,'i') > 0
-- returns 0,1,2,3,4,6but now if i want to find a 10 it will only look for 1 or 0 not "10".
Any suggestions on how to accomplish this with regular expressions or any other method of reaching the same functionality?
Cheers,
Tyson Jouglet

Answer 1

All,
After realizing that regular expressions get exponentially complicated as you add more digits i decided to ditch that effort and dynamically built the where clause. In short I replaced the "1-4" with a between statement and added all none range inputs into an IN statement
here is the first go around of the code:
create or replace
function createWhereClause(p_string varchar2
                          ,p_column varchar2
                          ,p_delim varchar2 default ',')
return varchar2
deterministic
is
  l_or        varchar2(4)      := ' OR ';
  l_crlf      varchar2(2)      := chr(13)||chr(10);
  l_output    varchar2(32000);
  l_index     pls_integer;
  l_bet_index pls_integer      := 0;
  l_ins_index pls_integer      := 0;
  l_tokens    wwv_flow_global.vc_arr2;
  l_betweens  wwv_flow_global.vc_arr2;
  l_ins       wwv_flow_global.vc_arr2;
begin
  l_tokens := htmldb_util.string_to_table(p_string,p_delim);
  l_index := l_tokens.first;
  while l_index is not null loop
    if instr(l_tokens(l_index),'-') > 0 then
      l_bet_index := l_bet_index + 1;
      l_betweens(l_bet_index) := p_column || ' BETWEEN ' ||replace(l_tokens(l_index),'-',' AND ');
    elsif l_tokens(l_index) is not null then
      l_ins_index := l_ins_index + 1;
      l_ins(l_ins_index) := l_tokens(l_index);
    end if;
     l_index := l_tokens.next(l_index);
  end loop;
  l_index := l_betweens.first;
  while l_index is not null loop
    l_output := l_output || l_betweens(l_index) || l_or || l_crlf;
    l_index  := l_betweens.next(l_index);
  end loop;
  l_index := l_ins.first;
  if l_index is not null then
    l_output := l_output || p_column || ' IN (';
    while l_index is not null loop
      l_output := l_output || l_ins(l_index) || ',';
      l_index  := l_ins.next(l_index);
    end loop;
    l_output := rtrim(l_output,',') || ')';
  end if;
  return rtrim(l_output,l_or);
end;Cheers,
Tyson Jouglet